[gentoo-commits] gentoo-x86 commit in app-pda/libplist: libplist-1.8-r1.ebuild ChangeLog

["Samuli Suominen (ssuominen)" <ssuominen@gentoo.org>]

ssuominen    12/03/31 15:28:45

  Modified:             ChangeLog
  Added:                libplist-1.8-r1.ebuild
  Log:
  USE="python" is for building Cython based python binding for compability with libimobiledevice >= 1.1.2
  
  (Portage version: 2.2.0_alpha96/cvs/Linux x86_64)

Revision  Changes    Path
1.23                 app-pda/libplist/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/libplist/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/libplist/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/libplist/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-pda/libplist/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	25 Mar 2012 20:16:26 -0000	1.22
+++ ChangeLog	31 Mar 2012 15:28:44 -0000	1.23
@@ -1,6 +1,12 @@
 # ChangeLog for app-pda/libplist
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-pda/libplist/ChangeLog,v 1.22 2012/03/25 20:16:26 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-pda/libplist/ChangeLog,v 1.23 2012/03/31 15:28:44 ssuominen Exp $
+
+*libplist-1.8-r1 (31 Mar 2012)
+
+  31 Mar 2012; Samuli Suominen <ssuominen@gentoo.org> +libplist-1.8-r1.ebuild:
+  USE="python" is for building Cython based python binding for compability with
+  libimobiledevice >= 1.1.2
 
   25 Mar 2012; Davide Pesavento <pesa@gentoo.org>
   -files/libplist-1.4-gcc46.patch, -libplist-1.4.ebuild, metadata.xml:



1.1                  app-pda/libplist/libplist-1.8-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/libplist/libplist-1.8-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/libplist/libplist-1.8-r1.ebuild?rev=1.1&content-type=text/plain

Index: libplist-1.8-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-pda/libplist/libplist-1.8-r1.ebuild,v 1.1 2012/03/31 15:28:44 ssuominen Exp $

EAPI=4

PYTHON_DEPEND="python? 2:2.7"

inherit cmake-utils python

DESCRIPTION="Support library to deal with Apple Property Lists (Binary & XML)"
HOMEPAGE="http://www.libimobiledevice.org/"
SRC_URI="http://www.libimobiledevice.org/downloads/${P}.tar.bz2"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~x86"
IUSE="python"

RDEPEND="dev-libs/libxml2"
DEPEND="${RDEPEND}
	python? ( >=dev-python/cython-0.13 )"

DOCS=( AUTHORS NEWS README )

MAKEOPTS+=" -j1" #406365

pkg_setup() {
	if use python; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_configure() {
	# Use cython instead of swig to match behavior of libimobiledevice >= 1.1.2
	local mycmakeargs=(
		-DCMAKE_SKIP_RPATH=ON
		$(cmake-utils_use_enable python CYTHON)
		-DENABLE_SWIG=OFF
	)

	cmake-utils_src_configure
}

src_test() {
	cd "${CMAKE_BUILD_DIR}"

	local testfile
	for testfile in "${S}"/test/data/*; do
		LD_LIBRARY_PATH=src ./test/plist_test "${testfile}" || die
	done
}