* [gentoo-commits] gentoo-x86 commit in gnome-extra/cinnamon: ChangeLog cinnamon-1.2.ebuild
@ 2012-01-25 8:43 Alexandre Rostovtsev (tetromino)
0 siblings, 0 replies; only message in thread
From: Alexandre Rostovtsev (tetromino) @ 2012-01-25 8:43 UTC (permalink / raw
To: gentoo-commits
tetromino 12/01/25 08:43:16
Modified: ChangeLog
Added: cinnamon-1.2.ebuild
Log:
Version bump. Adds support for applets and desktop effects. Cinnamon now uses its own window manager (muffin) and is incompatible with gnome-shell themes. Synced with gnome-shell ebuild for optional networkmanager patch and hardened/PaX marking.
(Portage version: 2.2.0_alpha84/cvs/Linux x86_64)
Revision Changes Path
1.3 gnome-extra/cinnamon/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/ChangeLog?r1=1.2&r2=1.3
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog 10 Jan 2012 05:53:59 -0000 1.2
+++ ChangeLog 25 Jan 2012 08:43:16 -0000 1.3
@@ -1,6 +1,15 @@
# ChangeLog for gnome-extra/cinnamon
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/ChangeLog,v 1.2 2012/01/10 05:53:59 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/ChangeLog,v 1.3 2012/01/25 08:43:16 tetromino Exp $
+
+*cinnamon-1.2 (25 Jan 2012)
+
+ 25 Jan 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+ +cinnamon-1.2.ebuild, +files/cinnamon-1.2-optional-networkmanager.patch:
+ Version bump. Adds support for applets and desktop effects. Cinnamon now uses
+ its own window manager (muffin) and is incompatible with gnome-shell themes.
+ Synced with gnome-shell ebuild for optional networkmanager patch and
+ hardened/PaX marking.
10 Jan 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
cinnamon-1.1.3.ebuild:
1.1 gnome-extra/cinnamon/cinnamon-1.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.2.ebuild?rev=1.1&content-type=text/plain
Index: cinnamon-1.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.2.ebuild,v 1.1 2012/01/25 08:43:16 tetromino Exp $
EAPI="4"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_DEPEND="2:2.5"
inherit autotools eutils gnome2 pax-utils python
DESCRIPTION="A fork of GNOME Shell with layout similar to GNOME 2"
HOMEPAGE="http://cinnamon.linuxmint.com/"
SRC_URI="https://github.com/linuxmint/Cinnamon/tarball/${PV} -> ${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
IUSE="+bluetooth +networkmanager"
KEYWORDS="~amd64 ~x86"
# gnome-desktop-2.91.2 is needed due to header changes, db82a33 in gnome-desktop
# latest gsettings-desktop-schemas is needed due to commit 602fa1c6
# latest g-c-c is needed due to https://bugs.gentoo.org/show_bug.cgi?id=360057
# libXfixes-5.0 needed for pointer barriers
# gnome-menus-3.2.0.1-r1 needed for new 10-xdg-menu-gnome
COMMON_DEPEND=">=dev-libs/glib-2.29.10:2
>=dev-libs/gjs-1.29.18
>=dev-libs/gobject-introspection-0.10.1
x11-libs/gdk-pixbuf:2[introspection]
>=x11-libs/gtk+-3.0.0:3[introspection]
>=media-libs/clutter-1.7.5:1.0[introspection]
app-misc/ca-certificates
>=dev-libs/folks-0.5.2
>=dev-libs/json-glib-0.13.2
>=gnome-base/gnome-desktop-2.91.2:3
>=gnome-base/gsettings-desktop-schemas-2.91.91
>=gnome-extra/evolution-data-server-2.91.6
>=media-libs/gstreamer-0.10.16:0.10
>=media-libs/gst-plugins-base-0.10.16:0.10
>=net-im/telepathy-logger-0.2.4[introspection]
net-libs/libsoup:2.4[introspection]
>=net-libs/telepathy-glib-0.15.5[introspection]
>=net-misc/networkmanager-0.8.999[introspection]
>=sys-auth/polkit-0.100[introspection]
>=x11-wm/muffin-1.0.0[introspection]
dev-libs/dbus-glib
dev-libs/libxml2:2
x11-libs/pango[introspection]
>=dev-libs/libcroco-0.6.2:0.6
gnome-base/gconf:2[introspection]
>=gnome-base/gnome-menus-3.2.0.1-r1:3[introspection]
gnome-base/librsvg
media-libs/libcanberra
media-sound/pulseaudio
>=x11-libs/startup-notification-0.11
x11-libs/libX11
>=x11-libs/libXfixes-5.0
x11-apps/mesa-progs
bluetooth? ( >=net-wireless/gnome-bluetooth-3.1.0[introspection] )
networkmanager? (
gnome-base/libgnome-keyring
>=net-misc/networkmanager-0.8.999[introspection] )"
# Runtime-only deps are probably incomplete and approximate.
# Each block:
# 2. Introspection stuff + dconf needed via imports.gi.*
# 3. gnome-session is needed for gnome-session-quit
# 4. Control shell settings
# 5. accountsservice is needed for GdmUserManager (0.6.14 needed for fast
# user switching with gdm-3.1.x)
# 6. caribou needed for on-screen keyboard
# 7. xdg-utils needed for xdg-open, used by extension tool
RDEPEND="${COMMON_DEPEND}
>=gnome-base/dconf-0.4.1
>=gnome-base/libgnomekbd-2.91.4[introspection]
sys-power/upower[introspection]
>=gnome-base/gnome-session-3.2.1-r1
>=gnome-base/gnome-settings-daemon-2.91
>=gnome-base/gnome-control-center-2.91.92-r1
>=sys-apps/accountsservice-0.6.14[introspection]
>=app-accessibility/caribou-0.3
x11-misc/xdg-utils
networkmanager? (
net-misc/mobile-broadband-provider-info
sys-libs/timezone-data )"
DEPEND="${COMMON_DEPEND}
>=sys-devel/gettext-0.17
>=dev-util/pkgconfig-0.22
>=dev-util/intltool-0.40
gnome-base/gnome-common
!!=dev-lang/spidermonkey-1.8.2*"
# libmozjs.so is picked up from /usr/lib while compiling, so block at build-time
# https://bugs.gentoo.org/show_bug.cgi?id=360413
S="${WORKDIR}/linuxmint-Cinnamon-185383f"
pkg_setup() {
DOCS="AUTHORS NEWS README"
# Don't error out on warnings
G2CONF="${G2CONF}
--enable-compile-warnings=maximum
--disable-schemas-compile
--disable-jhbuild-wrapper-script
$(use_with bluetooth)
$(use_enable networkmanager)
--with-ca-certificates=${EPREFIX}/etc/ssl/certs/ca-certificates.crt
BROWSER_PLUGIN_DIR=${EPREFIX}/usr/$(get_libdir)/nsbrowser/plugins"
python_set_active_version 2
python_pkg_setup
}
src_prepare() {
# Fix automagic gnome-bluetooth dep, bug #398145
epatch "${FILESDIR}/${PN}-1.1.3-automagic-gnome-bluetooth.patch"
# Make networkmanager optional, bug #398593
epatch "${FILESDIR}/${PN}-1.2-optional-networkmanager.patch"
# Do not depend on libgnome (patch from gnome-shell 3.3.x)
epatch "${FILESDIR}/${PN}-1.1.3-extensionjs_path.patch"
epatch "${FILESDIR}/${PN}-1.1.3-xdg-open.patch"
# Gentoo uses /usr/libexec
sed -e "s:/usr/lib/gnome-session/gnome-session-check-accelerated:${EPREFIX}/usr/libexec/gnome-session-check-accelerated:" \
-i "files/usr/share/gnome-session/sessions/cinnamon.session" || die "sed 1 failed"
eautoreconf
gnome2_src_prepare
# Drop G_DISABLE_DEPRECATED for sanity on glib upgrades; bug #384765
# Note: sed Makefile.in because it is generated from several Makefile.ams
sed -e 's/-DG_DISABLE_DEPRECATED//g' \
-i src/Makefile.in browser-plugin/Makefile.in || die "sed 2 failed"
}
src_install() {
gnome2_src_install
python_convert_shebangs 2 "${D}"/usr/bin/cinnamon-extension-tool
# Required for gnome-shell on hardened/PaX, bug #398941
pax-mark mr "${ED}usr/bin/cinnamon"
}
pkg_postinst() {
gnome2_pkg_postinst
if ! has_version '>=media-libs/gst-plugins-good-0.10.23' || \
! has_version 'media-plugins/gst-plugins-vp8'; then
ewarn "To make use of Cinnamon's built-in screen recording utility,"
ewarn "you need to either install >=media-libs/gst-plugins-good-0.10.23"
ewarn "and media-plugins/gst-plugins-vp8, or use dconf-editor to change"
ewarn "apps.gnome-shell.recorder/pipeline to what you want to use."
fi
if ! has_version ">=x11-base/xorg-server-1.11"; then
ewarn "If you use multiple screens, it is highly recommended that you"
ewarn "upgrade to >=x11-base/xorg-server-1.11 to be able to make use of"
ewarn "pointer barriers which will make it easier to use hot corners."
fi
if has_version "<x11-drivers/ati-drivers-12"; then
ewarn "Cinnamon has been reported to show graphical corruption under"
ewarn "x11-drivers/ati-drivers-11.*; you may want to use GNOME in"
ewarn "fallback mode, or switch to open-source drivers."
fi
if has_version "media-libs/mesa[video_cards_radeon]"; then
elog "Cinnamon is unstable under classic-mode r300/r600 mesa drivers."
elog "Make sure that gallium architecture for r300 and r600 drivers is"
elog "selected using 'eselect mesa'."
if ! has_version "media-libs/mesa[gallium]"; then
ewarn "You will need to emerge media-libs/mesa with USE=gallium."
fi
fi
if has_version "media-libs/mesa[video_cards_intel]"; then
elog "Cinnamon is unstable under gallium-mode i915/i965 mesa drivers."
elog "Make sure that classic architecture for i915 and i965 drivers is"
elog "selected using 'eselect mesa'."
if ! has_version "media-libs/mesa[classic]"; then
ewarn "You will need to emerge media-libs/mesa with USE=classic."
fi
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-01-25 8:43 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-01-25 8:43 [gentoo-commits] gentoo-x86 commit in gnome-extra/cinnamon: ChangeLog cinnamon-1.2.ebuild Alexandre Rostovtsev (tetromino)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox