[gentoo-commits] gentoo-x86 commit in x11-terms/roxterm: metadata.xml ChangeLog roxterm-2.5.2.ebuild

[gentoo-commits] gentoo-x86 commit in x11-terms/roxterm: metadata.xml ChangeLog roxterm-2.5.2.ebuild

[Jim Ramsay (lack)]

lack        12/02/28 20:40:35

  Modified:             metadata.xml ChangeLog
  Added:                roxterm-2.5.2.ebuild
  Log:
  Version bump, plus Bug #396539: Adding gtk3 USE flag
  
  (Portage version: 2.1.10.49/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  x11-terms/roxterm/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/roxterm/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/roxterm/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/roxterm/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-terms/roxterm/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	15 Jan 2009 21:34:53 -0000	1.3
+++ metadata.xml	28 Feb 2012 20:40:35 -0000	1.4
@@ -4,5 +4,8 @@
 	<herd>rox</herd>
 	<longdescription lang="en">
 	</longdescription>
+	<use>
+		<flag name="gtk3">Use gtk3 instead of gtk2 (and associated version of x11-libs/vte)</flag>
+	</use>
 </pkgmetadata>
 



1.56                 x11-terms/roxterm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/roxterm/ChangeLog?rev=1.56&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/roxterm/ChangeLog?rev=1.56&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/roxterm/ChangeLog?r1=1.55&r2=1.56

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-terms/roxterm/ChangeLog,v
retrieving revision 1.55
retrieving revision 1.56
diff -u -r1.55 -r1.56
--- ChangeLog	30 Dec 2011 13:57:20 -0000	1.55
+++ ChangeLog	28 Feb 2012 20:40:35 -0000	1.56
@@ -1,6 +1,12 @@
 # ChangeLog for x11-terms/roxterm
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/roxterm/ChangeLog,v 1.55 2011/12/30 13:57:20 ssuominen Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/roxterm/ChangeLog,v 1.56 2012/02/28 20:40:35 lack Exp $
+
+*roxterm-2.5.2 (28 Feb 2012)
+
+  28 Feb 2012; Jim Ramsay <jim_ramsay@gentoo.org> +roxterm-2.5.2.ebuild,
+  metadata.xml:
+  Version bump, plus Bug #396539: Adding gtk3 USE flag
 
 *roxterm-2.3.4 (30 Dec 2011)
 



1.1                  x11-terms/roxterm/roxterm-2.5.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/roxterm/roxterm-2.5.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/roxterm/roxterm-2.5.2.ebuild?rev=1.1&content-type=text/plain

Index: roxterm-2.5.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-terms/roxterm/roxterm-2.5.2.ebuild,v 1.1 2012/02/28 20:40:35 lack Exp $

EAPI=4
PYTHON_DEPEND="2:2.6"
inherit gnome2-utils python

DESCRIPTION="A terminal emulator designed to integrate with the ROX environment"
HOMEPAGE="http://roxterm.sourceforge.net/"
SRC_URI="mirror://sourceforge/roxterm/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="nls +gtk3"

RDEPEND="dev-libs/dbus-glib
	>=dev-libs/glib-2.16
	gtk3?  ( x11-libs/gtk+:3 x11-libs/vte:2.90 )
	!gtk3? ( x11-libs/gtk+:2 x11-libs/vte:0    )
	x11-libs/libICE
	x11-libs/libSM"
DEPEND="${RDEPEND}
	dev-libs/libxslt
	dev-util/pkgconfig
	dev-python/lockfile
	|| ( media-gfx/imagemagick media-gfx/graphicsmagick[imagemagick] )
	nls? ( app-text/po4a sys-devel/gettext )"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	python_convert_shebangs 2 mscript.py

	# build system is crap
	sed -i -e 's:TerminalEmulator:System;&:' roxterm.desktop || die
	sed -i -e '/ctx.install_doc/s:COPYING ::' mscript.py || die
	sed -i -e "/CFLAGS/s:-O2 -g:${CFLAGS}:" {maitch,mscript}.py || die
	sed -i \
		-e "/LDFLAGS/s:'':'${LDFLAGS}':" \
		-e 's:--mode=link:--mode=link --tag=CC:' \
		maitch.py || die
}

src_configure() {
	local myconf=( --prefix=/usr --docdir=/usr/share/doc/${PF} --destdir="${D}" )
	use nls || myconf+=( --disable-gettext --disable-po4a --disable-translations )
	use gtk3 || myconf+=( --disable-gtk3 )
	./mscript.py configure "${myconf[@]}"
}

src_compile() { ./mscript.py build; }
src_install() { ./mscript.py install; }
pkg_preinst() { gnome2_icon_savelist; }
pkg_postinst() { gnome2_icon_cache_update; }
pkg_postrm() { gnome2_icon_cache_update; }