[gentoo-commits] gentoo-x86 commit in app-i18n/fcitx: ChangeLog fcitx-4.2.1.ebuild fcitx-4.1.2-r1.ebuild

[gentoo-commits] gentoo-x86 commit in app-i18n/fcitx: ChangeLog fcitx-4.2.1.ebuild fcitx-4.1.2-r1.ebuild

[Mu Qiao (qiaomuf)]

qiaomuf     12/03/13 01:58:10

  Modified:             ChangeLog
  Added:                fcitx-4.2.1.ebuild
  Removed:              fcitx-4.1.2-r1.ebuild
  Log:
  Version bump and remove old version
  
  (Portage version: 2.1.10.49/cvs/Linux x86_64)

Revision  Changes    Path
1.40                 app-i18n/fcitx/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/fcitx/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/fcitx/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/fcitx/ChangeLog?r1=1.39&r2=1.40

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/fcitx/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog	24 Feb 2012 06:23:07 -0000	1.39
+++ ChangeLog	13 Mar 2012 01:58:10 -0000	1.40
@@ -1,6 +1,12 @@
 # ChangeLog for app-i18n/fcitx
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/fcitx/ChangeLog,v 1.39 2012/02/24 06:23:07 qiaomuf Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/fcitx/ChangeLog,v 1.40 2012/03/13 01:58:10 qiaomuf Exp $
+
+*fcitx-4.2.1 (13 Mar 2012)
+
+  13 Mar 2012; Mu Qiao <qiaomuf@gentoo.org> -fcitx-4.1.2-r1.ebuild,
+  +fcitx-4.2.1.ebuild:
+  Version bump and remove old version
 
 *fcitx-4.2.0-r2 (24 Feb 2012)
 



1.1                  app-i18n/fcitx/fcitx-4.2.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/fcitx/fcitx-4.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/fcitx/fcitx-4.2.1.ebuild?rev=1.1&content-type=text/plain

Index: fcitx-4.2.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-i18n/fcitx/fcitx-4.2.1.ebuild,v 1.1 2012/03/13 01:58:10 qiaomuf Exp $

EAPI="3"

inherit cmake-utils eutils

DESCRIPTION="Free Chinese Input Toy for X. Another Chinese XIM Input Method"
HOMEPAGE="http://www.fcitx.org/"
SRC_URI="http://fcitx.googlecode.com/files/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cairo dbus debug gtk gtk3 opencc pango"

RDEPEND="x11-libs/libX11
	x11-libs/libXrender
	media-libs/fontconfig
	pango? ( x11-libs/pango )
	opencc? ( app-i18n/opencc )
	gtk? ( x11-libs/gtk+:2 )
	gtk3? ( x11-libs/gtk+:3 )
	cairo? ( x11-libs/cairo[X] )
	dbus? ( sys-apps/dbus )"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	x11-proto/xproto
	dev-util/pkgconfig"

update_gtk_immodules() {
	local GTK2_CONFDIR="/etc/gtk-2.0"
	# bug #366889
	if has_version '>=x11-libs/gtk+-2.22.1-r1:2' || has_multilib_profile ; then
		GTK2_CONFDIR="${GTK2_CONFDIR}/$(get_abi_CHOST)"
	fi
	mkdir -p "${EPREFIX}${GTK2_CONFDIR}"

	if [ -x "${EPREFIX}/usr/bin/gtk-query-immodules-2.0" ] ; then
		"${EPREFIX}/usr/bin/gtk-query-immodules-2.0" > "${EPREFIX}${GTK2_CONFDIR}/gtk.immodules"
	fi
}

update_gtk3_immodules() {
	if [ -x "${EPREFIX}/usr/bin/gtk-query-immodules-3.0" ] ; then
		"${EPREFIX}/usr/bin/gtk-query-immodules-3.0" --update-cache
	fi
}

src_configure() {
	local mycmakeargs="
		$(cmake-utils_use_enable cairo)
		$(cmake-utils_use_enable dbus)
		$(cmake-utils_use_enable debug)
		$(cmake-utils_use_enable gtk GTK2_IM_MODULE)
		$(cmake-utils_use_enable gtk3 GTK3_IM_MODULE)
		$(cmake-utils_use_enable opencc)
		$(cmake-utils_use_enable pango)"
		cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	dodoc AUTHORS ChangeLog README THANKS TODO || die

	rm -rf "${ED}"/usr/share/fcitx/doc/ || die
	dodoc doc/pinyin.txt doc/cjkvinput.txt || die
	dohtml doc/wb_fh.htm || die
}

pkg_postinst() {
	use gtk && update_gtk_immodules
	use gtk3 && update_gtk3_immodules
	elog
	elog "You should export the following variables to use fcitx"
	elog " export XMODIFIERS=\"@im=fcitx\""
	elog " export XIM=fcitx"
	elog " export XIM_PROGRAM=fcitx"
	elog
}

pkg_postrm() {
	use gtk && update_gtk_immodules
	use gtk3 && update_gtk3_immodules
}