* [gentoo-commits] gentoo-x86 commit in dev-libs/glib: ChangeLog glib-2.32.1.ebuild
@ 2012-04-14 3:30 Alexandre Rostovtsev (tetromino)
0 siblings, 0 replies; 5+ messages in thread
From: Alexandre Rostovtsev (tetromino) @ 2012-04-14 3:30 UTC (permalink / raw
To: gentoo-commits
tetromino 12/04/14 03:30:40
Modified: ChangeLog
Added: glib-2.32.1.ebuild
Log:
Version bump with minor bugfixes.
(Portage version: 2.2.0_alpha100/cvs/Linux x86_64)
Revision Changes Path
1.510 dev-libs/glib/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.510&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.510&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?r1=1.509&r2=1.510
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v
retrieving revision 1.509
retrieving revision 1.510
diff -u -r1.509 -r1.510
--- ChangeLog 27 Mar 2012 03:16:18 -0000 1.509
+++ ChangeLog 14 Apr 2012 03:30:40 -0000 1.510
@@ -1,6 +1,11 @@
# ChangeLog for dev-libs/glib
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.509 2012/03/27 03:16:18 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.510 2012/04/14 03:30:40 tetromino Exp $
+
+*glib-2.32.1 (14 Apr 2012)
+
+ 14 Apr 2012; Alexandre Rostovtsev <tetromino@gentoo.org> +glib-2.32.1.ebuild:
+ Version bump with minor bugfixes.
27 Mar 2012; Alexandre Rostovtsev <tetromino@gentoo.org> glib-2.28.8.ebuild,
glib-2.30.2.ebuild, glib-2.30.2-r1.ebuild, glib-2.30.3.ebuild,
1.1 dev-libs/glib/glib-2.32.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild?rev=1.1&content-type=text/plain
Index: glib-2.32.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild,v 1.1 2012/04/14 03:30:40 tetromino Exp $
EAPI="4"
PYTHON_DEPEND="utils? 2"
# Avoid runtime dependency on python when USE=test
inherit autotools gnome.org libtool eutils flag-o-matic gnome2-utils multilib pax-utils python virtualx
DESCRIPTION="The GLib library of C routines"
HOMEPAGE="http://www.gtk.org/"
SRC_URI="${SRC_URI}
http://pkgconfig.freedesktop.org/releases/pkg-config-0.26.tar.gz" # pkg.m4 for eautoreconf
LICENSE="LGPL-2"
SLOT="2"
IUSE="debug doc fam selinux static-libs systemtap test utils xattr"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~x86-linux"
RDEPEND="virtual/libiconv
virtual/libffi
sys-libs/zlib
xattr? ( sys-apps/attr )
fam? ( virtual/fam )
utils? ( >=dev-util/gdbus-codegen-${PV} )"
DEPEND="${RDEPEND}
dev-libs/elfutils
>=sys-devel/gettext-0.11
>=dev-util/gtk-doc-am-1.15
doc? (
>=dev-libs/libxslt-1.0
>=dev-util/gdbus-codegen-${PV}
>=dev-util/gtk-doc-1.15
~app-text/docbook-xml-dtd-4.1.2 )
systemtap? ( >=dev-util/systemtap-1.3 )
test? (
sys-devel/gdb
=dev-lang/python-2*
>=dev-util/gdbus-codegen-${PV}
>=sys-apps/dbus-1.2.14 )
!<dev-util/gtk-doc-1.15-r2"
PDEPEND="x11-misc/shared-mime-info
!<gnome-base/gvfs-1.6.4-r990"
# shared-mime-info needed for gio/xdgmime, bug #409481
# Earlier versions of gvfs do not work with glib
pkg_setup() {
# Needed for gio/tests/gdbus-testserver.py
if use test ; then
python_set_active_version 2
python_pkg_setup
fi
}
src_prepare() {
mv -vf "${WORKDIR}"/pkg-config-*/pkg.m4 "${WORKDIR}"/ || die
if use ia64 ; then
# Only apply for < 4.1
local major=$(gcc-major-version)
local minor=$(gcc-minor-version)
if (( major < 4 || ( major == 4 && minor == 0 ) )); then
epatch "${FILESDIR}/glib-2.10.3-ia64-atomic-ops.patch"
fi
fi
# Don't fail gio tests when ran without userpriv, upstream bug 552912
# This is only a temporary workaround, remove as soon as possible
# epatch "${FILESDIR}/${PN}-2.18.1-workaround-gio-test-failure-without-userpriv.patch"
# Fix gmodule issues on fbsd; bug #184301
epatch "${FILESDIR}"/${PN}-2.12.12-fbsd.patch
# Do not try to remove files on live filesystem, upstream bug #619274
sed 's:^\(.*"/desktop-app-info/delete".*\):/*\1*/:' \
-i "${S}"/gio/tests/desktop-app-info.c || die "sed failed"
# need to build tests if USE=doc for bug #387385
if ! use test && ! use doc; then
# don't waste time building tests
sed 's/^\(.*\SUBDIRS .*\=.*\)tests\(.*\)$/\1\2/' -i $(find . -name Makefile.am -o -name Makefile.in) || die
else
# Disable tests requiring dev-util/desktop-file-utils when not installed, bug #286629
if ! has_version dev-util/desktop-file-utils ; then
ewarn "Some tests will be skipped due dev-util/desktop-file-utils not being present on your system,"
ewarn "think on installing it to get these tests run."
sed -i -e "/appinfo\/associations/d" gio/tests/appinfo.c || die
sed -i -e "/desktop-app-info\/default/d" gio/tests/desktop-app-info.c || die
sed -i -e "/desktop-app-info\/fallback/d" gio/tests/desktop-app-info.c || die
sed -i -e "/desktop-app-info\/lastused/d" gio/tests/desktop-app-info.c || die
fi
# Disable tests requiring dbus-python and pygobject; bugs #349236, #377549, #384853
if ! has_version dev-python/dbus-python || ! has_version 'dev-python/pygobject:2' ; then
ewarn "Some tests will be skipped due to dev-python/dbus-python or dev-python/pygobject:2"
ewarn "not being present on your system, think on installing them to get these tests run."
sed -i -e "/connection\/filter/d" gio/tests/gdbus-connection.c || die
sed -i -e "/connection\/large_message/d" gio/tests/gdbus-connection-slow.c || die
sed -i -e "/gdbus\/proxy/d" gio/tests/gdbus-proxy.c || die
sed -i -e "/gdbus\/proxy-well-known-name/d" gio/tests/gdbus-proxy-well-known-name.c || die
sed -i -e "/gdbus\/introspection-parser/d" gio/tests/gdbus-introspection.c || die
sed -i -e "/g_test_add_func/d" gio/tests/gdbus-threading.c || die
sed -i -e "/gdbus\/method-calls-in-thread/d" gio/tests/gdbus-threading.c || die
# needed to prevent gdbus-threading from asserting
ln -sfn $(type -P true) gio/tests/gdbus-testserver.py
fi
fi
# gdbus-codegen is a separate package
epatch "${FILESDIR}/${PN}-2.31.x-external-gdbus-codegen.patch"
# disable pyc compiling
use test && python_clean_py-compile_files
# Needed for the punt-python-check patch, disabling timeout test
# Also needed to prevent croscompile failures, see bug #267603
# Also needed for the no-gdbus-codegen patch
AT_M4DIR="${WORKDIR}" eautoreconf
[[ ${CHOST} == *-freebsd* ]] && elibtoolize
epunt_cxx
}
src_configure() {
# Avoid circular depend with dev-util/pkgconfig
if ! has_version dev-util/pkgconfig; then
if has_version sys-apps/dbus; then
export DBUS1_CFLAGS="-I/usr/include/dbus-1.0 -I/usr/$(get_libdir)/dbus-1.0/include"
export DBUS1_LIBS="-ldbus-1"
fi
export LIBFFI_CFLAGS="-I$(echo /usr/$(get_libdir)/libffi-*/include)"
export LIBFFI_LIBS="-lffi"
fi
local myconf
# Building with --disable-debug highly unrecommended. It will build glib in
# an unusable form as it disables some commonly used API. Please do not
# convert this to the use_enable form, as it results in a broken build.
# -- compnerd (3/27/06)
use debug && myconf="--enable-debug"
# Always use internal libpcre, bug #254659
econf ${myconf} \
$(use_enable xattr) \
$(use_enable doc man) \
$(use_enable doc gtk-doc) \
$(use_enable fam) \
$(use_enable selinux) \
$(use_enable static-libs static) \
$(use_enable systemtap dtrace) \
$(use_enable systemtap systemtap) \
--with-pcre=internal \
--with-threads=posix
}
src_install() {
local f
# install-exec-hook substitutes ${PYTHON} in glib/gtester-report
emake DESTDIR="${D}" PYTHON="${EPREFIX}/usr/bin/python2" install
if ! use utils; then
rm "${ED}usr/bin/gtester-report"
fi
# Do not install charset.alias even if generated, leave it to libiconv
rm -f "${ED}/usr/lib/charset.alias"
# Don't install gdb python macros, bug 291328
rm -rf "${ED}/usr/share/gdb/" "${ED}/usr/share/glib-2.0/gdb/"
dodoc AUTHORS ChangeLog* NEWS* README
insinto /usr/share/bash-completion
for f in gdbus gsettings; do
newins "${ED}/etc/bash_completion.d/${f}-bash-completion.sh" ${f}
done
rm -rf "${ED}/etc"
# Completely useless with or without USE static-libs, people need to use
# pkg-config
find "${D}" -name '*.la' -exec rm -f {} +
}
src_test() {
gnome2_environment_reset
unset DBUS_SESSION_BUS_ADDRESS
export XDG_CONFIG_DIRS=/etc/xdg
export XDG_DATA_DIRS=/usr/local/share:/usr/share
export G_DBUS_COOKIE_SHA1_KEYRING_DIR="${T}/temp"
unset GSETTINGS_BACKEND # bug 352451
# Related test is a bit nitpicking
mkdir "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
chmod 0700 "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
# Hardened: gdb needs this, bug #338891
if host-is-pax ; then
pax-mark -mr "${S}"/tests/.libs/assert-msg-test \
|| die "Hardened adjustment failed"
fi
# Need X for dbus-launch session X11 initialization
Xemake check
}
pkg_preinst() {
# Only give the introspection message if:
# * The user has gobject-introspection
# * Has glib already installed
# * Previous version was different from new version
if has_version "dev-libs/gobject-introspection" && ! has_version "=${CATEGORY}/${PF}"; then
ewarn "You must rebuild gobject-introspection so that the installed"
ewarn "typelibs and girs are regenerated for the new APIs in glib"
fi
}
pkg_postinst() {
# Inform users about possible breakage when updating glib and not dbus-glib, bug #297483
if has_version dev-libs/dbus-glib; then
ewarn "If you experience a breakage after updating dev-libs/glib try"
ewarn "rebuilding dev-libs/dbus-glib"
fi
if has_version '<x11-libs/gtk+-3.0.12:3'; then
# To have a clear upgrade path for gtk+-3.0.x users, have to resort to
# a warning instead of a blocker
ewarn
ewarn "Using <gtk+-3.0.12:3 with ${P} results in frequent crashes."
ewarn "You should upgrade to a newer version of gtk+:3 immediately."
fi
}
^ permalink raw reply [flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in dev-libs/glib: ChangeLog glib-2.32.1.ebuild
@ 2012-04-14 16:12 Alexis Ballier (aballier)
0 siblings, 0 replies; 5+ messages in thread
From: Alexis Ballier (aballier) @ 2012-04-14 16:12 UTC (permalink / raw
To: gentoo-commits
aballier 12/04/14 16:12:55
Modified: ChangeLog glib-2.32.1.ebuild
Log:
allow to replace lelfutils by libelf. the former isnt keyworded and doesnt build on fbsd while the latter is fine
(Portage version: 2.2.0_alpha100/cvs/Linux x86_64)
Revision Changes Path
1.512 dev-libs/glib/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.512&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.512&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?r1=1.511&r2=1.512
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v
retrieving revision 1.511
retrieving revision 1.512
diff -u -r1.511 -r1.512
--- ChangeLog 14 Apr 2012 04:45:17 -0000 1.511
+++ ChangeLog 14 Apr 2012 16:12:55 -0000 1.512
@@ -1,6 +1,10 @@
# ChangeLog for dev-libs/glib
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.511 2012/04/14 04:45:17 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.512 2012/04/14 16:12:55 aballier Exp $
+
+ 14 Apr 2012; Alexis Ballier <aballier@gentoo.org> glib-2.32.1.ebuild:
+ allow to replace lelfutils by libelf. the former isnt keyworded and doesnt
+ build on fbsd while the latter is fine
14 Apr 2012; Zac Medico <zmedico@gentoo.org> glib-2.32.1.ebuild:
Add ~amd64-linux keyword.
1.3 dev-libs/glib/glib-2.32.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild?r1=1.2&r2=1.3
Index: glib-2.32.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- glib-2.32.1.ebuild 14 Apr 2012 04:45:17 -0000 1.2
+++ glib-2.32.1.ebuild 14 Apr 2012 16:12:55 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild,v 1.2 2012/04/14 04:45:17 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild,v 1.3 2012/04/14 16:12:55 aballier Exp $
EAPI="4"
PYTHON_DEPEND="utils? 2"
@@ -25,7 +25,7 @@
fam? ( virtual/fam )
utils? ( >=dev-util/gdbus-codegen-${PV} )"
DEPEND="${RDEPEND}
- dev-libs/elfutils
+ || ( dev-libs/elfutils dev-libs/libelf )
>=sys-devel/gettext-0.11
>=dev-util/gtk-doc-am-1.15
doc? (
^ permalink raw reply [flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in dev-libs/glib: ChangeLog glib-2.32.1.ebuild
@ 2012-04-16 3:24 Alexandre Rostovtsev (tetromino)
0 siblings, 0 replies; 5+ messages in thread
From: Alexandre Rostovtsev (tetromino) @ 2012-04-16 3:24 UTC (permalink / raw
To: gentoo-commits
tetromino 12/04/16 03:24:01
Modified: ChangeLog glib-2.32.1.ebuild
Log:
Fix building on systems with gnustep-base installed (bug #411981, thanks to Carlos Konstanski et al. for reporting).
(Portage version: 2.2.0_alpha100/cvs/Linux x86_64)
Revision Changes Path
1.514 dev-libs/glib/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.514&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.514&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?r1=1.513&r2=1.514
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v
retrieving revision 1.513
retrieving revision 1.514
diff -u -r1.513 -r1.514
--- ChangeLog 14 Apr 2012 23:23:18 -0000 1.513
+++ ChangeLog 16 Apr 2012 03:24:01 -0000 1.514
@@ -1,6 +1,11 @@
# ChangeLog for dev-libs/glib
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.513 2012/04/14 23:23:18 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.514 2012/04/16 03:24:01 tetromino Exp $
+
+ 16 Apr 2012; Alexandre Rostovtsev <tetromino@gentoo.org> glib-2.32.1.ebuild,
+ +files/glib-2.32.1-gnustep-not-cocoa.patch:
+ Fix building on systems with gnustep-base installed (bug #411981, thanks to
+ Carlos Konstanski et al. for reporting).
14 Apr 2012; Alexandre Rostovtsev <tetromino@gentoo.org> glib-2.32.0.ebuild,
glib-2.32.1.ebuild, +files/glib-2.32.1-fix-libelf-check.patch:
1.5 dev-libs/glib/glib-2.32.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild?r1=1.4&r2=1.5
Index: glib-2.32.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- glib-2.32.1.ebuild 14 Apr 2012 23:23:18 -0000 1.4
+++ glib-2.32.1.ebuild 16 Apr 2012 03:24:01 -0000 1.5
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild,v 1.4 2012/04/14 23:23:18 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild,v 1.5 2012/04/16 03:24:01 tetromino Exp $
EAPI="4"
PYTHON_DEPEND="utils? 2"
@@ -115,6 +115,9 @@
# https://bugzilla.gnome.org/show_bug.cgi?id=673132
epatch "${FILESDIR}/${PN}-2.32.1-fix-libelf-check.patch"
+ # bug #411981, https://bugzilla.gnome.org/show_bug.cgi?id=674172
+ epatch "${FILESDIR}/${PN}-2.32.1-gnustep-not-cocoa.patch"
+
# disable pyc compiling
use test && python_clean_py-compile_files
^ permalink raw reply [flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in dev-libs/glib: ChangeLog glib-2.32.1.ebuild
@ 2012-04-26 14:14 Alexis Ballier (aballier)
0 siblings, 0 replies; 5+ messages in thread
From: Alexis Ballier (aballier) @ 2012-04-26 14:14 UTC (permalink / raw
To: gentoo-commits
aballier 12/04/26 14:14:32
Modified: ChangeLog glib-2.32.1.ebuild
Log:
keyword ~amd64-fbsd
(Portage version: 2.2.0_alpha101/cvs/Linux x86_64)
Revision Changes Path
1.518 dev-libs/glib/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.518&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.518&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?r1=1.517&r2=1.518
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v
retrieving revision 1.517
retrieving revision 1.518
diff -u -r1.517 -r1.518
--- ChangeLog 25 Apr 2012 19:51:43 -0000 1.517
+++ ChangeLog 26 Apr 2012 14:14:32 -0000 1.518
@@ -1,6 +1,9 @@
# ChangeLog for dev-libs/glib
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.517 2012/04/25 19:51:43 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.518 2012/04/26 14:14:32 aballier Exp $
+
+ 26 Apr 2012; Alexis Ballier <aballier@gentoo.org> glib-2.32.1.ebuild:
+ keyword ~amd64-fbsd
25 Apr 2012; Markus Meier <maekke@gentoo.org> glib-2.30.3.ebuild:
arm stable, bug #410611
1.6 dev-libs/glib/glib-2.32.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild?r1=1.5&r2=1.6
Index: glib-2.32.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- glib-2.32.1.ebuild 16 Apr 2012 03:24:01 -0000 1.5
+++ glib-2.32.1.ebuild 26 Apr 2012 14:14:32 -0000 1.6
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild,v 1.5 2012/04/16 03:24:01 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild,v 1.6 2012/04/26 14:14:32 aballier Exp $
EAPI="4"
PYTHON_DEPEND="utils? 2"
@@ -16,7 +16,7 @@
LICENSE="LGPL-2"
SLOT="2"
IUSE="debug doc fam selinux static-libs systemtap test utils xattr"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
RDEPEND="virtual/libiconv
virtual/libffi
^ permalink raw reply [flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in dev-libs/glib: ChangeLog glib-2.32.1.ebuild
@ 2012-04-30 19:17 Samuli Suominen (ssuominen)
0 siblings, 0 replies; 5+ messages in thread
From: Samuli Suominen (ssuominen) @ 2012-04-30 19:17 UTC (permalink / raw
To: gentoo-commits
ssuominen 12/04/30 19:17:07
Modified: ChangeLog glib-2.32.1.ebuild
Log:
Check for CONFIG_INOTIFY_USER wrt #413403
(Portage version: 2.2.0_alpha101/cvs/Linux x86_64)
Revision Changes Path
1.520 dev-libs/glib/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.520&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.520&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?r1=1.519&r2=1.520
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v
retrieving revision 1.519
retrieving revision 1.520
diff -u -r1.519 -r1.520
--- ChangeLog 29 Apr 2012 15:23:06 -0000 1.519
+++ ChangeLog 30 Apr 2012 19:17:06 -0000 1.520
@@ -1,6 +1,9 @@
# ChangeLog for dev-libs/glib
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.519 2012/04/29 15:23:06 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.520 2012/04/30 19:17:06 ssuominen Exp $
+
+ 30 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> glib-2.32.1.ebuild:
+ Check for CONFIG_INOTIFY_USER wrt #413403
29 Apr 2012; Markus Meier <maekke@gentoo.org> glib-2.30.3.ebuild:
x86 stable, bug #410611
1.7 dev-libs/glib/glib-2.32.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild?r1=1.6&r2=1.7
Index: glib-2.32.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- glib-2.32.1.ebuild 26 Apr 2012 14:14:32 -0000 1.6
+++ glib-2.32.1.ebuild 30 Apr 2012 19:17:06 -0000 1.7
@@ -1,12 +1,12 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild,v 1.6 2012/04/26 14:14:32 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild,v 1.7 2012/04/30 19:17:06 ssuominen Exp $
EAPI="4"
PYTHON_DEPEND="utils? 2"
# Avoid runtime dependency on python when USE=test
-inherit autotools gnome.org libtool eutils flag-o-matic gnome2-utils multilib pax-utils python virtualx
+inherit autotools gnome.org libtool eutils flag-o-matic gnome2-utils multilib pax-utils python virtualx linux-info
DESCRIPTION="The GLib library of C routines"
HOMEPAGE="http://www.gtk.org/"
@@ -15,7 +15,7 @@
LICENSE="LGPL-2"
SLOT="2"
-IUSE="debug doc fam selinux static-libs systemtap test utils xattr"
+IUSE="debug doc fam kernel_linux selinux static-libs systemtap test utils xattr"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
RDEPEND="virtual/libiconv
@@ -53,6 +53,11 @@
python_set_active_version 2
python_pkg_setup
fi
+
+ if use kernel_linux ; then
+ CONFIG_CHECK="~INOTIFY_USER"
+ linux-info_pkg_setup
+ fi
}
src_prepare() {
^ permalink raw reply [flat|nested] 5+ messages in thread
end of thread, other threads:[~2012-04-30 19:17 UTC | newest]
Thread overview: 5+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-04-14 3:30 [gentoo-commits] gentoo-x86 commit in dev-libs/glib: ChangeLog glib-2.32.1.ebuild Alexandre Rostovtsev (tetromino)
-- strict thread matches above, loose matches on Subject: below --
2012-04-14 16:12 Alexis Ballier (aballier)
2012-04-16 3:24 Alexandre Rostovtsev (tetromino)
2012-04-26 14:14 Alexis Ballier (aballier)
2012-04-30 19:17 Samuli Suominen (ssuominen)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox