* [gentoo-commits] gentoo-x86 commit in dev-util/perf: ChangeLog perf-3.2.ebuild perf-3.1.ebuild perf-2.6.35_rc4.ebuild
@ 2012-02-28 22:21 Mike Frysinger (vapier)
0 siblings, 0 replies; only message in thread
From: Mike Frysinger (vapier) @ 2012-02-28 22:21 UTC (permalink / raw
To: gentoo-commits
vapier 12/02/28 22:21:06
Modified: ChangeLog
Added: perf-3.2.ebuild
Removed: perf-3.1.ebuild perf-2.6.35_rc4.ebuild
Log:
Fix automagic depends #390191 and clean up the ebuild.
(Portage version: 2.2.0_alpha86/cvs/Linux x86_64)
Revision Changes Path
1.19 dev-util/perf/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/perf/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/perf/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/perf/ChangeLog?r1=1.18&r2=1.19
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/perf/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog 1 Nov 2011 07:33:12 -0000 1.18
+++ ChangeLog 28 Feb 2012 22:21:05 -0000 1.19
@@ -1,6 +1,12 @@
# ChangeLog for dev-util/perf
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/perf/ChangeLog,v 1.18 2011/11/01 07:33:12 robbat2 Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/perf/ChangeLog,v 1.19 2012/02/28 22:21:05 vapier Exp $
+
+*perf-3.2 (28 Feb 2012)
+
+ 28 Feb 2012; Mike Frysinger <vapier@gentoo.org> -perf-2.6.35_rc4.ebuild,
+ -perf-3.1.ebuild, +perf-3.2.ebuild:
+ Fix automagic depends #390191 and clean up the ebuild.
*perf-3.1 (01 Nov 2011)
1.1 dev-util/perf/perf-3.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/perf/perf-3.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/perf/perf-3.2.ebuild?rev=1.1&content-type=text/plain
Index: perf-3.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/perf/perf-3.2.ebuild,v 1.1 2012/02/28 22:21:05 vapier Exp $
EAPI="4"
PYTHON_DEPEND="python? 2"
inherit versionator eutils toolchain-funcs python linux-info
MY_PV="${PV/_/-}"
MY_PV="${MY_PV/-pre/-git}"
DESCRIPTION="Userland tools for Linux Performance Counters"
HOMEPAGE="http://perf.wiki.kernel.org/"
LINUX_V=$(get_version_component_range 1-2)
if [[ ${PV/_rc} != ${PV} ]] ; then
LINUX_VER=$(get_version_component_range 1-2).$(($(get_version_component_range 3)-1))
PATCH_VERSION=$(get_version_component_range 1-3)
LINUX_PATCH=patch-${PV//_/-}.bz2
SRC_URI="mirror://kernel/linux/kernel/v${LINUX_V}/testing/${LINUX_PATCH}
mirror://kernel/linux/kernel/v${LINUX_V}/testing/v${PATCH_VERSION}/${LINUX_PATCH}"
elif [[ $(get_version_component_count) == 4 ]] ; then
# stable-release series
LINUX_VER=$(get_version_component_range 1-3)
LINUX_PATCH=patch-${PV}.bz2
SRC_URI="mirror://kernel/linux/kernel/v${LINUX_V}/${LINUX_PATCH}"
else
LINUX_VER=${PV}
SRC_URI=""
fi
LINUX_SOURCES="linux-${LINUX_VER}.tar.bz2"
SRC_URI+=" mirror://kernel/linux/kernel/v${LINUX_V}/${LINUX_SOURCES}"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="+demangle +doc perl python slang"
RDEPEND="demangle? ( sys-devel/binutils )
perl? ( || ( >=dev-lang/perl-5.10 sys-devel/libperl ) )
slang? ( dev-libs/newt )
dev-libs/elfutils"
DEPEND="${RDEPEND}
${LINUX_PATCH+dev-util/patchutils}
doc? ( app-text/asciidoc app-text/xmlto )"
S_K="${WORKDIR}/linux-${LINUX_VER}"
S="${S_K}/tools/perf"
CONFIG_CHECK="~PERF_EVENTS ~KALLSYMS"
pkg_setup() {
use python && python_set_active_version 2
}
src_unpack() {
local paths=( tools/perf include lib "arch/*/include" "arch/*/lib" )
# We expect the tar implementation to support the -j option (both
# GNU tar and libarchive's tar support that).
echo ">>> Unpacking ${LINUX_SOURCES} (${paths[*]}) to ${PWD}"
tar --wildcards -xpf "${DISTDIR}"/${LINUX_SOURCES} \
"${paths[@]/#/linux-${LINUX_VER}/}" || die
if [[ -n ${LINUX_PATCH} ]] ; then
eshopts_push -o noglob
ebegin "Filtering partial source patch"
filterdiff -p1 ${paths[@]/#/-i } -z "${DISTDIR}"/${LINUX_PATCH} > ${P}.patch || die
eend $? || die "filterdiff failed"
eshopts_pop
fi
local a
for a in ${A}; do
[[ ${a} == ${LINUX_SOURCES} ]] && continue
[[ ${a} == ${LINUX_PATCH} ]] && continue
unpack ${a}
done
}
src_prepare() {
if [[ -n ${LINUX_PATCH} ]] ; then
cd "${S_K}"
epatch "${WORKDIR}"/${P}.patch
fi
# Drop some upstream too-developer-oriented flags and fix the
# Makefile in general
sed -i \
-e 's:-Werror::' \
-e 's:-ggdb3::' \
-e 's:-fstack-protector-all::' \
-e 's:^LDFLAGS =:EXTLIBS +=:' \
-e '/\(PERL\|PYTHON\)_EMBED_LDOPTS/s:ALL_LDFLAGS +=:EXTLIBS +=:' \
-e '/-x c - /s:\$(ALL_LDFLAGS):\0 $(EXTLIBS):' \
-e '/^ALL_CFLAGS =/s:$: $(CFLAGS_OPTIMIZE):' \
-e '/^ALL_LDFLAGS =/s:$: $(LDFLAGS_OPTIMIZE):' \
-e '/.FORCE-PERF-VERSION-FILE/s,.FORCE-PERF-VERSION-FILE,,g' \
"${S}"/Makefile
# Avoid the call to make kernelversion
echo "PERF_VERSION = ${MY_PV}" > PERF-VERSION-FILE
# The code likes to compile local assembly files which lack ELF markings.
find -name '*.S' -exec sed -i '$a.section .note.GNU-stack,"",%progbits' {} +
}
puse() { usex $1 "" no; }
perf_make() {
emake V=1 \
CC="$(tc-getCC)" AR="$(tc-getAR)" \
prefix="/usr" bindir_relative="sbin" \
CFLAGS_OPTIMIZE="${CFLAGS}" \
LDFLAGS_OPTIMIZE="${LDFLAGS}" \
ARCH="$(tc-arch-kernel)" \
NO_DEMANGLE=$(puse demangle) \
NO_LIBPERL=$(puse perl) \
NO_LIBPYTHON=$(puse python) \
NO_NEWT=$(puse slang) \
"$@"
}
src_compile() {
perf_make
if use doc ; then
pushd Documentation
emake ${makeargs}
popd
fi
}
src_test() {
:
}
src_install() {
perf_make install DESTDIR="${D}"
dodoc CREDITS
dodoc *txt Documentation/*.txt
if use doc ; then
dohtml Documentation/*.html
doman Documentation/*.1
fi
}
pkg_postinst() {
if ! use doc ; then
elog "Without the doc USE flag you won't get any documentation nor man pages."
elog "And without man pages, you won't get any --help output for perf and its"
elog "sub-tools."
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-02-28 22:21 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-02-28 22:21 [gentoo-commits] gentoo-x86 commit in dev-util/perf: ChangeLog perf-3.2.ebuild perf-3.1.ebuild perf-2.6.35_rc4.ebuild Mike Frysinger (vapier)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox