[gentoo-commits] gentoo-x86 commit in sys-cluster/openmpi: openmpi-1.5.4-r3.ebuild openmpi-1.5.5.ebuild ChangeLog

["Alexey Shvetsov (alexxy)" <alexxy@gentoo.org>]

alexxy      12/04/18 20:35:24

  Modified:             openmpi-1.5.4-r3.ebuild ChangeLog
  Added:                openmpi-1.5.5.ebuild
  Log:
  [sys-cluster/openmpi] Version bump. Also introduce new USE EXPAND for openmpi
  
  (Portage version: 2.2.0_alpha100/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  sys-cluster/openmpi/openmpi-1.5.4-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/openmpi/openmpi-1.5.4-r3.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/openmpi/openmpi-1.5.4-r3.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/openmpi/openmpi-1.5.4-r3.ebuild?r1=1.1&r2=1.2

Index: openmpi-1.5.4-r3.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/openmpi/openmpi-1.5.4-r3.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- openmpi-1.5.4-r3.ebuild	3 Feb 2012 21:55:52 -0000	1.1
+++ openmpi-1.5.4-r3.ebuild	18 Apr 2012 20:35:24 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/openmpi/openmpi-1.5.4-r3.ebuild,v 1.1 2012/02/03 21:55:52 jsbronder Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/openmpi/openmpi-1.5.4-r3.ebuild,v 1.2 2012/04/18 20:35:24 alexxy Exp $
 
 EAPI=4
 inherit eutils fortran-2 multilib flag-o-matic toolchain-funcs
@@ -24,7 +24,7 @@
 RDEPEND="
 	elibc_FreeBSD? ( dev-libs/libexecinfo )
 	fortran? ( virtual/fortran )
-	infiniband? ( sys-infiniband/openib )
+	infiniband? ( sys-infiniband/ofed )
 	knem? ( sys-cluster/knem )
 	numa? ( sys-process/numactl )
 	open-mx? ( sys-cluster/open-mx )



1.103                sys-cluster/openmpi/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/openmpi/ChangeLog?rev=1.103&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/openmpi/ChangeLog?rev=1.103&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/openmpi/ChangeLog?r1=1.102&r2=1.103

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/openmpi/ChangeLog,v
retrieving revision 1.102
retrieving revision 1.103
diff -u -r1.102 -r1.103
--- ChangeLog	31 Mar 2012 17:56:03 -0000	1.102
+++ ChangeLog	18 Apr 2012 20:35:24 -0000	1.103
@@ -1,6 +1,12 @@
 # ChangeLog for sys-cluster/openmpi
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/openmpi/ChangeLog,v 1.102 2012/03/31 17:56:03 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/openmpi/ChangeLog,v 1.103 2012/04/18 20:35:24 alexxy Exp $
+
+*openmpi-1.5.5 (18 Apr 2012)
+
+  18 Apr 2012; Alexey Shvetsov <alexxy@gentoo.org> +openmpi-1.5.5.ebuild,
+  openmpi-1.5.4-r3.ebuild:
+  [sys-cluster/openmpi] Version bump. Also introduce new USE EXPAND for openmpi
 
   31 Mar 2012; Raúl Porcel <armin76@gentoo.org> openmpi-1.4.3.ebuild:
   alpha/ia64/sparc/x86 stable wrt #402095



1.1                  sys-cluster/openmpi/openmpi-1.5.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/openmpi/openmpi-1.5.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/openmpi/openmpi-1.5.5.ebuild?rev=1.1&content-type=text/plain

Index: openmpi-1.5.5.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/openmpi/openmpi-1.5.5.ebuild,v 1.1 2012/04/18 20:35:24 alexxy Exp $

EAPI=4
inherit eutils fortran-2 multilib flag-o-matic toolchain-funcs versionator

MY_P=${P/-mpi}
S=${WORKDIR}/${MY_P}

IUSE_OPENMPI_FABRICS="
	openmpi_fabrics_dapl
	openmpi_fabrics_ofed
	openmpi_fabrics_knem
	openmpi_fabrics_open-mx
	openmpi_fabrics_psm
	openmpi_fabrics_sctp"

IUSE_OPENMPI_RM="
	openmpi_rm_pbs
	openmpi_rm_slurm"

IUSE_OPENMPI_OFED_FEATURES="
	openmpi_ofed_features_control-hdr-padding
	openmpi_ofed_features_connectx-xrc
	openmpi_ofed_features_rdmacm
	openmpi_ofed_features_dynamic-sl
	openmpi_ofed_features_failover
	"

DESCRIPTION="A high-performance message passing library (MPI)"
HOMEPAGE="http://www.open-mpi.org"
SRC_URI="http://www.open-mpi.org/software/ompi/v$(get_version_component_range 1-2)/downloads/${MY_P}.tar.bz2"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux"
IUSE="+cxx elibc_FreeBSD fortran heterogeneous ipv6 mpi-threads romio threads vt
	${IUSE_OPENMPI_FABRICS} ${IUSE_OPENMPI_RM} ${IUSE_OPENMPI_OFED_FEATURES}"

REQUIRED_USE="openmpi_rm_slurm? ( !openmpi_rm_pbs )
	openmpi_rm_pbs? ( !openmpi_rm_slurm )
	openmpi_fabrics_psm? ( openmpi_fabrics_ofed )
	openmpi_ofed_features_control-hdr-padding? ( openmpi_fabrics_ofed )
	openmpi_ofed_features_connectx-xrc? ( openmpi_fabrics_ofed )
	openmpi_ofed_features_rdmacm? ( openmpi_fabrics_ofed )
	openmpi_ofed_features_dynamic-sl? ( openmpi_fabrics_ofed )
	openmpi_ofed_features_failover? ( openmpi_fabrics_ofed )"

RDEPEND="
	!sys-cluster/mpich
	!sys-cluster/lam-mpi
	!sys-cluster/mpich2
	!sys-cluster/mpiexec
	>=sys-apps/hwloc-1.3
	elibc_FreeBSD? ( dev-libs/libexecinfo )
	openmpi_fabrics_dapl? ( sys-infiniband/dapl )
	openmpi_fabrics_ofed? ( sys-infiniband/ofed )
	openmpi_fabrics_knem? ( sys-cluster/knem )
	openmpi_fabrics_open-mx? ( sys-cluster/open-mx )
	openmpi_fabrics_psm? ( sys-infiniband/infinipath-psm )
	openmpi_fabrics_sctp? ( net-misc/lksctp-tools )
	openmpi_rm_pbs? ( sys-cluster/torque )
	openmpi_rm_slurm? ( sys-cluster/slurm )
	fortran? ( virtual/fortran )
	vt? (
		!dev-libs/libotf
		!app-text/lcdf-typetools
	)
	"
DEPEND="${RDEPEND}"

pkg_setup() {
	use fortran && fortran-2_pkg_setup
	if use mpi-threads; then
		echo
		ewarn "WARNING: use of MPI_THREAD_MULTIPLE is still disabled by"
		ewarn "default and officially unsupported by upstream."
		ewarn "You may stop now and set USE=-mpi-threads"
		echo
	fi

	echo
	elog "OpenMPI has an overwhelming count of configuration options."
	elog "Don't forget the EXTRA_ECONF environment variable can let you"
	elog "specify configure options if you find them necessary."
	echo
}

src_prepare() {
	# Necessary for scalibility, see
	# http://www.open-mpi.org/community/lists/users/2008/09/6514.php
	if use threads; then
		echo 'oob_tcp_listen_mode = listen_thread' \
			>> opal/etc/openmpi-mca-params.conf
	fi

	epatch "${FILESDIR}"/openmpi-r24328.patch
}

src_configure() {
	local myconf=(
		--sysconfdir="${EPREFIX}/etc/${PN}"
		--enable-pretty-print-stacktrace
		--enable-orterun-prefix-by-default
		--with-hwloc="${EPREFIX}/usr"
		)

	if use mpi-threads; then
		myconf+=(
			--enable-mpi-thread-multiple
			--enable-opal-multi-threads
			)
	fi

	if use fortran; then
		if [[ $(tc-getFC) =~ g77 ]]; then
			myconf+=(--disable-mpi-f90)
		elif [[ $(tc-getFC) =~ if ]]; then
			# Enabled here as gfortran compile times are huge with this enabled.
			myconf+=(--with-mpi-f90-size=medium)
		fi
	else
		myconf+=(--disable-mpi-f90 --disable-mpi-f77)
	fi

	! use vt && myconf+=(--enable-contrib-no-build=vt)

	econf "${myconf[@]}" \
		$(use_enable cxx mpi-cxx) \
		$(use_enable romio io-romio) \
		$(use_enable heterogeneous) \
		$(use_enable ipv6) \
		$(use_with numa libnuma "${EPREFIX}"/usr) \
		$(use_with openmpi_fabrics_dapl udapl "${EPREFIX}"/usr) \
		$(use_with openmpi_fabrics_ofed openib "${EPREFIX}"/usr) \
		$(use_with openmpi_fabrics_knem knem "${EPREFIX}"/usr) \
		$(use_with openmpi_fabrics_open-mx mx "${EPREFIX}"/usr) \
		$(use_with openmpi_fabrics_psm psm "${EPREFIX}"/usr) \
		$(use_enable openmpi_ofed_features_control-hdr-padding openib-control-hdr-padding) \
		$(use_enable openmpi_ofed_features_connectx-xrc openib-connectx-xrc) \
		$(use_enable openmpi_ofed_features_rdmacm openib-rdmacm) \
		$(use_enable openmpi_ofed_features_dynamic-sl openib-dynamic-sl) \
		$(use_enable openmpi_ofed_features_failover btl-openib-failover) \
		$(use_with openmpi_fabrics_sctp sctp) \
		$(use_with openmpi_rm_pbs tm) \
		$(use_with openmpi_rm_slurm slurm)
}

src_install () {
	emake DESTDIR="${D}" install || die "make install failed"
	# From USE=vt see #359917
	rm "${ED}"/usr/share/libtool &> /dev/null
	dodoc README AUTHORS NEWS VERSION || die
}

src_test() {
	# Doesn't work with the default src_test as the dry run (-n) fails.
	emake -j1 check || die "emake check failed"
}