[gentoo-commits] gentoo-x86 commit in dev-games/cegui: cegui-0.7.6.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-games/cegui: cegui-0.7.6.ebuild ChangeLog

[Tristan Heaven (tristan)]

tristan     12/01/25 01:01:51

  Modified:             ChangeLog
  Added:                cegui-0.7.6.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.40                 dev-games/cegui/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/cegui/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/cegui/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/cegui/ChangeLog?r1=1.39&r2=1.40

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-games/cegui/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog	9 Nov 2011 02:04:08 -0000	1.39
+++ ChangeLog	25 Jan 2012 01:01:51 -0000	1.40
@@ -1,6 +1,11 @@
 # ChangeLog for dev-games/cegui
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-games/cegui/ChangeLog,v 1.39 2011/11/09 02:04:08 mr_bones_ Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-games/cegui/ChangeLog,v 1.40 2012/01/25 01:01:51 tristan Exp $
+
+*cegui-0.7.6 (25 Jan 2012)
+
+  25 Jan 2012; Tristan Heaven <tristan@gentoo.org> +cegui-0.7.6.ebuild:
+  Version bump
 
   09 Nov 2011; Michael Sterrett <mr_bones_@gentoo.org> cegui-0.7.5-r1.ebuild:
   build with newer zlib (bug #389863); kill ogre use flag (bug #387103)



1.1                  dev-games/cegui/cegui-0.7.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/cegui/cegui-0.7.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/cegui/cegui-0.7.6.ebuild?rev=1.1&content-type=text/plain

Index: cegui-0.7.6.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-games/cegui/cegui-0.7.6.ebuild,v 1.1 2012/01/25 01:01:51 tristan Exp $

EAPI=4

MY_P=CEGUI-${PV}
MY_D=CEGUI-DOCS-${PV}
DESCRIPTION="Crazy Eddie's GUI System"
HOMEPAGE="http://www.cegui.org.uk/"
SRC_URI="mirror://sourceforge/crayzedsgui/${MY_P}.tar.gz
	doc? ( mirror://sourceforge/crayzedsgui/${MY_D}.tar.gz )"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 -ppc ~x86"
IUSE="bidi debug devil doc examples expat gtk irrlicht lua opengl pcre static-libs tinyxml truetype xerces-c xml zip"
REQUIRED_USE="|| ( expat tinyxml xerces-c xml )" # bug 362223

RDEPEND="bidi? ( dev-libs/fribidi )
	devil? ( media-libs/devil )
	expat? ( dev-libs/expat )
	truetype? ( media-libs/freetype:2 )
	irrlicht? ( dev-games/irrlicht )
	lua? (
		dev-lang/lua
		dev-lua/toluapp
	)
	opengl? (
		virtual/opengl
		virtual/glu
		media-libs/freeglut
		media-libs/glew
	)
	pcre? ( dev-libs/libpcre )
	tinyxml? ( dev-libs/tinyxml )
	xerces-c? ( dev-libs/xerces-c )
	xml? ( dev-libs/libxml2 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( app-doc/doxygen )"

S=${WORKDIR}/${MY_P}

src_prepare() {
	# build with newer zlib (bug #389863)
	sed -i -e '74i#define OF(x) x' cegui/src/minizip/unzip.h || die
	sed -i -e '125i#define OF(x) x' cegui/src/minizip/ioapi.h || die

	if use examples ; then
		cp -r Samples Samples.clean
		rm -f $(find Samples.clean -name 'Makefile*')
	fi
}

src_configure() {
	# ogre-1.6.5 needs older cegui (bug #387103)
	econf \
		--disable-ogre-renderer \
		$(use_enable bidi bidirectional-text) \
		$(use_enable debug) \
		$(use_enable devil) \
		$(use_enable examples samples) \
		$(use_enable expat) \
		$(use_enable truetype freetype) \
		$(use_enable irrlicht irrlicht-renderer) \
		$(use_enable lua lua-module) \
		$(use_enable lua toluacegui) \
		--enable-external-toluapp \
		$(use_enable opengl opengl-renderer) \
		--enable-external-glew \
		$(use_enable pcre) \
		$(use_enable tinyxml) \
		--enable-external-tinyxml \
		$(use_enable xerces-c) \
		$(use_enable xml libxml) \
		$(use_enable zip minizip-resource-provider) \
		--enable-null-renderer \
		--enable-stb \
		--enable-tga \
		--disable-corona \
		--disable-dependency-tracking \
		--disable-freeimage \
		--disable-rapidxml \
		--disable-samples \
		--disable-silly \
		$(use_with gtk gtk2) \
		$(use_enable static-libs static) \
		--enable-shared
}

src_install() {
	emake DESTDIR="${D}" install || die

	# remove .la files
	use static-libs || rm -f "${D}"/usr/*/*.la

	if use doc ; then
		emake html || die
		dohtml -r doc/doxygen/html/* || die
	fi
	if use examples ; then
		insinto /usr/share/doc/${PF}/Samples
		doins -r Samples.clean/* || die
	fi
}