[gentoo-commits] gentoo-x86 commit in net-misc/ps3mediaserver: ps3mediaserver-1.52.1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-misc/ps3mediaserver: ps3mediaserver-1.52.1.ebuild ChangeLog

[Mike Gilbert (floppym)]

floppym     12/04/11 05:19:10

  Modified:             ChangeLog
  Added:                ps3mediaserver-1.52.1.ebuild
  Log:
  Version bump for #411551 by dirtyepic.
  
  (Portage version: 2.2.0_alpha100/cvs/Linux x86_64)

Revision  Changes    Path
1.11                 net-misc/ps3mediaserver/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/ps3mediaserver/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/ps3mediaserver/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/ps3mediaserver/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/ps3mediaserver/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	1 Mar 2012 17:47:41 -0000	1.10
+++ ChangeLog	11 Apr 2012 05:19:10 -0000	1.11
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/ps3mediaserver
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/ps3mediaserver/ChangeLog,v 1.10 2012/03/01 17:47:41 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/ps3mediaserver/ChangeLog,v 1.11 2012/04/11 05:19:10 floppym Exp $
+
+*ps3mediaserver-1.52.1 (11 Apr 2012)
+
+  11 Apr 2012; Mike Gilbert <floppym@gentoo.org> +ps3mediaserver-1.52.1.ebuild:
+  Version bump for #411551 by dirtyepic.
 
   01 Mar 2012; Mike Gilbert <floppym@gentoo.org> ps3mediaserver-1.50.1.ebuild:
   Add graphicsmagick[imagemagick] as an alternative per ssuominen.



1.1                  net-misc/ps3mediaserver/ps3mediaserver-1.52.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/ps3mediaserver/ps3mediaserver-1.52.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/ps3mediaserver/ps3mediaserver-1.52.1.ebuild?rev=1.1&content-type=text/plain

Index: ps3mediaserver-1.52.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/ps3mediaserver/ps3mediaserver-1.52.1.ebuild,v 1.1 2012/04/11 05:19:10 floppym Exp $

EAPI="4"

inherit eutils

DESCRIPTION="DLNA compliant UPNP server for streaming media to Playstation 3"
HOMEPAGE="http://code.google.com/p/ps3mediaserver"
SRC_URI="http://ps3mediaserver.googlecode.com/files/pms-generic-linux-unix-${PV}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="multiuser +transcode tsmuxer"

DEPEND="app-arch/unzip"
RDEPEND=">=virtual/jre-1.6.0
	|| ( media-gfx/imagemagick media-gfx/graphicsmagick[imagemagick] )
	media-libs/libmediainfo
	media-libs/libzen
	tsmuxer? ( media-video/tsmuxer )
	transcode? ( media-video/mplayer[encode] )"

S=${WORKDIR}/pms-${PV}
PMS_HOME=/opt/${PN}

src_prepare() {
	if use multiuser; then
		cat > ${PN} <<-EOF
		#!/bin/sh
		if [ ! -e ~/.${PN} ]; then
			echo "Copying ${PMS_HOME} to ~/.${PN}"
			cp -pPR "${PMS_HOME}" ~/.${PN}
		fi
		export PMS_HOME=~/.${PN}
		exec "\${PMS_HOME}/PMS.sh" "\$@"
		EOF
	else
		cat > ${PN} <<-EOF
		#!/bin/sh
		export PMS_HOME=${PMS_HOME}
		exec "\${PMS_HOME}/PMS.sh" "\$@"
		EOF
	fi

	cat > ${PN}.desktop <<-EOF
	[Desktop Entry]
	Name=PS3 Media Server
	GenericName=Media Server
	Exec=${PN}
	Icon=${PN}
	Type=Application
	Categories=Network;
	EOF

	unzip -j pms.jar resources/images/icon-{32,256}.png || die
}

src_install() {
	dobin ${PN}

	exeinto ${PMS_HOME}
	doexe PMS.sh

	insinto ${PMS_HOME}
	doins -r pms.jar *.conf documentation plugins renderers *.xml
	use tsmuxer && dosym /opt/tsmuxer/bin/tsMuxeR ${PMS_HOME}/linux/tsMuxeR
	dodoc CHANGELOG README.md

	insinto /usr/share/icons/hicolor/32x32/apps
	newins icon-32.png ${PN}.png
	insinto /usr/share/icons/hicolor/256x256/apps
	newins icon-256.png ${PN}.png

	domenu ${PN}.desktop

	newconfd "${FILESDIR}/${PN}.confd" ${PN}
	newinitd "${FILESDIR}/${PN}.initd" ${PN}
}

pkg_postinst() {
	ewarn "Don't forget to disable transcoding engines for software"
	ewarn "that you don't have installed (such as having the VLC"
	ewarn "transcoding engine enabled when you only have mencoder)."
	if use multiuser; then
		echo
		ewarn "Make sure to refresh the .${PN} in your home directory if you are"
		ewarn "upgrading from a previous version."
	fi
}