* [gentoo-commits] gentoo-x86 commit in www-client/epiphany: ChangeLog epiphany-3.2.2.ebuild
@ 2012-04-09 11:24 Gilles Dartiguelongue (eva)
0 siblings, 0 replies; only message in thread
From: Gilles Dartiguelongue (eva) @ 2012-04-09 11:24 UTC (permalink / raw
To: gentoo-commits
eva 12/04/09 11:24:38
Modified: ChangeLog
Added: epiphany-3.2.2.ebuild
Log:
Version bump.
(Portage version: 2.2.0_alpha100/cvs/Linux x86_64)
Revision Changes Path
1.280 www-client/epiphany/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/epiphany/ChangeLog?rev=1.280&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/epiphany/ChangeLog?rev=1.280&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/epiphany/ChangeLog?r1=1.279&r2=1.280
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v
retrieving revision 1.279
retrieving revision 1.280
diff -u -r1.279 -r1.280
--- ChangeLog 6 Mar 2012 16:24:34 -0000 1.279
+++ ChangeLog 9 Apr 2012 11:24:38 -0000 1.280
@@ -1,6 +1,11 @@
# ChangeLog for www-client/epiphany
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v 1.279 2012/03/06 16:24:34 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v 1.280 2012/04/09 11:24:38 eva Exp $
+
+*epiphany-3.2.2 (09 Apr 2012)
+
+ 09 Apr 2012; Gilles Dartiguelongue <eva@gentoo.org> +epiphany-3.2.2.ebuild:
+ Version bump.
06 Mar 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
epiphany-3.2.1-r1.ebuild:
1.1 www-client/epiphany/epiphany-3.2.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/epiphany/epiphany-3.2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/epiphany/epiphany-3.2.2.ebuild?rev=1.1&content-type=text/plain
Index: epiphany-3.2.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/epiphany-3.2.2.ebuild,v 1.1 2012/04/09 11:24:38 eva Exp $
EAPI="4"
GCONF_DEBUG="yes"
inherit autotools eutils gnome2 pax-utils
DESCRIPTION="GNOME webbrowser based on Webkit"
HOMEPAGE="http://projects.gnome.org/epiphany/"
LICENSE="GPL-2"
SLOT="0"
IUSE="avahi doc +introspection +networkmanager +nss test"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
# XXX: Should we add seed support? Seed seems to be unmaintained now.
# Require {glib,gdbus-codegen}-2.30.0 due to GDBus API changes between 2.29.92
# and 2.30.0
COMMON_DEPEND=">=dev-libs/glib-2.30.0:2
>=x11-libs/gtk+-3.0.2:3[introspection?]
>=dev-libs/libxml2-2.6.12:2
>=dev-libs/libxslt-1.1.7
>=app-text/iso-codes-0.35
>=net-libs/webkit-gtk-1.6.1:3[introspection?]
>=net-libs/libsoup-gnome-2.33.1:2.4
>=gnome-base/gnome-keyring-2.26.0
>=gnome-base/gsettings-desktop-schemas-0.0.1
>=x11-libs/libnotify-0.5.1
x11-libs/libICE
x11-libs/libSM
x11-libs/libX11
app-misc/ca-certificates
x11-themes/gnome-icon-theme
avahi? ( >=net-dns/avahi-0.6.22 )
introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
nss? ( dev-libs/nss )"
# networkmanager is used purely via dbus
RDEPEND="${COMMON_DEPEND}
x11-themes/gnome-icon-theme-symbolic
networkmanager? ( >=net-misc/networkmanager-0.8.997 )"
# paxctl needed for bug #407085
DEPEND="${COMMON_DEPEND}
app-text/gnome-doc-utils
>=dev-util/gdbus-codegen-2.30.0
>=dev-util/intltool-0.40
dev-util/pkgconfig
sys-apps/paxctl
sys-devel/gettext
doc? ( >=dev-util/gtk-doc-1 )"
pkg_setup() {
DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS README TODO"
G2CONF="${G2CONF}
--enable-shared
--disable-schemas-compile
--disable-scrollkeeper
--disable-static
--with-distributor-name=Gentoo
--with-ca-file=${EPREFIX}/etc/ssl/certs/ca-certificates.crt
$(use_enable avahi zeroconf)
$(use_enable introspection)
$(use_enable nss)
$(use_enable test tests)"
# Upstream no longer makes networkmanager optional, but we still want
# to make it possible for prefix users to use epiphany
use networkmanager && CFLAGS="${CFLAGS} -DENABLE_NETWORK_MANAGER"
}
src_prepare() {
# Make networkmanager optional for prefix people
epatch "${FILESDIR}/${PN}-3.2.0-optional-networkmanager.patch"
# Build-time segfaults under PaX with USE=introspection
epatch "${FILESDIR}/${PN}-3.2.1-paxctl-introspection.patch"
cp "${FILESDIR}/gir-paxctl-lt-wrapper" \
"${FILESDIR}/paxctl.sh" "${S}/" || die
sed -e "s:@S@:${S}:" -i gir-paxctl-lt-wrapper || die
eautoreconf
gnome2_src_prepare
}
src_install() {
gnome2_src_install
pax-mark m "${ED}usr/bin/epiphany"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-04-09 11:24 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-04-09 11:24 [gentoo-commits] gentoo-x86 commit in www-client/epiphany: ChangeLog epiphany-3.2.2.ebuild Gilles Dartiguelongue (eva)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox