[gentoo-commits] gentoo-x86 commit in dev-lang/swi-prolog: ChangeLog swi-prolog-5.11.37.ebuild

["Keri Harris (keri)" <keri@gentoo.org>]

keri        12/03/01 12:46:01

  Modified:             ChangeLog
  Added:                swi-prolog-5.11.37.ebuild
  Log:
  Bump -5.11 development version
  
  (Portage version: 2.1.10.41/cvs/Linux x86_64)

Revision  Changes    Path
1.317                dev-lang/swi-prolog/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/swi-prolog/ChangeLog?rev=1.317&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/swi-prolog/ChangeLog?rev=1.317&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/swi-prolog/ChangeLog?r1=1.316&r2=1.317

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/swi-prolog/ChangeLog,v
retrieving revision 1.316
retrieving revision 1.317
diff -u -r1.316 -r1.317
--- ChangeLog	7 Feb 2012 03:30:22 -0000	1.316
+++ ChangeLog	1 Mar 2012 12:46:01 -0000	1.317
@@ -1,6 +1,11 @@
 # ChangeLog for dev-lang/swi-prolog
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/swi-prolog/ChangeLog,v 1.316 2012/02/07 03:30:22 keri Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/swi-prolog/ChangeLog,v 1.317 2012/03/01 12:46:01 keri Exp $
+
+*swi-prolog-5.11.37 (01 Mar 2012)
+
+  01 Mar 2012; <keri@gentoo.org> +swi-prolog-5.11.37.ebuild:
+  Bump -5.11 development version
 
   07 Feb 2012; <keri@gentoo.org> -swi-prolog-5.10.4.ebuild,
   -swi-prolog-5.10.5.ebuild:



1.1                  dev-lang/swi-prolog/swi-prolog-5.11.37.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/swi-prolog/swi-prolog-5.11.37.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/swi-prolog/swi-prolog-5.11.37.ebuild?rev=1.1&content-type=text/plain

Index: swi-prolog-5.11.37.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/swi-prolog/swi-prolog-5.11.37.ebuild,v 1.1 2012/03/01 12:46:01 keri Exp $

EAPI=2

inherit eutils flag-o-matic java-pkg-opt-2

PATCHSET_VER="0"

DESCRIPTION="free, small, and standard compliant Prolog compiler"
HOMEPAGE="http://www.swi-prolog.org/"
SRC_URI="http://www.swi-prolog.org/download/devel/src/pl-${PV}.tar.gz
	mirror://gentoo/${P}-gentoo-patchset-${PATCHSET_VER}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug doc gmp hardened java minimal odbc readline ssl static test zlib X"

RDEPEND="sys-libs/ncurses
	zlib? ( sys-libs/zlib )
	odbc? ( dev-db/unixODBC )
	readline? ( sys-libs/readline )
	gmp? ( dev-libs/gmp )
	ssl? ( dev-libs/openssl )
	java? ( >=virtual/jdk-1.4 )
	X? (
		virtual/jpeg
		x11-libs/libX11
		x11-libs/libXft
		x11-libs/libXpm
		x11-libs/libXt
		x11-libs/libICE
		x11-libs/libSM )"

DEPEND="${RDEPEND}
	X? ( x11-proto/xproto )
	java? ( test? ( =dev-java/junit-3.8* ) )"

S="${WORKDIR}/pl-${PV}"

src_prepare() {
	EPATCH_FORCE=yes
	EPATCH_SUFFIX=patch
	epatch "${WORKDIR}"/${PV}
}

src_configure() {
	append-flags -fno-strict-aliasing
	use ppc && append-flags -mno-altivec
	use hardened && append-flags -fno-unit-at-a-time
	use debug && append-flags -DO_DEBUG

	cd "${S}"/src
	econf \
		--libdir=/usr/$(get_libdir) \
		$(use_enable gmp) \
		$(use_enable readline) \
		$(use_enable !static shared) \
		--enable-custom-flags COFLAGS="${CFLAGS}"
}

src_compile() {
	cd "${S}"/src
	emake || die "emake failed"

	if ! use minimal ; then
		local jpltestconf
		if use java && use test ; then
			jpltestconf="--with-junit=$(java-config --classpath junit)"
		fi

		cd "${S}/packages"
		econf \
			--libdir=/usr/$(get_libdir) \
			--with-chr \
			--with-clib \
			--with-clpqr \
			--with-cpp \
			--with-http \
			$(use_with java jpl) \
			${jpltestconf} \
			--with-nlp \
			$(use_with odbc) \
			--with-pldoc \
			--with-plunit \
			--with-protobufs \
			--with-R \
			--with-RDF \
			--with-semweb \
			--with-sgml \
			$(use_with ssl) \
			--with-table \
			--with-tipc \
			$(use_with X xpce) \
			$(use_with zlib) \
			COFLAGS='"${CFLAGS}"'

		emake || die "packages emake failed"
	fi
}

src_test() {
	cd "${S}/src"
	emake check || die "make check failed. See above for details."

	if ! use minimal ; then
		cd "${S}/packages"
		emake check || die "make check failed. See above for details."
	fi
}

src_install() {
	emake -C src DESTDIR="${D}" install || die "install src failed"

	if ! use minimal ; then
		emake -C packages DESTDIR="${D}" install || die "install packages failed"
		if use doc ; then
			emake -C packages DESTDIR="${D}" html-install || die "html-install failed"
		fi
	fi

	dodoc ReleaseNotes/relnotes-5.10 INSTALL README VERSION || die
}