[gentoo-commits] gentoo-x86 commit in www-client/lynx: ChangeLog lynx-2.8.8_pre12.ebuild

["Tim Harder (radhermit)" <radhermit@gentoo.org>]

radhermit    12/02/23 03:47:36

  Modified:             ChangeLog
  Added:                lynx-2.8.8_pre12.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha87/cvs/Linux x86_64)

Revision  Changes    Path
1.113                www-client/lynx/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/lynx/ChangeLog?rev=1.113&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/lynx/ChangeLog?rev=1.113&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/lynx/ChangeLog?r1=1.112&r2=1.113

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/lynx/ChangeLog,v
retrieving revision 1.112
retrieving revision 1.113
diff -u -r1.112 -r1.113
--- ChangeLog	20 Feb 2012 23:12:14 -0000	1.112
+++ ChangeLog	23 Feb 2012 03:47:36 -0000	1.113
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/lynx
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/lynx/ChangeLog,v 1.112 2012/02/20 23:12:14 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/lynx/ChangeLog,v 1.113 2012/02/23 03:47:36 radhermit Exp $
+
+*lynx-2.8.8_pre12 (23 Feb 2012)
+
+  23 Feb 2012; Tim Harder <radhermit@gentoo.org> +lynx-2.8.8_pre12.ebuild:
+  Version bump.
 
 *lynx-2.8.8_pre11 (20 Feb 2012)
 



1.1                  www-client/lynx/lynx-2.8.8_pre12.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/lynx/lynx-2.8.8_pre12.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/lynx/lynx-2.8.8_pre12.ebuild?rev=1.1&content-type=text/plain

Index: lynx-2.8.8_pre12.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/lynx/lynx-2.8.8_pre12.ebuild,v 1.1 2012/02/23 03:47:36 radhermit Exp $

EAPI=4

inherit eutils versionator

# VERSIONING SCHEME TRANSLATION
# Upstream	:	Gentoo
# rel.		:	_p
# pre.		:	_rc
# dev.		:	_pre

case ${PV} in
	*_pre*) MY_P="${PN}${PV/_pre/dev.}" ;;
	*_rc*)  MY_P="${PN}${PV/_rc/pre.}" ;;
	*_p*|*) MY_P="${PN}${PV/_p/rel.}" ;;
esac

DESCRIPTION="An excellent console-based web browser with ssl support"
HOMEPAGE="http://lynx.isc.org/"
SRC_URI="http://lynx.isc.org/current/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="bzip2 cjk gnutls idn ipv6 nls ssl unicode"

RDEPEND="sys-libs/ncurses[unicode?]
	sys-libs/zlib
	nls? ( virtual/libintl )
	ssl? (
		!gnutls? ( >=dev-libs/openssl-0.9.8 )
		gnutls? ( >=net-libs/gnutls-2.6.4 )
	)
	bzip2? ( app-arch/bzip2 )
	idn? ( net-dns/libidn )"

DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	>=dev-util/pkgconfig-0.23"

S="${WORKDIR}/${PN}$(replace_all_version_separators - $(get_version_component_range 1-3))"

pkg_setup() {
	! use ssl && elog "SSL support disabled; you will not be able to access secure websites."
}

src_prepare() {
	# fix up toplevel makefile to enable parallel make (bug #262972)
	#
	# add '+' prefix to lines using $(MAKE_RECUR),
	# making sure '+' comes after leading whitespace
	sed -i -e '/$(MAKE_RECUR)/ s/\([[:blank:]]\)/\1+/' makefile.in || \
	    die "failed to update makefile.in"

	# fix configure for openssl compiled with kerberos (bug #267749)
	epatch "${FILESDIR}/lynx-2.8.7-configure-openssl.patch"
	epatch "${FILESDIR}"/${PN}-2.8.6-mint.patch
}

src_configure() {
	local myargs

	if use ssl ; then
		# --with-gnutls and --with-ssl are alternatives,
		# the latter enabling openssl support so it should be
		# _not_ be used if gnutls ssl implementation is desired
		if use gnutls ; then
			myargs+=" --with-gnutls" # ssl implementation = gnutls
		else
			myargs+=" --with-ssl"    # ssl implementation = openssl
		fi
	fi

	use unicode && myargs+=" --with-screen=ncursesw"

	econf \
		--enable-nested-tables \
		--enable-cgi-links \
		--enable-persistent-cookies \
		--enable-prettysrc \
		--enable-nsl-fork \
		--enable-file-upload \
		--enable-read-eta \
		--enable-color-style \
		--enable-scrollbar \
		--enable-included-msgs \
		--enable-externs \
		--with-zlib \
		$(use_enable nls) \
		$(use_enable idn idna) \
		$(use_enable ipv6) \
		$(use_enable cjk) \
		$(use_enable unicode japanese-utf8) \
		$(use_with bzip2 bzlib) \
		$myargs
}

src_install() {
	emake install DESTDIR="${D}"

	sed -i -e "s|^HELPFILE.*$|HELPFILE:file://localhost/usr/share/doc/${PF}/lynx_help/lynx_help_main.html|" \
			"${ED}"/etc/lynx.cfg || die "lynx.cfg not found"
	if use unicode ; then
		sed -i -e '/^#CHARACTER_SET:/ c\CHARACTER_SET:utf-8' \
				"${ED}"/etc/lynx.cfg || die "lynx.cfg not found"
	fi
	dodoc CHANGES COPYHEADER PROBLEMS README
	docinto docs
	dodoc docs/*
	docinto lynx_help
	dodoc lynx_help/*.txt
	dohtml -r lynx_help/*
}