* [gentoo-commits] gentoo-x86 commit in media-plugins/live: ChangeLog live-2012.02.29.ebuild
@ 2012-03-20 10:05 Alexis Ballier (aballier)
0 siblings, 0 replies; 2+ messages in thread
From: Alexis Ballier (aballier) @ 2012-03-20 10:05 UTC (permalink / raw
To: gentoo-commits
aballier 12/03/20 10:05:44
Modified: ChangeLog
Added: live-2012.02.29.ebuild
Log:
version bump
(Portage version: 2.2.0_alpha93/cvs/Linux x86_64)
Revision Changes Path
1.143 media-plugins/live/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/live/ChangeLog?rev=1.143&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/live/ChangeLog?rev=1.143&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/live/ChangeLog?r1=1.142&r2=1.143
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/live/ChangeLog,v
retrieving revision 1.142
retrieving revision 1.143
diff -u -r1.142 -r1.143
--- ChangeLog 20 Mar 2012 10:00:20 -0000 1.142
+++ ChangeLog 20 Mar 2012 10:05:44 -0000 1.143
@@ -1,6 +1,11 @@
# ChangeLog for media-plugins/live
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/live/ChangeLog,v 1.142 2012/03/20 10:00:20 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/live/ChangeLog,v 1.143 2012/03/20 10:05:44 aballier Exp $
+
+*live-2012.02.29 (20 Mar 2012)
+
+ 20 Mar 2012; Alexis Ballier <aballier@gentoo.org> +live-2012.02.29.ebuild:
+ version bump
20 Mar 2012; Alexis Ballier <aballier@gentoo.org> -live-2011.12.23.ebuild:
remove old
1.1 media-plugins/live/live-2012.02.29.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/live/live-2012.02.29.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/live/live-2012.02.29.ebuild?rev=1.1&content-type=text/plain
Index: live-2012.02.29.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/live/live-2012.02.29.ebuild,v 1.1 2012/03/20 10:05:44 aballier Exp $
EAPI=3
inherit flag-o-matic eutils toolchain-funcs multilib
DESCRIPTION="Source-code libraries for standards-based RTP/RTCP/RTSP multimedia streaming, suitable for embedded and/or low-cost streaming applications"
HOMEPAGE="http://www.live555.com/"
SRC_URI="http://www.live555.com/liveMedia/public/${P/-/.}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE=""
S="${WORKDIR}"
# Alexis Ballier <aballier@gentoo.org>
# Be careful, bump this everytime you bump the package and the ABI has changed.
# If you don't know, ask someone.
LIVE_ABI_VERSION=4
src_prepare() {
cd "${WORKDIR}"
epatch "${FILESDIR}/${PN}-recursive.patch"
cp -pPR live live-shared
mv live live-static
cp "${FILESDIR}/config.gentoo" live-static
cp "${FILESDIR}/config.gentoo-so-r1" live-shared
case ${CHOST} in
*-solaris*)
sed -i \
-e '/^COMPILE_OPTS /s/$/ -DSOLARIS/' \
-e '/^LIBS_FOR_CONSOLE_APPLICATION /s/$/ -lsocket -lnsl/' \
live-static/config.gentoo \
live-shared/config.gentoo-so-r1 \
|| die
;;
*-darwin*)
sed -i \
-e '/^COMPILE_OPTS /s/$/ -DBSD=1 -DHAVE_SOCKADDR_LEN=1/' \
-e '/^LINK /s/$/ /' \
-e '/^LIBRARY_LINK /s/$/ /' \
-e '/^LIBRARY_LINK_OPTS /s/-Bstatic//' \
live-static/config.gentoo \
|| die static
sed -i \
-e '/^COMPILE_OPTS /s/$/ -DBSD=1 -DHAVE_SOCKADDR_LEN=1/' \
-e '/^LINK /s/$/ /' \
-e '/^LIBRARY_LINK /s/=.*$/= $(CXX) -o /' \
-e '/^LIBRARY_LINK_OPTS /s:-shared.*$:-undefined suppress -flat_namespace -dynamiclib -install_name '"${EPREFIX}/usr/$(get_libdir)/"'$@:' \
live-shared/config.gentoo-so-r1 \
|| die shared
;;
esac
}
src_configure() { :; }
src_compile() {
tc-export CC CXX LD
cd "${WORKDIR}/live-static"
einfo "Beginning static library build"
./genMakefiles gentoo
emake -j1 LINK_OPTS="-L. $(raw-ldflags)" || die "failed to build static libraries"
einfo "Beginning programs build"
cd "${WORKDIR}/live-static/testProgs"
emake LINK_OPTS="-L. ${LDFLAGS}" || die "failed to build test programs"
cd "${WORKDIR}/live-static/mediaServer"
emake LINK_OPTS="-L. ${LDFLAGS}" || die "failed to build the mediaserver"
cd "${WORKDIR}/live-shared"
einfo "Beginning shared library build"
./genMakefiles gentoo-so-r1
local suffix=$(get_libname ${LIVE_ABI_VERSION})
emake -j1 LINK_OPTS="-L. ${LDFLAGS}" LIB_SUFFIX="${suffix#.}" || die "failed to build shared libraries"
}
src_install() {
for library in UsageEnvironment liveMedia BasicUsageEnvironment groupsock; do
dolib.a live-static/${library}/lib${library}.a
dolib.so live-shared/${library}/lib${library}$(get_libname ${LIVE_ABI_VERSION})
dosym lib${library}$(get_libname ${LIVE_ABI_VERSION}) /usr/$(get_libdir)/lib${library}$(get_libname)
insinto /usr/include/${library}
doins live-shared/${library}/include/*h
done
# Should we really install these?
find live-static/testProgs -type f -perm +111 -print0 | \
xargs -0 dobin
#install included live555MediaServer aplication
dobin live-static/mediaServer/live555MediaServer
# install docs
dodoc live-static/README
}
pkg_postinst() {
ewarn "If you are upgrading from a version prior to live-2008.02.08"
ewarn "Please make sure to rebuild applications built against ${PN}"
ewarn "like vlc or mplayer. ${PN} may have had ABI changes and ${PN}"
ewarn "support might be broken."
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-plugins/live: ChangeLog live-2012.02.29.ebuild
@ 2012-03-22 1:49 Alexis Ballier (aballier)
0 siblings, 0 replies; 2+ messages in thread
From: Alexis Ballier (aballier) @ 2012-03-22 1:49 UTC (permalink / raw
To: gentoo-commits
aballier 12/03/22 01:49:50
Modified: ChangeLog
Removed: live-2012.02.29.ebuild
Log:
remove latest version: it breaks api, abi hasnt been bumped, and mplayer fails to build, bug #409043, we will readd a newer version when things will be saner
(Portage version: 2.2.0_alpha93/cvs/Linux x86_64)
Revision Changes Path
1.145 media-plugins/live/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/live/ChangeLog?rev=1.145&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/live/ChangeLog?rev=1.145&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/live/ChangeLog?r1=1.144&r2=1.145
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/live/ChangeLog,v
retrieving revision 1.144
retrieving revision 1.145
diff -u -r1.144 -r1.145
--- ChangeLog 21 Mar 2012 12:01:58 -0000 1.144
+++ ChangeLog 22 Mar 2012 01:49:50 -0000 1.145
@@ -1,6 +1,11 @@
# ChangeLog for media-plugins/live
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/live/ChangeLog,v 1.144 2012/03/21 12:01:58 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/live/ChangeLog,v 1.145 2012/03/22 01:49:50 aballier Exp $
+
+ 22 Mar 2012; Alexis Ballier <aballier@gentoo.org> -live-2012.02.29.ebuild:
+ remove latest version: it breaks api, abi hasnt been bumped, and mplayer
+ fails to build, bug #409043, we will readd a newer version when things will
+ be saner
21 Mar 2012; Agostino Sarubbo <ago@gentoo.org> live-2012.01.07.ebuild:
Stable for amd64, wrt bug #408983
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2012-03-22 1:49 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-03-20 10:05 [gentoo-commits] gentoo-x86 commit in media-plugins/live: ChangeLog live-2012.02.29.ebuild Alexis Ballier (aballier)
-- strict thread matches above, loose matches on Subject: below --
2012-03-22 1:49 Alexis Ballier (aballier)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox