* [gentoo-commits] gentoo-x86 commit in sci-physics/hepmc: ChangeLog hepmc-2.06.08.ebuild
@ 2012-03-02 5:26 Sebastien Fabbro (bicatali)
0 siblings, 0 replies; only message in thread
From: Sebastien Fabbro (bicatali) @ 2012-03-02 5:26 UTC (permalink / raw
To: gentoo-commits
bicatali 12/03/02 05:26:02
Modified: ChangeLog
Added: hepmc-2.06.08.ebuild
Log:
Version bump
(Portage version: 2.1.10.44/cvs/Linux x86_64)
Revision Changes Path
1.31 sci-physics/hepmc/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/hepmc/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/hepmc/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/hepmc/ChangeLog?r1=1.30&r2=1.31
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-physics/hepmc/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog 19 Jan 2012 23:28:40 -0000 1.30
+++ ChangeLog 2 Mar 2012 05:26:02 -0000 1.31
@@ -1,6 +1,11 @@
# ChangeLog for sci-physics/hepmc
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-physics/hepmc/ChangeLog,v 1.30 2012/01/19 23:28:40 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-physics/hepmc/ChangeLog,v 1.31 2012/03/02 05:26:02 bicatali Exp $
+
+*hepmc-2.06.08 (02 Mar 2012)
+
+ 02 Mar 2012; Sébastien Fabbro <bicatali@gentoo.org> +hepmc-2.06.08.ebuild:
+ Version bump
*hepmc-2.06.07 (19 Jan 2012)
1.1 sci-physics/hepmc/hepmc-2.06.08.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/hepmc/hepmc-2.06.08.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/hepmc/hepmc-2.06.08.ebuild?rev=1.1&content-type=text/plain
Index: hepmc-2.06.08.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-physics/hepmc/hepmc-2.06.08.ebuild,v 1.1 2012/03/02 05:26:02 bicatali Exp $
EAPI=4
inherit cmake-utils
MYP=HepMC-${PV}
DESCRIPTION="Event Record for Monte Carlo Generators"
HOMEPAGE="https://savannah.cern.ch/projects/hepmc/"
SRC_URI="http://lcgapp.cern.ch/project/simu/HepMC/download/${MYP}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cm doc examples gev static-libs test"
RDEPEND=""
DEPEND="${RDEPEND}
doc? ( app-doc/doxygen dev-tex/floatflt )"
S="${WORKDIR}/${MYP}"
DOCS=( ChangeLog AUTHORS )
src_prepare() {
sed -i -e '/add_subdirectory(doc)/d' CMakeLists.txt
# CMake doc building broken
# gentoo doc directory
#sed -i \
# -e "s:share/HepMC/doc:share/doc/${PF}:" \
# doc/CMakeLists.txt || die
# gentoo examples directory
sed -i \
-e "s:share/HepMC:share/doc/${PF}:" \
$(find examples -name CMakeLists.txt) || die
# respect user's flags
sed -i \
-e "s/-O -ansi -pedantic -Wall//g" \
cmake/Modules/HepMCVariables.cmake || die
# gentoo libdir love
sed -i \
-e '/DESTINATION/s/lib/lib${LIB_SUFFIX}/g' \
{src,fio}/CMakeLists.txt || die
# remove targets if use flags not set
use examples || sed -i -e '/add_subdirectory(examples)/d' CMakeLists.txt
use test || sed -i -e '/add_subdirectory(test)/d' CMakeLists.txt
if ! use static-libs; then
sed -i \
-e '/(HepMC\(fio\|\)S/d' \
-e '/TARGETS/s/HepMC\(fio\|\)S//' \
{src,fio}/CMakeLists.txt || die
fi
}
src_configure() {
# use MeV over GeV and mm over cm
local length_conf="MM"
use cm && length_conf="CM"
local momentum_conf="MEV"
use gev && momentum_conf="GEV"
mycmakeargs+=(
-Dlength=${length_conf}
-Dmomentum=${momentum_conf}
)
cmake-utils_src_configure
}
src_compile() {
cmake-utils_src_compile
if use doc; then
cd doc
./buildDoc.sh || die
./buildDoxygen.sh || die
fi
}
src_install() {
cmake-utils_src_install
use doc && dodoc doc/*.pdf && dohtml -r doc/html/*
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-03-02 5:26 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-03-02 5:26 [gentoo-commits] gentoo-x86 commit in sci-physics/hepmc: ChangeLog hepmc-2.06.08.ebuild Sebastien Fabbro (bicatali)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox