* [gentoo-commits] gentoo-x86 commit in media-video/mplayer: ChangeLog mplayer-1.0_rc4_p20120405.ebuild
@ 2012-04-05 11:57 Alexis Ballier (aballier)
0 siblings, 0 replies; 2+ messages in thread
From: Alexis Ballier (aballier) @ 2012-04-05 11:57 UTC (permalink / raw
To: gentoo-commits
aballier 12/04/05 11:57:16
Modified: ChangeLog
Added: mplayer-1.0_rc4_p20120405.ebuild
Log:
bump a new snapshot
(Portage version: 2.2.0_alpha99/cvs/Linux x86_64)
Revision Changes Path
1.845 media-video/mplayer/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mplayer/ChangeLog?rev=1.845&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mplayer/ChangeLog?rev=1.845&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mplayer/ChangeLog?r1=1.844&r2=1.845
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/mplayer/ChangeLog,v
retrieving revision 1.844
retrieving revision 1.845
diff -u -r1.844 -r1.845
--- ChangeLog 18 Mar 2012 13:47:12 -0000 1.844
+++ ChangeLog 5 Apr 2012 11:57:16 -0000 1.845
@@ -1,6 +1,12 @@
# ChangeLog for media-video/mplayer
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mplayer/ChangeLog,v 1.844 2012/03/18 13:47:12 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mplayer/ChangeLog,v 1.845 2012/04/05 11:57:16 aballier Exp $
+
+*mplayer-1.0_rc4_p20120405 (05 Apr 2012)
+
+ 05 Apr 2012; Alexis Ballier <aballier@gentoo.org> +files/ffmpeg2.patch,
+ +mplayer-1.0_rc4_p20120405.ebuild:
+ bump a new snapshot
18 Mar 2012; Samuli Suominen <ssuominen@gentoo.org>
mplayer-1.0_rc4_p20110322-r1.ebuild, mplayer-1.0_rc4_p20120213.ebuild,
1.1 media-video/mplayer/mplayer-1.0_rc4_p20120405.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mplayer/mplayer-1.0_rc4_p20120405.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mplayer/mplayer-1.0_rc4_p20120405.ebuild?rev=1.1&content-type=text/plain
Index: mplayer-1.0_rc4_p20120405.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/mplayer/mplayer-1.0_rc4_p20120405.ebuild,v 1.1 2012/04/05 11:57:16 aballier Exp $
EAPI=4
EGIT_REPO_URI="git://git.videolan.org/ffmpeg.git"
ESVN_REPO_URI="svn://svn.mplayerhq.hu/mplayer/trunk"
[[ ${PV} = *9999* ]] && SVN_ECLASS="subversion git-2" || SVN_ECLASS=""
inherit toolchain-funcs eutils flag-o-matic multilib base ${SVN_ECLASS}
IUSE="3dnow 3dnowext +a52 aalib +alsa altivec aqua +ass bidi bindist bl bluray
bs2b cddb +cdio cdparanoia cpudetection debug dga
directfb doc +dts +dv dvb +dvd +dvdnav dxr3 +enca +encode faac +faad fbcon
ftp gif ggi gsm +iconv ipv6 jack joystick jpeg jpeg2k kernel_linux ladspa
libcaca libmpeg2 lirc +live lzo mad md5sum +mmx mmxext mng +mp3 nas
+network nut openal +opengl +osdmenu oss png pnm pulseaudio pvr +quicktime
radio +rar +real +rtc rtmp samba +shm sdl +speex sse sse2 ssse3
tga +theora +tremor +truetype +toolame +twolame +unicode v4l vdpau vidix
+vorbis win32codecs +X +x264 xanim xinerama +xscreensaver +xv +xvid xvmc
zoran"
VIDEO_CARDS="s3virge mga tdfx"
for x in ${VIDEO_CARDS}; do
IUSE+=" video_cards_${x}"
done
FONT_URI="
mirror://mplayer/releases/fonts/font-arial-iso-8859-1.tar.bz2
mirror://mplayer/releases/fonts/font-arial-iso-8859-2.tar.bz2
mirror://mplayer/releases/fonts/font-arial-cp1250.tar.bz2
"
if [[ ${PV} == *9999* ]]; then
RELEASE_URI=""
else
RELEASE_URI="mirror://gentoo/${P}.tar.xz"
fi
SRC_URI="${RELEASE_URI}
!truetype? ( ${FONT_URI} )"
DESCRIPTION="Media Player for Linux"
HOMEPAGE="http://www.mplayerhq.hu/"
FONT_RDEPS="
virtual/ttf-fonts
media-libs/fontconfig
>=media-libs/freetype-2.2.1:2
"
X_RDEPS="
x11-libs/libXext
x11-libs/libXxf86vm
"
# Rar: althrought -gpl version is nice, it cant do most functions normal rars can
# nemesi? ( net-libs/libnemesi )
RDEPEND+="
sys-libs/ncurses
app-arch/bzip2
sys-libs/zlib
>=media-video/ffmpeg-0.10
!bindist? (
x86? (
win32codecs? ( media-libs/win32codecs )
)
)
a52? ( media-libs/a52dec )
aalib? ( media-libs/aalib )
alsa? ( media-libs/alsa-lib )
ass? ( >=media-libs/libass-0.9.10[enca?] )
bidi? ( dev-libs/fribidi )
bluray? ( >=media-libs/libbluray-0.2.1 )
bs2b? ( media-libs/libbs2b )
cdio? ( dev-libs/libcdio )
cdparanoia? ( !cdio? ( media-sound/cdparanoia ) )
dga? ( x11-libs/libXxf86dga )
directfb? ( dev-libs/DirectFB )
dts? ( media-libs/libdca )
dv? ( media-libs/libdv )
dvb? ( virtual/linuxtv-dvb-headers )
dvd? ( >=media-libs/libdvdread-4.1.3 )
dvdnav? ( >=media-libs/libdvdnav-4.1.3 )
encode? (
!twolame? ( toolame? ( media-sound/toolame ) )
twolame? ( media-sound/twolame )
faac? ( media-libs/faac )
mp3? ( media-sound/lame )
x264? ( >=media-libs/x264-0.0.20100423 )
xvid? ( media-libs/xvid )
)
enca? ( app-i18n/enca )
faad? ( media-libs/faad2 )
ggi? ( media-libs/libggi media-libs/libggiwmh )
gif? ( media-libs/giflib )
gsm? ( media-sound/gsm )
iconv? ( virtual/libiconv )
jack? ( media-sound/jack-audio-connection-kit )
jpeg? ( virtual/jpeg )
jpeg2k? ( media-libs/openjpeg )
ladspa? ( media-libs/ladspa-sdk )
libcaca? ( media-libs/libcaca )
libmpeg2? ( media-libs/libmpeg2 )
lirc? ( app-misc/lirc )
live? ( media-plugins/live )
lzo? ( >=dev-libs/lzo-2 )
mad? ( media-libs/libmad )
mng? ( media-libs/libmng )
mp3? ( media-sound/mpg123 )
nas? ( media-libs/nas )
nut? ( >=media-libs/libnut-661 )
openal? ( media-libs/openal )
opengl? ( virtual/opengl )
png? ( media-libs/libpng )
pnm? ( media-libs/netpbm )
pulseaudio? ( media-sound/pulseaudio )
rar? (
|| (
app-arch/unrar
app-arch/rar
)
)
rtmp? ( media-video/rtmpdump )
samba? ( net-fs/samba )
sdl? ( media-libs/libsdl )
speex? ( media-libs/speex )
theora? ( media-libs/libtheora[encode?] )
truetype? ( ${FONT_RDEPS} )
vdpau? ( x11-libs/libvdpau )
vorbis? ( media-libs/libvorbis )
X? ( ${X_RDEPS} )
xanim? ( media-video/xanim )
xinerama? ( x11-libs/libXinerama )
xscreensaver? ( x11-libs/libXScrnSaver )
xv? ( x11-libs/libXv )
xvmc? ( x11-libs/libXvMC )
"
X_DEPS="
x11-proto/videoproto
x11-proto/xf86vidmodeproto
"
ASM_DEP="dev-lang/yasm"
DEPEND="${RDEPEND}
dev-util/pkgconfig
dga? ( x11-proto/xf86dgaproto )
dxr3? ( media-video/em8300-libraries )
X? ( ${X_DEPS} )
xinerama? ( x11-proto/xineramaproto )
xscreensaver? ( x11-proto/scrnsaverproto )
amd64? ( ${ASM_DEP} )
doc? (
dev-libs/libxslt app-text/docbook-xml-dtd
app-text/docbook-xsl-stylesheets
)
x86? ( ${ASM_DEP} )
x86-fbsd? ( ${ASM_DEP} )
"
SLOT="0"
LICENSE="GPL-2"
if [[ ${PV} != *9999* ]]; then
KEYWORDS="~amd64 ~hppa ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
else
KEYWORDS=""
fi
# faac codecs are nonfree, win32codecs are nonfree
# libcdio support: prefer libcdio over cdparanoia and don't check for cddb w/cdio
# dvd navigation requires dvd read support
# ass and freetype font require iconv and ass requires freetype fonts
# unicode transformations are usefull only with iconv
# libvorbis require external tremor to work
# radio requires oss or alsa backend
# xvmc requires xvideo support
REQUIRED_USE="bindist? ( !faac !win32codecs )
dvdnav? ( dvd )
ass? ( truetype )
truetype? ( iconv )
dxr3? ( X )
ggi? ( X )
xinerama? ( X )
dga? ( X )
opengl? ( X )
osdmenu? ( X )
vdpau? ( X )
vidix? ( X )
xscreensaver? ( X )
xv? ( X )
xvmc? ( xv )"
PATCHES=( "${FILESDIR}/ffmpeg.patch" "${FILESDIR}/ffmpeg2.patch" )
pkg_setup() {
if [[ ${PV} == *9999* ]]; then
elog
elog "This is a live ebuild which installs the latest from upstream's"
elog "subversion repository, and is unsupported by Gentoo."
elog "Everything but bugs in the ebuild itself will be ignored."
elog
fi
if use cpudetection; then
ewarn
ewarn "You've enabled the cpudetection flag. This feature is"
ewarn "included mainly for people who want to use the same"
ewarn "binary on another system with a different CPU architecture."
ewarn "MPlayer will already detect your CPU settings by default at"
ewarn "buildtime; this flag is used for runtime detection."
ewarn "You won't need this turned on if you are only building"
ewarn "mplayer for this system. Also, if your compile fails, try"
ewarn "disabling this use flag."
fi
}
src_unpack() {
if [[ ${PV} = *9999* ]]; then
subversion_src_unpack
cd "${WORKDIR}"
rm -rf "${WORKDIR}/${P}/ffmpeg/"
( S="${WORKDIR}/${P}/ffmpeg/" git-2_src_unpack )
cd "${S}"
cp "${FILESDIR}/dump_ffmpeg.sh" . || die
chmod +x dump_ffmpeg.sh
./dump_ffmpeg.sh || die
else
unpack ${A}
fi
if ! use truetype; then
unpack font-arial-iso-8859-1.tar.bz2 \
font-arial-iso-8859-2.tar.bz2 \
font-arial-cp1250.tar.bz2
fi
}
src_prepare() {
local svf=snapshot_version
if [[ ${PV} = *9999* ]]; then
# Set SVN version manually
subversion_wc_info
printf "${ESVN_WC_REVISION}" > $svf
fi
[ -f "$svf" ] || die "Missing ${svf}. Did you generate your snapshot with prepare_mplayer.sh?"
local sv=$(<$svf)
printf "SVN-r${sv} (Gentoo)" > VERSION
# fix path to bash executable in configure scripts
sed -i -e "1c\#!${EPREFIX}/bin/bash" configure version.sh || die
base_src_prepare
}
src_configure() {
local myconf=""
local uses i
# set LINGUAS
[[ -n $LINGUAS ]] && LINGUAS="${LINGUAS/da/dk}"
# mplayer ebuild uses "use foo || --disable-foo" to forcibly disable
# compilation in almost every situation. The reason for this is
# because if --enable is used, it will force the build of that option,
# regardless of whether the dependency is available or not.
###################
#Optional features#
###################
# disable svga since we don't want it
# disable arts since we don't have kde3
# always disable internal ass
myconf+="
--disable-svga --disable-svgalib_helper
--disable-ass-internal
--disable-arts
--disable-kai
$(use_enable network networking)
$(use_enable joystick)
"
uses="ass bl bluray enca ftp rtc" # nemesi <- not working with in-tree ebuild
myconf+=" --disable-nemesi" # nemesi automagic disable
for i in ${uses}; do
use ${i} || myconf+=" --disable-${i}"
done
use bidi || myconf+=" --disable-fribidi"
use ipv6 || myconf+=" --disable-inet6"
use nut || myconf+=" --disable-libnut"
use rar || myconf+=" --disable-unrarexec"
use samba || myconf+=" --disable-smb"
use lirc || myconf+=" --disable-lirc --disable-lircc --disable-apple-ir"
# libcdio support: prefer libcdio over cdparanoia
# don't check for cddb w/cdio
if use cdio; then
myconf+=" --disable-cdparanoia"
else
myconf+=" --disable-libcdio"
use cdparanoia || myconf+=" --disable-cdparanoia"
use cddb || myconf+=" --disable-cddb"
fi
################################
# DVD read, navigation support #
################################
#
# dvdread - accessing a DVD
# dvdnav - navigation of menus
#
# use external libdvdcss, dvdread and dvdnav
myconf+=" --disable-dvdread-internal --disable-libdvdcss-internal"
use dvd || myconf+=" --disable-dvdread"
use dvdnav || myconf+=" --disable-dvdnav"
#############
# Subtitles #
#############
#
# SRT/ASS/SSA (subtitles) requires freetype support
# freetype support requires iconv
# iconv optionally can use unicode
use truetype || myconf+=" --disable-freetype"
use iconv || myconf+=" --disable-iconv --charset=noconv"
use iconv && use unicode && myconf+=" --charset=UTF-8"
#####################################
# DVB / Video4Linux / Radio support #
#####################################
myconf+=" --disable-tv-bsdbt848"
# broken upstream, won't work with recent kernels
myconf+=" --disable-ivtv"
# gone since linux-headers-2.6.38
myconf+=" --disable-tv-v4l1"
if { use dvb || use v4l || use pvr || use radio; }; then
use dvb || myconf+=" --disable-dvb"
use pvr || myconf+=" --disable-pvr"
use v4l || myconf+=" --disable-tv-v4l2"
if use radio && { use dvb || use v4l; }; then
myconf+="
--enable-radio
$(use_enable encode radio-capture)
"
else
myconf+="
--disable-radio-v4l2
--disable-radio-bsdbt848
"
fi
else
myconf+="
--disable-tv
--disable-tv-v4l2
--disable-radio
--disable-radio-v4l2
--disable-radio-bsdbt848
--disable-dvb
--disable-v4l2
--disable-pvr"
fi
##########
# Codecs #
##########
myconf+=" --disable-musepack" # Use internal musepack codecs for SV7 and SV8 support
myconf+=" --disable-libmpeg2-internal" # always use system media-libs/libmpeg2
use dts || myconf+=" --disable-libdca"
# Disable internal mp3lib, bug #384849
# Samuli Suominen: Looks like MPlayer in Portage is using internal mp3lib by
# default, where as mpg123 upstream has incorporated all the optimizations
# from mplayer's mp3lib in libmpg123 and more.
# It makes very little sense to use the internal copy as default anymore.
myconf+=" --disable-mp3lib"
if ! use mp3; then
myconf+="
--disable-mp3lame
--disable-mpg123
"
fi
uses="a52 bs2b dv gsm lzo rtmp"
for i in ${uses}; do
use ${i} || myconf+=" --disable-lib${i}"
done
uses="faad gif jpeg libmpeg2 live mad mng png pnm speex tga theora xanim"
for i in ${uses}; do
use ${i} || myconf+=" --disable-${i}"
done
use jpeg2k || myconf+=" --disable-libopenjpeg"
if use vorbis || use tremor; then
use tremor || myconf+=" --disable-tremor-internal"
use vorbis || myconf+=" --disable-libvorbis"
else
myconf+="
--disable-tremor-internal
--disable-tremor
--disable-libvorbis
"
fi
# Encoding
uses="faac x264 xvid toolame twolame"
if use encode; then
for i in ${uses}; do
use ${i} || myconf+=" --disable-${i}"
done
else
myconf+=" --disable-mencoder"
for i in ${uses}; do
myconf+=" --disable-${i}"
use ${i} && elog "Useflag \"${i}\" will only be useful for encoding, i.e., with \"encode\" useflag enabled."
done
fi
#################
# Binary codecs #
#################
# bug 213836
if ! use x86 || ! use win32codecs; then
use quicktime || myconf+=" --disable-qtx"
fi
######################
# RealPlayer support #
######################
# Realplayer support shows up in four places:
# - libavcodec (internal)
# - win32codecs
# - realcodecs (win32codecs libs)
# - realcodecs (realplayer libs)
# internal
use real || myconf+=" --disable-real"
# Real binary codec support only available on x86, amd64
if use real; then
use x86 && myconf+=" --codecsdir=/opt/RealPlayer/codecs"
use amd64 && myconf+=" --codecsdir=/usr/$(get_libdir)/codecs"
fi
myconf+=" $(use_enable win32codecs win32dll)"
################
# Video Output #
################
uses="directfb md5sum sdl"
for i in ${uses}; do
use ${i} || myconf+=" --disable-${i}"
done
use aalib || myconf+=" --disable-aa"
use fbcon || myconf+=" --disable-fbdev"
use fbcon && use video_cards_s3virge && myconf+=" --enable-s3fb"
use libcaca || myconf+=" --disable-caca"
use zoran || myconf+=" --disable-zr"
if ! use kernel_linux || ! use video_cards_mga; then
myconf+=" --disable-mga --disable-xmga"
fi
if use video_cards_tdfx; then
myconf+="
$(use_enable video_cards_tdfx tdfxvid)
$(use_enable fbcon tdfxfb)
"
else
myconf+="
--disable-3dfx
--disable-tdfxvid
--disable-tdfxfb
"
fi
# sun card, disable by default, see bug #258729
myconf+=" --disable-xvr100"
################
# Audio Output #
################
myconf+=" --disable-esd"
uses="alsa jack ladspa nas openal"
for i in ${uses}; do
use ${i} || myconf+=" --disable-${i}"
done
use pulseaudio || myconf+=" --disable-pulse"
if ! use radio; then
use oss || myconf+=" --disable-ossaudio"
fi
####################
# Advanced Options #
####################
# Platform specific flags, hardcoded on amd64 (see below)
use cpudetection && myconf+=" --enable-runtime-cpudetection"
uses="3dnow 3dnowext altivec mmx mmxext shm sse sse2 ssse3"
for i in ${uses}; do
myconf+=" $(use_enable ${i})"
done
use debug && myconf+=" --enable-debug=3"
if use x86 && gcc-specs-pie; then
filter-flags -fPIC -fPIE
append-ldflags -nopie
fi
###########################
# X enabled configuration #
###########################
myconf+=" --disable-gui"
myconf+=" --disable-vesa"
uses="dxr3 ggi vdpau xinerama xv"
for i in ${uses}; do
use ${i} || myconf+=" --disable-${i}"
done
use dga || myconf+=" --disable-dga1 --disable-dga2"
use opengl || myconf+=" --disable-gl"
use osdmenu && myconf+=" --enable-menu"
use vidix || myconf+=" --disable-vidix --disable-vidix-pcidb"
use xscreensaver || myconf+=" --disable-xss"
use X || myconf+=" --disable-x11"
if use xvmc; then
myconf+=" --enable-xvmc --with-xvmclib=XvMCW"
else
myconf+=" --disable-xvmc"
fi
############################
# OSX (aqua) configuration #
############################
if use aqua; then
myconf+="
--enable-macosx-finder
--enable-macosx-bundle
"
fi
./configure \
--cc="$(tc-getCC)" \
--host-cc="$(tc-getBUILD_CC)" \
--prefix="${EPREFIX}/usr" \
--bindir="${EPREFIX}/usr/bin" \
--libdir="${EPREFIX}/usr/$(get_libdir)" \
--confdir="${EPREFIX}/etc/mplayer" \
--datadir="${EPREFIX}/usr/share/mplayer${namesuf}" \
--mandir="${EPREFIX}/usr/share/man" \
--disable-ffmpeg_a \
${myconf} || die
}
src_compile() {
base_src_compile
# Build only user-requested docs if they're available.
if use doc ; then
# select available languages from $LINGUAS
LINGUAS=${LINGUAS/zh/zh_CN}
local ALLOWED_LINGUAS="cs de en es fr hu it pl ru zh_CN"
local BUILT_DOCS=""
for i in ${LINGUAS} ; do
has ${i} ${ALLOWED_LINGUAS} && BUILT_DOCS+=" ${i}"
done
if [[ -z $BUILT_DOCS ]]; then
emake -j1 html-chunked
else
for i in ${BUILT_DOCS}; do
emake -j1 html-chunked-${i}
done
fi
fi
}
src_install() {
local i
emake \
DESTDIR="${D}" \
INSTALLSTRIP="" \
install
dodoc AUTHORS Changelog Copyright README etc/codecs.conf
docinto tech/
dodoc DOCS/tech/{*.txt,MAINTAINERS,mpsub.sub,playtree,TODO,wishlist}
docinto TOOLS/
dodoc -r TOOLS
if use real; then
docinto tech/realcodecs/
dodoc DOCS/tech/realcodecs/*
fi
docinto tech/mirrors/
dodoc DOCS/tech/mirrors/*
if use doc; then
docinto html/
dohtml -r "${S}"/DOCS/HTML/*
fi
if ! use truetype; then
dodir /usr/share/mplayer/fonts
# Do this generic, as the mplayer people like to change the structure
# of their zips ...
for i in $(find "${WORKDIR}/" -type d -name 'font-arial-*'); do
cp -pPR "${i}" "${ED}/usr/share/mplayer/fonts"
done
# Fix the font symlink ...
rm -rf "${ED}/usr/share/mplayer/font"
dosym fonts/font-arial-14-iso-8859-1 /usr/share/mplayer/font
fi
insinto /etc/mplayer
newins "${S}/etc/example.conf" mplayer.conf
cat >> "${ED}/etc/mplayer/mplayer.conf" << _EOF_
# Config options can be section specific, global
# options should go in the default section
[default]
_EOF_
doins "${S}/etc/input.conf"
if use osdmenu; then
doins "${S}/etc/menu.conf"
fi
if use truetype; then
cat >> "${ED}/etc/mplayer/mplayer.conf" << _EOF_
fontconfig=1
subfont-osd-scale=4
subfont-text-scale=3
_EOF_
fi
# bug 256203
if use rar; then
cat >> "${ED}/etc/mplayer/mplayer.conf" << _EOF_
unrarexec=${EPREFIX}/usr/bin/unrar
_EOF_
fi
dosym ../../../etc/mplayer/mplayer.conf /usr/share/mplayer/mplayer.conf
newbin "${S}/TOOLS/midentify.sh" midentify
}
pkg_preinst() {
[[ -d ${EROOT}/usr/share/mplayer/Skin/default ]] && \
rm -rf "${EROOT}/usr/share/mplayer/Skin/default"
}
pkg_postrm() {
# Cleanup stale symlinks
[ -L "${EROOT}/usr/share/mplayer/font" -a \
! -e "${EROOT}/usr/share/mplayer/font" ] && \
rm -f "${EROOT}/usr/share/mplayer/font"
[ -L "${EROOT}/usr/share/mplayer/subfont.ttf" -a \
! -e "${EROOT}/usr/share/mplayer/subfont.ttf" ] && \
rm -f "${EROOT}/usr/share/mplayer/subfont.ttf"
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-video/mplayer: ChangeLog mplayer-1.0_rc4_p20120405.ebuild
@ 2012-04-05 18:42 Mike Frysinger (vapier)
0 siblings, 0 replies; 2+ messages in thread
From: Mike Frysinger (vapier) @ 2012-04-05 18:42 UTC (permalink / raw
To: gentoo-commits
vapier 12/04/05 18:42:48
Modified: ChangeLog mplayer-1.0_rc4_p20120405.ebuild
Log:
Fix pkg-config handling with libdvd{nav,read} #410189.
(Portage version: 2.2.0_alpha95/cvs/Linux x86_64)
Revision Changes Path
1.847 media-video/mplayer/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mplayer/ChangeLog?rev=1.847&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mplayer/ChangeLog?rev=1.847&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mplayer/ChangeLog?r1=1.846&r2=1.847
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/mplayer/ChangeLog,v
retrieving revision 1.846
retrieving revision 1.847
diff -u -r1.846 -r1.847
--- ChangeLog 5 Apr 2012 12:02:56 -0000 1.846
+++ ChangeLog 5 Apr 2012 18:42:48 -0000 1.847
@@ -1,6 +1,10 @@
# ChangeLog for media-video/mplayer
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mplayer/ChangeLog,v 1.846 2012/04/05 12:02:56 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mplayer/ChangeLog,v 1.847 2012/04/05 18:42:48 vapier Exp $
+
+ 05 Apr 2012; Mike Frysinger <vapier@gentoo.org>
+ mplayer-1.0_rc4_p20120405.ebuild, +files/mplayer-1.0_rc4-pkg-config.patch:
+ Fix pkg-config handling with libdvd{nav,read} #410189.
05 Apr 2012; Alexis Ballier <aballier@gentoo.org>
mplayer-1.0_rc4_p20120405.ebuild, mplayer-9999.ebuild:
1.3 media-video/mplayer/mplayer-1.0_rc4_p20120405.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mplayer/mplayer-1.0_rc4_p20120405.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mplayer/mplayer-1.0_rc4_p20120405.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mplayer/mplayer-1.0_rc4_p20120405.ebuild?r1=1.2&r2=1.3
Index: mplayer-1.0_rc4_p20120405.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/mplayer/mplayer-1.0_rc4_p20120405.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- mplayer-1.0_rc4_p20120405.ebuild 5 Apr 2012 12:02:56 -0000 1.2
+++ mplayer-1.0_rc4_p20120405.ebuild 5 Apr 2012 18:42:48 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mplayer/mplayer-1.0_rc4_p20120405.ebuild,v 1.2 2012/04/05 12:02:56 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mplayer/mplayer-1.0_rc4_p20120405.ebuild,v 1.3 2012/04/05 18:42:48 vapier Exp $
EAPI=4
@@ -187,7 +187,11 @@
xv? ( X )
xvmc? ( xv )"
-PATCHES=( "${FILESDIR}/ffmpeg.patch" "${FILESDIR}/ffmpeg2.patch" )
+PATCHES=(
+ "${FILESDIR}/ffmpeg.patch"
+ "${FILESDIR}/ffmpeg2.patch"
+ "${FILESDIR}/${PN}-1.0_rc4-pkg-config.patch"
+)
pkg_setup() {
if [[ ${PV} == *9999* ]]; then
@@ -529,6 +533,7 @@
"
fi
+ tc-export PKG_CONFIG
./configure \
--cc="$(tc-getCC)" \
--host-cc="$(tc-getBUILD_CC)" \
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2012-04-05 18:43 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-04-05 18:42 [gentoo-commits] gentoo-x86 commit in media-video/mplayer: ChangeLog mplayer-1.0_rc4_p20120405.ebuild Mike Frysinger (vapier)
-- strict thread matches above, loose matches on Subject: below --
2012-04-05 11:57 Alexis Ballier (aballier)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox