[gentoo-commits] gentoo-x86 commit in sys-apps/x86info: x86info-1.30.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in sys-apps/x86info: x86info-1.30.ebuild ChangeLog

[Robin H. Johnson (robbat2)]

robbat2     12/03/12 01:46:23

  Modified:             ChangeLog
  Added:                x86info-1.30.ebuild
  Log:
  Version bump per bug# 400743, as earlier versions needed python2.
  
  (Portage version: 2.2.0_alpha90/cvs/Linux x86_64)

Revision  Changes    Path
1.32                 sys-apps/x86info/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/x86info/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/x86info/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/x86info/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/x86info/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -p -w -b -B -u -u -r1.31 -r1.32
--- ChangeLog	15 May 2011 18:25:40 -0000	1.31
+++ ChangeLog	12 Mar 2012 01:46:23 -0000	1.32
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/x86info
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/x86info/ChangeLog,v 1.31 2011/05/15 18:25:40 robbat2 Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/x86info/ChangeLog,v 1.32 2012/03/12 01:46:23 robbat2 Exp $
+
+*x86info-1.30 (12 Mar 2012)
+
+  12 Mar 2012; Robin H. Johnson <robbat2@gentoo.org> +x86info-1.30.ebuild:
+  Version bump per bug# 400743, as earlier versions needed python2.
 
 *x86info-1.29 (15 May 2011)
 



1.1                  sys-apps/x86info/x86info-1.30.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/x86info/x86info-1.30.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/x86info/x86info-1.30.ebuild?rev=1.1&content-type=text/plain

Index: x86info-1.30.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/x86info/x86info-1.30.ebuild,v 1.1 2012/03/12 01:46:23 robbat2 Exp $

EAPI=2
inherit eutils toolchain-funcs flag-o-matic

DESCRIPTION="Dave Jones' handy, informative x86 CPU diagnostic utility"
HOMEPAGE="http://www.codemonkey.org.uk/projects/x86info/"
SRC_URI="http://www.codemonkey.org.uk/projects/x86info/${P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE=""

RDEPEND="sys-apps/pciutils"
DEPEND="${RDEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/1.21-pic.patch
	epatch "${FILESDIR}"/${PN}-1.24-pic.patch #270388
	epatch "${FILESDIR}"/${PN}-1.29-parallel-make-cleanup.patch
}

src_compile() {
	# These flags taken from the 1.29 ebuild
	append-flags -Wall -Wshadow -Wextra -Wmissing-declarations -Wdeclaration-after-statement -Wredundant-decls
	append-ldflags -Wl,-z,relro,-z,now
	emake x86info lsmsr \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS} ${CPPFLAGS}" \
		LDFLAGS="${LDFLAGS}" \
		|| die "emake failed"
}

src_install() {
	dobin x86info lsmsr || die

	insinto /etc/modprobe.d
	newins "${FILESDIR}"/x86info-modules.conf-rc x86info.conf

	dodoc TODO README
	doman x86info.1 lsmsr.8
	insinto /usr/share/doc/${PF}
	doins -r results
	prepalldocs
}

pkg_preinst() {
	if [ -a "${ROOT}"/etc/modules.d/x86info ] && [ ! -a "${ROOT}"/etc/modprobe.d/x86info ] ; then
		elog "Moving x86info from /etc/modules.d/ to /etc/modprobe.d/"
		mv "${ROOT}"/etc/{modules,modprobe}.d/x86info
	fi
	if [ -a "${ROOT}"/etc/modprobe.d/x86info ] && [ ! -a "${ROOT}"/etc/modprobe.d/x86info.conf ] ; then
		elog "Adding .conf suffix to x86info in /etc/modprobe.d/"
		mv "${ROOT}"/etc/modprobe.d/x86info{,.conf}
	fi
}

pkg_postinst() {
	ewarn "Your kernel must be built with the following options"
	ewarn "set to Y or M"
	ewarn "     Processor type and features ->"
	ewarn "         [*] /dev/cpu/*/msr - Model-specific register support"
	ewarn "         [*] /dev/cpu/*/cpuid - CPU information support"
}