[gentoo-commits] gentoo-x86 commit in dev-libs/expat: ChangeLog expat-2.1.0.ebuild

[gentoo-commits] gentoo-x86 commit in dev-libs/expat: ChangeLog expat-2.1.0.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/03/28 11:42:42

  Modified:             ChangeLog
  Added:                expat-2.1.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha92/cvs/Linux x86_64)

Revision  Changes    Path
1.127                dev-libs/expat/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/expat/ChangeLog?rev=1.127&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/expat/ChangeLog?rev=1.127&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/expat/ChangeLog?r1=1.126&r2=1.127

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/expat/ChangeLog,v
retrieving revision 1.126
retrieving revision 1.127
diff -u -r1.126 -r1.127
--- ChangeLog	28 Mar 2012 05:42:21 -0000	1.126
+++ ChangeLog	28 Mar 2012 11:42:42 -0000	1.127
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/expat
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/expat/ChangeLog,v 1.126 2012/03/28 05:42:21 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/expat/ChangeLog,v 1.127 2012/03/28 11:42:42 ssuominen Exp $
+
+*expat-2.1.0 (28 Mar 2012)
+
+  28 Mar 2012; Samuli Suominen <ssuominen@gentoo.org> +expat-2.1.0.ebuild:
+  Version bump.
 
   28 Mar 2012; Markus Meier <maekke@gentoo.org> expat-2.1.0_beta3.ebuild:
   arm stable, bug #407519



1.1                  dev-libs/expat/expat-2.1.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/expat/expat-2.1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/expat/expat-2.1.0.ebuild?rev=1.1&content-type=text/plain

Index: expat-2.1.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/expat/expat-2.1.0.ebuild,v 1.1 2012/03/28 11:42:42 ssuominen Exp $

EAPI=4
inherit eutils libtool toolchain-funcs

DESCRIPTION="XML parsing libraries"
HOMEPAGE="http://expat.sourceforge.net/"
SRC_URI="mirror://sourceforge/expat/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="elibc_FreeBSD examples static-libs unicode"

src_prepare() {
	elibtoolize
	epunt_cxx

	mkdir "${S}"-build{,u,w} || die
}

src_configure() {
	local myconf="$(use_enable static-libs static)"

	pushd "${S}"-build >/dev/null
	ECONF_SOURCE="${S}" econf ${myconf}
	popd >/dev/null

	if use unicode; then
		pushd "${S}"-buildu >/dev/null
		CPPFLAGS="${CPPFLAGS} -DXML_UNICODE" ECONF_SOURCE="${S}" econf ${myconf}
		popd >/dev/null

		pushd "${S}"-buildw >/dev/null
		CFLAGS="${CFLAGS} -fshort-wchar" CPPFLAGS="${CPPFLAGS} -DXML_UNICODE_WCHAR_T" ECONF_SOURCE="${S}" econf ${myconf}
		popd >/dev/null
	fi
}

src_compile() {
	pushd "${S}"-build >/dev/null
	emake
	popd >/dev/null

	if use unicode; then
		pushd "${S}"-buildu >/dev/null
		emake buildlib LIBRARY=libexpatu.la
		popd >/dev/null

		pushd "${S}"-buildw >/dev/null
		emake buildlib LIBRARY=libexpatw.la
		popd >/dev/null
	fi
}

src_install() {
	dodoc Changes README
	dohtml doc/*

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins examples/*.c
	fi

	pushd "${S}"-build >/dev/null
	emake install DESTDIR="${D}"
	popd >/dev/null

	if use unicode; then
		pushd "${S}"-buildu >/dev/null
		emake installlib DESTDIR="${D}" LIBRARY=libexpatu.la
		popd >/dev/null

		pushd "${S}"-buildw >/dev/null
		emake installlib DESTDIR="${D}" LIBRARY=libexpatw.la
		popd >/dev/null
	fi

	rm -f "${ED}"usr/lib*/libexpat{,u,w}.la

	# libgeom in /lib and ifconfig in /sbin require it on FreeBSD since we
	# stripped the libbsdxml copy starting from freebsd-lib-8.2-r1
	use elibc_FreeBSD && gen_usr_ldscript -a expat{,u,w}
}

[gentoo-commits] gentoo-x86 commit in dev-libs/expat: ChangeLog expat-2.1.0.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/10/07 10:05:20

  Modified:             ChangeLog
  Removed:              expat-2.1.0.ebuild
  Log:
  old
  
  (Portage version: 2.2.0_alpha135/cvs/Linux x86_64)

Revision  Changes    Path
1.145                dev-libs/expat/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/expat/ChangeLog?rev=1.145&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/expat/ChangeLog?rev=1.145&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/expat/ChangeLog?r1=1.144&r2=1.145

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/expat/ChangeLog,v
retrieving revision 1.144
retrieving revision 1.145
diff -u -r1.144 -r1.145
--- ChangeLog	6 Oct 2012 17:14:41 -0000	1.144
+++ ChangeLog	7 Oct 2012 10:05:20 -0000	1.145
@@ -1,6 +1,9 @@
 # ChangeLog for dev-libs/expat
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/expat/ChangeLog,v 1.144 2012/10/06 17:14:41 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/expat/ChangeLog,v 1.145 2012/10/07 10:05:20 ssuominen Exp $
+
+  07 Oct 2012; Samuli Suominen <ssuominen@gentoo.org> -expat-2.1.0.ebuild:
+  old
 
   06 Oct 2012; Raúl Porcel <armin76@gentoo.org> expat-2.1.0-r2.ebuild:
   alpha/ia64/m68k/s390/sh/sparc stable wrt #437036