[gentoo-commits] gentoo-x86 commit in kde-base/korundum: korundum-4.8.1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in kde-base/korundum: korundum-4.8.1.ebuild ChangeLog

[Andreas HAttel (dilfridge)]

dilfridge    12/03/06 23:35:10

  Modified:             ChangeLog
  Added:                korundum-4.8.1.ebuild
  Log:
  Version bump KDE SC 4.8.1
  
  (Portage version: 2.1.10.49/cvs/Linux x86_64)

Revision  Changes    Path
1.104                kde-base/korundum/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/korundum/ChangeLog?rev=1.104&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/korundum/ChangeLog?rev=1.104&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/korundum/ChangeLog?r1=1.103&r2=1.104

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/korundum/ChangeLog,v
retrieving revision 1.103
retrieving revision 1.104
diff -u -r1.103 -r1.104
--- ChangeLog	18 Feb 2012 15:50:31 -0000	1.103
+++ ChangeLog	6 Mar 2012 23:35:10 -0000	1.104
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/korundum
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/ChangeLog,v 1.103 2012/02/18 15:50:31 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/ChangeLog,v 1.104 2012/03/06 23:35:10 dilfridge Exp $
+
+*korundum-4.8.1 (06 Mar 2012)
+
+  06 Mar 2012; Andreas K. Huettel <dilfridge@gentoo.org>
+  +korundum-4.8.1.ebuild:
+  Version bump KDE SC 4.8.1
 
   18 Feb 2012; nixnut <nixnut@gentoo.org> korundum-4.7.4.ebuild:
   ppc stable #396359



1.1                  kde-base/korundum/korundum-4.8.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/korundum/korundum-4.8.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/korundum/korundum-4.8.1.ebuild?rev=1.1&content-type=text/plain

Index: korundum-4.8.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/korundum-4.8.1.ebuild,v 1.1 2012/03/06 23:35:10 dilfridge Exp $

EAPI=4

OPENGL_REQUIRED="always"
KDE_SCM="git"

USE_RUBY="ruby18"
# No ruby19 for three reasons:
# 1) it does not build (yet) - will likely be solved soon
# 2) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
# 3) the ebuild can only be installed for one ruby variant, otherwise the compiled
#    files with identical path+name will overwrite each other - difficult :(

inherit kde4-base ruby-ng

DESCRIPTION="KDE Ruby bindings"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="akonadi debug kate okular"

# unfortunately single modules cannot be disabled with cmake defines
# possible more useflags have no effect... does anyone actually build this stuff?
# may need some hacking, for now semantic-desktop just becomes a hard dependency

DEPEND="
	$(add_kdebase_dep qtruby)
	$(add_kdebase_dep smokekde 'akonadi?,kate?,okular?,semantic-desktop')
	$(add_kdebase_dep smokeqt)
"
RDEPEND="${DEPEND}
"

# Split from kdebindings-ruby in 4.7
add_blocker kdebindings-ruby

pkg_setup() {
	ruby-ng_pkg_setup
	kde4-base_pkg_setup
}

src_unpack() {
	local S="${WORKDIR}/${P}"
	kde4-base_src_unpack

	cd "${WORKDIR}"
	mkdir all
	mv ${P} all/ || die "Could not move sources"
}

all_ruby_prepare() {
	kde4-base_src_prepare
}

each_ruby_configure() {
	CMAKE_USE_DIR=${S}
	mycmakeargs=(
		-DRUBY_LIBRARY=$(ruby_get_libruby)
		-DRUBY_INCLUDE_PATH=$(ruby_get_hdrdir)
		-DRUBY_EXECUTABLE=${RUBY}
		$(cmake-utils_use_with akonadi)
		$(cmake-utils_use_with akonadi KdepimLibs)
		$(cmake-utils_use_disable kate)
		$(cmake-utils_use_with okular)
	)
	kde4-base_src_configure
}

each_ruby_compile() {
	CMAKE_USE_DIR=${S}
	kde4-base_src_compile
}

each_ruby_install() {
	CMAKE_USE_DIR=${S}
	kde4-base_src_install
}