[gentoo-commits] gentoo-x86 commit in www-misc/vdradmin-am: vdradmin-am-3.6.8.ebuild ChangeLog vdradmin-am-3.6.9.ebuild

["Joerg Bornkessel (hd_brummy)" <hd_brummy@gentoo.org>]

hd_brummy    12/02/24 20:55:01

  Modified:             vdradmin-am-3.6.8.ebuild ChangeLog
  Added:                vdradmin-am-3.6.9.ebuild
  Log:
  bump; #bug 405513, thx to T.Rheinhold for testing
  
  (Portage version: 2.1.10.11/cvs/Linux i686)

Revision  Changes    Path
1.4                  www-misc/vdradmin-am/vdradmin-am-3.6.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-misc/vdradmin-am/vdradmin-am-3.6.8.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-misc/vdradmin-am/vdradmin-am-3.6.8.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-misc/vdradmin-am/vdradmin-am-3.6.8.ebuild?r1=1.3&r2=1.4

Index: vdradmin-am-3.6.8.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-misc/vdradmin-am/vdradmin-am-3.6.8.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- vdradmin-am-3.6.8.ebuild	21 Dec 2011 09:01:25 -0000	1.3
+++ vdradmin-am-3.6.8.ebuild	24 Feb 2012 20:55:01 -0000	1.4
@@ -1,6 +1,6 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-misc/vdradmin-am/vdradmin-am-3.6.8.ebuild,v 1.3 2011/12/21 09:01:25 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-misc/vdradmin-am/vdradmin-am-3.6.8.ebuild,v 1.4 2012/02/24 20:55:01 hd_brummy Exp $
 
 EAPI=4
 
