[gentoo-commits] gentoo-x86 commit in media-video/mkvtoolnix: mkvtoolnix-5.5.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in media-video/mkvtoolnix: mkvtoolnix-5.5.0.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    12/04/08 07:40:03

  Modified:             ChangeLog
  Added:                mkvtoolnix-5.5.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha100/cvs/Linux x86_64)

Revision  Changes    Path
1.161                media-video/mkvtoolnix/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/ChangeLog?rev=1.161&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/ChangeLog?rev=1.161&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/ChangeLog?r1=1.160&r2=1.161

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v
retrieving revision 1.160
retrieving revision 1.161
diff -u -r1.160 -r1.161
--- ChangeLog	25 Mar 2012 08:17:16 -0000	1.160
+++ ChangeLog	8 Apr 2012 07:40:03 -0000	1.161
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/mkvtoolnix
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v 1.160 2012/03/25 08:17:16 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v 1.161 2012/04/08 07:40:03 radhermit Exp $
+
+*mkvtoolnix-5.5.0 (08 Apr 2012)
+
+  08 Apr 2012; Tim Harder <radhermit@gentoo.org> +mkvtoolnix-5.5.0.ebuild,
+  +files/mkvtoolnix-5.5.0-system-pugixml.patch:
+  Version bump.
 
   25 Mar 2012; Tim Harder <radhermit@gentoo.org> -mkvtoolnix-5.2.1.ebuild,
   -mkvtoolnix-5.3.0.ebuild:



1.1                  media-video/mkvtoolnix/mkvtoolnix-5.5.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-5.5.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-5.5.0.ebuild?rev=1.1&content-type=text/plain

Index: mkvtoolnix-5.5.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-5.5.0.ebuild,v 1.1 2012/04/08 07:40:03 radhermit Exp $

EAPI=4

inherit wxwidgets eutils

DESCRIPTION="Tools to create, alter, and inspect Matroska files"
HOMEPAGE="http://www.bunkus.org/videotools/mkvtoolnix"
SRC_URI="http://www.bunkus.org/videotools/mkvtoolnix/sources/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="bzip2 debug lzo pch qt4 wxwidgets"

RDEPEND="
	>=dev-libs/libebml-1.2.2
	>=media-libs/libmatroska-1.3.0
	>=dev-libs/boost-1.46.0
	dev-libs/pugixml
	media-libs/flac
	media-libs/libogg
	media-libs/libvorbis
	sys-apps/file
	>=sys-devel/gcc-4.6
	sys-libs/zlib
	bzip2? ( app-arch/bzip2 )
	lzo? ( dev-libs/lzo )
	qt4? (
		x11-libs/qt-core:4
		x11-libs/qt-gui:4
	)
	wxwidgets? ( x11-libs/wxGTK:2.8[X] )
"
DEPEND="${RDEPEND}
	dev-ruby/rake
	dev-util/pkgconfig
"

src_prepare() {
	epatch "${FILESDIR}"/${P}-system-pugixml.patch
}

src_configure() {
	local myconf

	use pch || myconf+=" --disable-precompiled-headers"

	if use wxwidgets ; then
		WX_GTK_VER="2.8"
		need-wxwidgets unicode
		myconf+=" --with-wx-config=${WX_CONFIG}"
	fi

	econf \
		$(use_enable bzip2 bz2) \
		$(use_enable debug) \
		$(use_enable lzo) \
		$(use_enable qt4 qt) \
		$(use_enable wxwidgets) \
		${myconf} \
		--with-boost-regex=boost_regex \
		--with-boost-filesystem=boost_filesystem \
		--with-boost-system=boost_system \
		--without-curl
}

src_compile() {
	rake || die "rake failed"
}

src_install() {
	# Don't run strip while installing stuff, leave to portage the job.
	DESTDIR="${D}" rake install || die

	dodoc AUTHORS ChangeLog README TODO
	doman doc/man/*.1
}