[gentoo-commits] gentoo-x86 commit in sci-physics/lhapdf: ChangeLog lhapdf-5.8.7.ebuild lhapdf-5.8.5.ebuild lhapdf-5.8.4-r1.ebuild

[gentoo-commits] gentoo-x86 commit in sci-physics/lhapdf: ChangeLog lhapdf-5.8.7.ebuild lhapdf-5.8.5.ebuild lhapdf-5.8.4-r1.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    12/02/27 02:35:17

  Modified:             ChangeLog
  Added:                lhapdf-5.8.7.ebuild
  Removed:              lhapdf-5.8.5.ebuild lhapdf-5.8.4-r1.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.44/cvs/Linux x86_64)

Revision  Changes    Path
1.19                 sci-physics/lhapdf/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/lhapdf/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/lhapdf/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/lhapdf/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-physics/lhapdf/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	6 Aug 2011 20:53:59 -0000	1.18
+++ ChangeLog	27 Feb 2012 02:35:17 -0000	1.19
@@ -1,6 +1,12 @@
 # ChangeLog for sci-physics/lhapdf
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-physics/lhapdf/ChangeLog,v 1.18 2011/08/06 20:53:59 bicatali Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-physics/lhapdf/ChangeLog,v 1.19 2012/02/27 02:35:17 bicatali Exp $
+
+*lhapdf-5.8.7 (27 Feb 2012)
+
+  27 Feb 2012; Sébastien Fabbro <bicatali@gentoo.org> -lhapdf-5.8.4-r1.ebuild,
+  -lhapdf-5.8.5.ebuild, +lhapdf-5.8.7.ebuild:
+  Version bump
 
 *lhapdf-5.8.6 (06 Aug 2011)
 



1.1                  sci-physics/lhapdf/lhapdf-5.8.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/lhapdf/lhapdf-5.8.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/lhapdf/lhapdf-5.8.7.ebuild?rev=1.1&content-type=text/plain

Index: lhapdf-5.8.7.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-physics/lhapdf/lhapdf-5.8.7.ebuild,v 1.1 2012/02/27 02:35:17 bicatali Exp $

EAPI=4

inherit versionator eutils

MY_PV=$(get_version_component_range 1-3 ${PV})
MY_PF=${PN}-${MY_PV}

DESCRIPTION="Les Houches Parton Density Function unified library"
HOMEPAGE="http://projects.hepforge.org/lhapdf/"
SRC_URI="http://www.hepforge.org/archive/lhapdf/${MY_PF}.tar.gz
	test? (
		http://svn.hepforge.org/${PN}/pdfsets/tags/${MY_PV}/cteq61.LHgrid
		http://svn.hepforge.org/${PN}/pdfsets/tags/${MY_PV}/MRST2004nlo.LHgrid
		http://svn.hepforge.org/${PN}/pdfsets/tags/${MY_PV}/cteq61.LHpdf
		octave? ( http://svn.hepforge.org/${PN}/pdfsets/tags/${MY_PV}/cteq5l.LHgrid ) )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cxx doc examples octave python static-libs test"
REQUIRED_USE="octave? ( cxx )"
RDEPEND="octave? ( sci-mathematics/octave )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen[latex] )
	python? ( dev-lang/swig )"

S="${WORKDIR}/${MY_PF}"

src_prepare() {
	# do not create extra latex docs
	sed -i \
		-e 's/GENERATE_LATEX.*=YES/GENERATE_LATEX = NO/g' \
		ccwrap/Doxyfile || die
}

src_configure() {
	econf \
		$(use_enable cxx ccwrap) \
		$(use_enable cxx old-ccwrap ) \
		$(use_enable doc doxygen) \
		$(use_enable octave) \
		$(use_enable python pyext) \
		$(use_enable static-libs static)
}

src_test() {
	# need to make a bogus link for octave test
	ln -s "${DISTDIR}" PDFsets
	LHAPATH="${PWD}/PDFsets" \
		LD_LIBRARY_PATH="${PWD}/lib/.libs:${LD_LIBRARY_PATH}" \
		emake check
}

src_install() {
	default
	# leftover
	rm -rf "${ED}"/usr/share/${PN}/doc || die
	use doc && use cxx && dohtml -r ccwrap/doxy/html/*
	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins examples/*.{f,cc}
	fi
}

pkg_postinst() {
	elog "To install data files, you have to run as root:"
	elog "lhapdf-getdata --dest=${EROOT}usr/share/lhapdf/PDFsets --all"
}