@@ -51,12 +51,6 @@
 pkg_setup() {
 	enewgroup ${VDRADMIN_GROUP}
 	enewuser ${VDRADMIN_USER} -1 /bin/bash ${CACHE_DIR} ${VDRADMIN_GROUP}
-
-	if ! use vdr; then
-		elog
-		elog "You can run ${PN} outside a vdr install. For minimal"
-		elog "functionality you need access to the epg.data file of your VDR."
-	fi
 }
 
 src_prepare() {



1.25                 www-misc/vdradmin-am/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-misc/vdradmin-am/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-misc/vdradmin-am/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-misc/vdradmin-am/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-misc/vdradmin-am/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	25 Jan 2012 20:18:37 -0000	1.24
+++ ChangeLog	24 Feb 2012 20:55:01 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for www-misc/vdradmin-am
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-misc/vdradmin-am/ChangeLog,v 1.24 2012/01/25 20:18:37 billie Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-misc/vdradmin-am/ChangeLog,v 1.25 2012/02/24 20:55:01 hd_brummy Exp $
+
+*vdradmin-am-3.6.9 (24 Feb 2012)
+
+  24 Feb 2012; Joerg Bornkessel <hd_brummy@gentoo.org>
+  vdradmin-am-3.6.8.ebuild, +vdradmin-am-3.6.9.ebuild:
+  bump; #bug 405513, thx to T.Rheinhold for testing
 
   25 Jan 2012; Daniel Pielmeier <billie@gentoo.org>
   -vdradmin-am-3.6.7-r1.ebuild:



1.1                  www-misc/vdradmin-am/vdradmin-am-3.6.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-misc/vdradmin-am/vdradmin-am-3.6.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-misc/vdradmin-am/vdradmin-am-3.6.9.ebuild?rev=1.1&content-type=text/plain

Index: vdradmin-am-3.6.9.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-misc/vdradmin-am/vdradmin-am-3.6.9.ebuild,v 1.1 2012/02/24 20:55:01 hd_brummy Exp $

EAPI="4"

inherit eutils ssl-cert

DESCRIPTION="WWW Admin for the Video Disk Recorder"
HOMEPAGE="http://andreas.vdr-developer.org/vdradmin-am/index.html"
SRC_URI="http://andreas.vdr-developer.org/vdradmin-am/download/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ipv6 ssl +vdr"

DEPEND="dev-lang/perl
	dev-perl/Template-Toolkit
	dev-perl/libwww-perl
	dev-perl/URI
	dev-perl/Locale-gettext
	virtual/perl-IO-Compress
	ipv6? ( dev-perl/IO-Socket-INET6 )
	ssl? ( dev-perl/IO-Socket-SSL )
	vdr? ( media-video/vdr )
	perl-core/libnet
	dev-perl/Authen-SASL
	dev-perl/Digest-HMAC"
RDEPEND="${DEPEND}"

ETC_DIR=/etc/vdradmin
CERTS_DIR=/etc/vdradmin/certs
LIB_DIR=/usr/share/vdradmin
CACHE_DIR=/var/cache/vdradmin
VDRADMIN_USER=vdradmin
VDRADMIN_GROUP=vdradmin

create_ssl_cert() {
	# The ssl-cert eclass is not flexible enough so do some steps manually
	SSL_ORGANIZATION="${SSL_ORGANIZATION:-vdradmin-am}"
	SSL_COMMONNAME="${SSL_COMMONNAME:-`hostname -f`}"

	gen_cnf || return 1

	gen_key 1 || return 1
	gen_csr 1 || return 1
	gen_crt 1 || return 1
}

pkg_setup() {
	enewgroup ${VDRADMIN_GROUP}
	enewuser ${VDRADMIN_USER} -1 /bin/bash ${CACHE_DIR} ${VDRADMIN_GROUP}
}

src_prepare() {
	sed -i vdradmind.pl \
		-e "s-FILES_IN_SYSTEM    = 0;-FILES_IN_SYSTEM    = 1;-g" || die
}

src_install() {
	newinitd "${FILESDIR}"/vdradmin-3.6.7.init vdradmin
	newconfd "${FILESDIR}"/vdradmin-3.6.6.conf vdradmin

	insinto /etc/logrotate.d
	newins "${FILESDIR}"/vdradmin-3.6.6.logrotate vdradmin

	newbin vdradmind.pl vdradmind

	insinto ${LIB_DIR}/template
	doins -r "${S}"/template/*

	insinto ${LIB_DIR}/lib/Template/Plugin
	doins -r "${S}"/lib/Template/Plugin/JavaScript.pm

	insinto /usr/share/locale/
	doins -r "${S}"/locale/*

	newman vdradmind.pl.1 vdradmind.8

	dodoc CREDITS ChangeLog FAQ HISTORY INSTALL README* REQUIREMENTS
	docinto contrib
	dodoc "${S}"/contrib/*

	diropts "-m755 -o ${VDRADMIN_USER} -g ${VDRADMIN_GROUP}"
	keepdir ${ETC_DIR}
	use ssl && keepdir ${CERTS_DIR}
}

pkg_preinst() {
	install -m 0644 -o ${VDRADMIN_USER} -g ${VDRADMIN_GROUP} /dev/null \
		"${D}"${ETC_DIR}/vdradmind.conf || die

	if [[ -f "${ROOT}"${ETC_DIR}/vdradmind.conf ]]; then
		cp "${ROOT}"${ETC_DIR}/vdradmind.conf \
			"${D}"${ETC_DIR}/vdradmind.conf || die
	else
		elog
		elog "Creating a new config-file."
		echo

		cat <<-EOF > "${D}"${ETC_DIR}/vdradmind.conf
			VDRCONFDIR = "${ROOT%/}"/etc/vdr
			VIDEODIR = "${ROOT%/}"/var/vdr/video
			EPG_FILENAME = "${ROOT%/}"/var/vdr/video/epg.data
			EPGIMAGES = "${ROOT%/}"/var/vdr/video/epgimages
			PASSWORD = gentoo-vdr
			USERNAME = gentoo-vdr
		EOF
		# Feed it with newlines
		yes "" \
			| "${D}"/usr/bin/vdradmind --cfgdir "${D}"${ETC_DIR} --config \
			|sed -e 's/: /: \n/g'

		[[ ${PIPESTATUS[1]} == "0" ]] \
			|| die "Failed to create initial configuration."

		elog
		elog "Created default user/password: gentoo-vdr/gentoo-vdr"
		elog
		elog "You can run \"emerge --config ${PN}\" if the default-values"
		elog "do not match your installation or change them in the Setup-Menu"
		elog "of the Web-Interface."
	fi
}

pkg_postinst() {
	if use ipv6; then
		elog
		elog "To make use of the ipv6 protocol"
		elog "you need to enable it in ${ROOT%/}/etc/conf.d/vdradmin"
	fi

	if use ssl; then
		elog
		elog "To use ssl connection to your vdr"
		elog "you need to enable it in ${ROOT%/}/etc/conf.d/vdradmin"

		if [[ ! -f "${ROOT}"${CERTS_DIR}/server-cert.pem || \
			! -f "${ROOT}"${CERTS_DIR}/server-key.pem ]]; then
			create_ssl_cert
			local base=$(get_base 1)
			install -D -m 0400 -o ${VDRADMIN_USER} -g ${VDRADMIN_GROUP} \
				"${base}".key "${ROOT}"${CERTS_DIR}/server-key.pem || die
			install -D -m 0444 -o ${VDRADMIN_USER} -g ${VDRADMIN_GROUP} \
				"${base}".crt "${ROOT}"${CERTS_DIR}/server-cert.pem || die
		fi
	fi

	elog
	elog "To extend ${PN} you can emerge"
	elog ">=media-plugins/vdr-epgsearch-0.9.25 to search the EPG,"
	elog "media-plugins/vdr-streamdev for livetv streaming and/or"
	elog "media-video/vdr with USE=\"liemikuutio\" to rename recordings"
	elog "on the machine running the VDR you connect to with ${PN}."
}

pkg_config() {
	"${ROOT}"/usr/bin/vdradmind -c
}