[gentoo-commits] gentoo-x86 commit in sci-biology/wgs-assembler: ChangeLog wgs-assembler-7.0.ebuild

[gentoo-commits] gentoo-x86 commit in sci-biology/wgs-assembler: ChangeLog wgs-assembler-7.0.ebuild

[Andrey Kislyuk (weaver)]

weaver      12/02/06 09:12:38

  Modified:             ChangeLog
  Added:                wgs-assembler-7.0.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha74/cvs/Linux x86_64)

Revision  Changes    Path
1.9                  sci-biology/wgs-assembler/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-biology/wgs-assembler/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-biology/wgs-assembler/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-biology/wgs-assembler/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-biology/wgs-assembler/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	20 Mar 2011 20:19:27 -0000	1.8
+++ ChangeLog	6 Feb 2012 09:12:38 -0000	1.9
@@ -1,6 +1,11 @@
 # ChangeLog for sci-biology/wgs-assembler
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-biology/wgs-assembler/ChangeLog,v 1.8 2011/03/20 20:19:27 weaver Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-biology/wgs-assembler/ChangeLog,v 1.9 2012/02/06 09:12:38 weaver Exp $
+
+*wgs-assembler-7.0 (06 Feb 2012)
+
+  06 Feb 2012; Andrey Kislyuk <weaver@gentoo.org> +wgs-assembler-7.0.ebuild:
+  Version bump
 
   20 Mar 2011; Andrey Kislyuk <weaver@gentoo.org> wgs-assembler-5.4.ebuild,
   wgs-assembler-6.1.ebuild:



1.1                  sci-biology/wgs-assembler/wgs-assembler-7.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-biology/wgs-assembler/wgs-assembler-7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-biology/wgs-assembler/wgs-assembler-7.0.ebuild?rev=1.1&content-type=text/plain

Index: wgs-assembler-7.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-biology/wgs-assembler/wgs-assembler-7.0.ebuild,v 1.1 2012/02/06 09:12:38 weaver Exp $

EAPI="2"

inherit eutils toolchain-funcs

DESCRIPTION="A de novo whole-genome shotgun DNA sequence assembler, also known as the Celera Assembler and CABOG"
HOMEPAGE="http://sourceforge.net/projects/wgs-assembler/"
SRC_URI="mirror://sourceforge/${PN}/wgs-${PV}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
IUSE=""
KEYWORDS="~amd64 ~x86"

DEPEND="x11-libs/libXt
	!x11-terms/terminator"
RDEPEND="${DEPEND}
	app-shells/tcsh
	dev-perl/Log-Log4perl"

S="${WORKDIR}/wgs-${PV}"

src_configure() {
	sed -i -e "s/CC *= *gcc/CC = $(tc-getCC)/" \
		-e "s/CXX *= *g++/CXX = $(tc-getCXX)/" \
		"${S}"/src/c_make.as || die
	sed -i -e "s/CC *:=.*/CC := $(tc-getCC)/" \
		-e "s/CXX *:=.*/CXX := $(tc-getCXX)/" \
		"${S}"/kmer/configure.sh || die
	cd "${S}/kmer"
	./configure.sh || die
}

src_compile() {
	# not really an install target
	emake -C kmer -j1 install || die
	emake -C src -j1 SITE_NAME=LOCAL || die
}

src_install() {
	OSTYPE=$(uname)
	MACHTYPE=$(uname -m)
	MACHTYPE=${MACHTYPE/x86_64/amd64}
	MY_S="${OSTYPE}-${MACHTYPE}"
	sed -i 's|#!/usr/local/bin/|#!/usr/bin/env |' $(find $MY_S -type f) || die

	sed -i '/sub getBinDirectory ()/ a return "/usr/bin";' ${MY_S}/bin/runCA* || die
	sed -i '/sub getBinDirectoryShellCode ()/ a return "bin=/usr/bin\n";' ${MY_S}/bin/runCA* || die
	sed -i '1 a use lib "/usr/share/'${PN}'/lib";' $(find $MY_S -name '*.p*') || die

	dobin kmer/${MY_S}/bin/* || die
	insinto /usr/$(get_libdir)/${PN}
	doins kmer/${MY_S}/lib/* || die
	# Collisions
	# dolib.a kmer/${MY_S}/lib/* || die
	insinto /usr/include/${PN}
	doins kmer/${MY_S}/include/*

	insinto /usr/share/${PN}
	doins -r ${MY_S}/bin/spec
	insinto /usr/share/${PN}/lib
	doins -r ${MY_S}/bin/TIGR || die
	rm -rf ${MY_S}/bin/{TIGR,spec}
	dobin ${MY_S}/bin/* || die
	dolib.a ${MY_S}/lib/* || die
	dodoc README
}