[gentoo-commits] gentoo-x86 commit in dev-util/coccigrep: ChangeLog coccigrep-1.7.ebuild

[gentoo-commits] gentoo-x86 commit in dev-util/coccigrep: ChangeLog coccigrep-1.7.ebuild

[Tim Harder (radhermit)]

radhermit    12/03/05 11:28:34

  Modified:             ChangeLog
  Added:                coccigrep-1.7.ebuild
  Log:
  Version bump. Fix emacs site-init filename.
  
  (Portage version: 2.2.0_alpha89/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  dev-util/coccigrep/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/coccigrep/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/coccigrep/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/coccigrep/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/coccigrep/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	28 Feb 2012 19:10:33 -0000	1.4
+++ ChangeLog	5 Mar 2012 11:28:34 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/coccigrep
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/coccigrep/ChangeLog,v 1.4 2012/02/28 19:10:33 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/coccigrep/ChangeLog,v 1.5 2012/03/05 11:28:34 radhermit Exp $
+
+*coccigrep-1.7 (05 Mar 2012)
+
+  05 Mar 2012; Tim Harder <radhermit@gentoo.org> +files/50coccigrep-gentoo.el,
+  -files/50-coccigrep-gentoo.el, +coccigrep-1.7.ebuild:
+  Version bump. Fix emacs site-init filename.
 
   28 Feb 2012; Tim Harder <radhermit@gentoo.org> -coccigrep-1.5.ebuild:
   Remove old.



1.1                  dev-util/coccigrep/coccigrep-1.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/coccigrep/coccigrep-1.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/coccigrep/coccigrep-1.7.ebuild?rev=1.1&content-type=text/plain

Index: coccigrep-1.7.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/coccigrep/coccigrep-1.7.ebuild,v 1.1 2012/03/05 11:28:34 radhermit Exp $

EAPI=4
USE_PYTHON="2"

inherit distutils elisp-common

DESCRIPTION="A semantic grep for the C language"
HOMEPAGE="http://home.regit.org/software/coccigrep/"
SRC_URI="https://github.com/regit/${PN}/tarball/v${PV/_/} -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc emacs vim"

RDEPEND="dev-util/coccinelle[python]
	|| ( dev-lang/python:2.7 dev-python/argparse )
	emacs? ( virtual/emacs )
	vim? ( || ( app-editors/vim app-editors/gvim ) )"
DEPEND="doc? ( dev-python/sphinx )
	emacs? ( virtual/emacs )"

SITEFILE="50${PN}-gentoo.el"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_unpack() {
	unpack ${A}
	mv *-${PN}-* "${S}" || die
}

src_compile() {
	distutils_src_compile
	use doc && emake -C doc html

	if use emacs ; then
		elisp-compile editors/*.el || die
	fi
}

src_install() {
	distutils_src_install
	doman ${PN}.1

	use doc && dohtml -r doc/_build/html/*

	if use emacs ; then
		elisp-install ${PN} editors/*.{el,elc} || die
		elisp-site-file-install "${FILESDIR}"/${SITEFILE} || die
	fi

	if use vim ; then
		insinto /usr/share/vim/vimfiles/plugin
		doins editors/cocci-grep.vim
	fi
}

pkg_postinst() {
	use emacs && elisp-site-regen

	einfo "Syntax highlighting is supported through dev-python/pygments."
	einfo "Install it if you want colorized output formats."
}

pkg_postrm() {
	use emacs && elisp-site-regen
}