[gentoo-commits] gentoo-x86 commit in sci-physics/espresso: ChangeLog espresso-3.1.0.ebuild espresso-3.0.2.ebuild

[gentoo-commits] gentoo-x86 commit in sci-physics/espresso: ChangeLog espresso-3.1.0.ebuild espresso-3.0.2.ebuild

[Christoph Junghans (ottxor)]

ottxor      12/03/22 03:45:20

  Modified:             ChangeLog
  Added:                espresso-3.1.0.ebuild
  Removed:              espresso-3.0.2.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha93/cvs/Linux i686)

Revision  Changes    Path
1.6                  sci-physics/espresso/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/espresso/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/espresso/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/espresso/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-physics/espresso/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	23 Feb 2012 17:04:57 -0000	1.5
+++ ChangeLog	22 Mar 2012 03:45:19 -0000	1.6
@@ -1,6 +1,12 @@
 # ChangeLog for sci-physics/espresso
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-physics/espresso/ChangeLog,v 1.5 2012/02/23 17:04:57 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-physics/espresso/ChangeLog,v 1.6 2012/03/22 03:45:19 ottxor Exp $
+
+*espresso-3.1.0 (22 Mar 2012)
+
+  22 Mar 2012; Christoph Junghans <ottxor@gentoo.org> -espresso-3.0.2.ebuild,
+  +espresso-3.1.0.ebuild:
+  version bump
 
   23 Feb 2012; Kacper Kowalik <xarthisius@gentoo.org> espresso-3.0.2.ebuild:
   Fix dependency on app-doc/doxygen wrt converting useflag 'nodot' to 'dot'.



1.1                  sci-physics/espresso/espresso-3.1.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/espresso/espresso-3.1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/espresso/espresso-3.1.0.ebuild?rev=1.1&content-type=text/plain

Index: espresso-3.1.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-physics/espresso/espresso-3.1.0.ebuild,v 1.1 2012/03/22 03:45:19 ottxor Exp $

EAPI=4

inherit autotools-utils savedconfig

DESCRIPTION="Extensible Simulation Package for Research on Soft matter"
HOMEPAGE="http://www.espressomd.org"

if [[ ${PV} = 9999 ]]; then
	EGIT_REPO_URI="git://git.savannah.nongnu.org/espressomd.git"
	EGIT_BRANCH="master"
	inherit git-2
else
	SRC_URI="mirror://nongnu/${PN}md/${P}.tar.gz"
fi

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~x86"
IUSE="X doc examples fftw mpi packages test -tk"
REQUIRED_USE="tk? ( X )"

RESTRICT="tk? ( test )"

RDEPEND="
	dev-lang/tcl
	fftw? ( sci-libs/fftw:3.0 )
	mpi? ( virtual/mpi )
	tk? ( >=dev-lang/tk-8.4.18-r1 )
	X? ( x11-libs/libX11 )"

DEPEND="${RDEPEND}
	dev-lang/python
	doc? (
		app-doc/doxygen[-nodot]
		virtual/latex-base )"

DOCS=( AUTHORS NEWS README ChangeLog )

src_prepare() {
	autotools-utils_src_prepare
	eautoreconf
	restore_config myconfig.h
}

src_configure() {
	myeconfargs=(
		$(use_with fftw) \
		$(use_with mpi) \
		$(use_with tk) \
		$(use_with X x)
	)
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile
	use doc && autotools-utils_src_compile ug doxygen tutorials
	[[ ${PV} = 9999 ]] && use doc && autotools-utils_src_compile dg
}

src_install() {
	local i

	autotools-utils_src_install

	insinto /usr/share/${PN}
	doins ${AUTOTOOLS_BUILD_DIR}/myconfig-sample.h

	save_config ${AUTOTOOLS_BUILD_DIR}/src/myconfig-final.h

	if use doc; then
		[[ ${PV} = 9999 ]] && \
			newdoc ${AUTOTOOLS_BUILD_DIR}/doc/dg/dg.pdf developer_guide.pdf
		newdoc ${AUTOTOOLS_BUILD_DIR}/doc/ug/ug.pdf user_guide.pdf
		dohtml -r ${AUTOTOOLS_BUILD_DIR}/doc/doxygen/html/*
		for i in ${AUTOTOOLS_BUILD_DIR}/doc/tutorials/*/[0-9]*.pdf; do
			newdoc ${i} tutorial_${i##*/}
		done
	fi

	if use examples; then
		insinto /usr/share/${PN}/examples
		doins -r samples/*
	fi

	if use packages; then
		insinto /usr/share/${PN}/packages
		doins -r packages/*
	fi
}

pkg_postinst() {
	elog
	elog "Please read and cite:"
	elog "ESPResSo, Comput. Phys. Commun. 174(9) ,704, 2006."
	elog "http://dx.doi.org/10.1016/j.cpc.2005.10.005"
	elog
	elog "If you need more features, change"
	elog "/etc/portage/savedconfig/${CATEGORY}/${PF}"
	elog "and reemerge with USE=savedconfig"
	elog
	elog "For a full feature list see:"
	elog "/usr/share/${PN}/myconfig-sample.h"
	elog
}