[gentoo-commits] gentoo-x86 commit in dev-libs/expat: ChangeLog expat-2.0.1-r6.ebuild

["Samuli Suominen (ssuominen)" <ssuominen@gentoo.org>]

ssuominen    12/02/25 11:34:44

  Modified:             ChangeLog
  Added:                expat-2.0.1-r6.ebuild
  Log:
  USE=unicode to control building libexpatu and libexpatw. Use correct CFLAGS and CPPFLAGS in the src_configure() phase for configuring unicode libraries.
  
  (Portage version: 2.2.0_alpha89/cvs/Linux x86_64)

Revision  Changes    Path
1.109                dev-libs/expat/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/expat/ChangeLog?rev=1.109&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/expat/ChangeLog?rev=1.109&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/expat/ChangeLog?r1=1.108&r2=1.109

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/expat/ChangeLog,v
retrieving revision 1.108
retrieving revision 1.109
diff -u -r1.108 -r1.109
--- ChangeLog	22 Dec 2011 16:44:36 -0000	1.108
+++ ChangeLog	25 Feb 2012 11:34:44 -0000	1.109
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/expat
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/expat/ChangeLog,v 1.108 2011/12/22 16:44:36 ssuominen Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/expat/ChangeLog,v 1.109 2012/02/25 11:34:44 ssuominen Exp $
+
+*expat-2.0.1-r6 (25 Feb 2012)
+
+  25 Feb 2012; Samuli Suominen <ssuominen@gentoo.org> +expat-2.0.1-r6.ebuild:
+  USE="unicode" to control building libexpatu and libexpatw. Use correct CFLAGS
+  and CPPFLAGS in the src_configure() phase for configuring the unicode
+  libraries.
 
   22 Dec 2011; Samuli Suominen <ssuominen@gentoo.org> -expat-2.0.1-r3.ebuild,
   -expat-2.0.1-r4.ebuild:



1.1                  dev-libs/expat/expat-2.0.1-r6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/expat/expat-2.0.1-r6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/expat/expat-2.0.1-r6.ebuild?rev=1.1&content-type=text/plain

Index: expat-2.0.1-r6.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/expat/expat-2.0.1-r6.ebuild,v 1.1 2012/02/25 11:34:44 ssuominen Exp $

EAPI=4
inherit eutils libtool toolchain-funcs

DESCRIPTION="XML parsing libraries"
HOMEPAGE="http://expat.sourceforge.net/"
SRC_URI="mirror://sourceforge/expat/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="elibc_FreeBSD examples static-libs unicode"

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}-check_stopped_parser.patch \
		"${FILESDIR}"/${P}-fix_bug_1990430.patch \
		"${FILESDIR}"/${P}-CVE-2009-3560-revised.patch

	elibtoolize
	epunt_cxx

	mkdir "${S}"-build{,u,w} || die
}

src_configure() {
	local myconf="$(use_enable static-libs static)"

	pushd "${S}"-build >/dev/null
	ECONF_SOURCE="${S}" econf ${myconf}
	popd >/dev/null

	if use unicode; then
		pushd "${S}"-buildu >/dev/null
		CPPFLAGS+=" -DXML_UNICODE" ECONF_SOURCE="${S}" econf ${myconf}
		popd >/dev/null

		pushd "${S}"-buildw >/dev/null
		CFLAGS+=" -fshort-wchar" CPPFLAGS+=" -DXML_UNICODE_WCHAR_T" ECONF_SOURCE="${S}" econf ${myconf}
		popd >/dev/null
	fi
}

src_compile() {
	pushd "${S}"-build >/dev/null
	emake
	popd >/dev/null

	if use unicode; then
		pushd "${S}"-buildu >/dev/null
		emake buildlib LIBRARY=libexpatu.la
		popd >/dev/null

		pushd "${S}"-buildw >/dev/null
		emake buildlib LIBRARY=libexpatw.la
		popd >/dev/null
	fi
}

src_install() {
	dodoc Changes README
	dohtml doc/*

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins examples/*.c
	fi

	pushd "${S}"-build >/dev/null
	emake install DESTDIR="${D}"
	popd >/dev/null

	if use unicode; then
		pushd "${S}"-buildu >/dev/null
		emake installlib DESTDIR="${D}" LIBRARY=libexpatu.la
		popd >/dev/null

		pushd "${S}"-buildw >/dev/null
		emake installlib DESTDIR="${D}" LIBRARY=libexpatw.la
		popd >/dev/null
	fi

	use static-libs || rm -f "${ED}"usr/lib*/libexpat{,u,w}.la

	# libgeom in /lib and ifconfig in /sbin require it on FreeBSD since we
	# stripped the libbsdxml copy starting from freebsd-lib-8.2-r1
	use elibc_FreeBSD && gen_usr_ldscript -a expat{,u,w}
}