[gentoo-commits] gentoo-x86 commit in mail-filter/spamdyke: ChangeLog spamdyke-4.3.0.ebuild

[gentoo-commits] gentoo-x86 commit in mail-filter/spamdyke: ChangeLog spamdyke-4.3.0.ebuild

[Alfredo Tupone (tupone)]

tupone      12/01/17 20:46:44

  Modified:             ChangeLog
  Added:                spamdyke-4.3.0.ebuild
  Log:
  Version bump to 4.3.0. Bug #399157
  
  (Portage version: 2.1.10.44/cvs/Linux i686)

Revision  Changes    Path
1.23                 mail-filter/spamdyke/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/spamdyke/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/spamdyke/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/spamdyke/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-filter/spamdyke/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	17 Jan 2012 11:33:35 -0000	1.22
+++ ChangeLog	17 Jan 2012 20:46:44 -0000	1.23
@@ -1,6 +1,12 @@
 # ChangeLog for mail-filter/spamdyke
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/spamdyke/ChangeLog,v 1.22 2012/01/17 11:33:35 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/spamdyke/ChangeLog,v 1.23 2012/01/17 20:46:44 tupone Exp $
+
+*spamdyke-4.3.0 (17 Jan 2012)
+
+  17 Jan 2012; Tupone Alfredo <tupone@gentoo.org> +spamdyke-4.3.0.ebuild,
+  +files/spamdyke-4.3.0-gcc46.patch:
+  Version bump to 4.3.0. Bug #399157 by Agostino Sarubbo
 
   17 Jan 2012; Agostino Sarubbo <ago@gentoo.org> spamdyke-4.2.1.ebuild:
   Stable for X86, wrt security bug #397941



1.1                  mail-filter/spamdyke/spamdyke-4.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/spamdyke/spamdyke-4.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/spamdyke/spamdyke-4.3.0.ebuild?rev=1.1&content-type=text/plain

Index: spamdyke-4.3.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-filter/spamdyke/spamdyke-4.3.0.ebuild,v 1.1 2012/01/17 20:46:44 tupone Exp $

EAPI="2"
inherit eutils autotools

DESCRIPTION="A drop-in connection-time spam filter for qmail"
HOMEPAGE="http://www.spamdyke.org/"
SRC_URI="http://www.spamdyke.org/releases/${P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+tls"

DEPEND="tls? ( dev-libs/openssl )"
RDEPEND="${DEPEND}
	virtual/qmail"

S=${WORKDIR}/${P}/${PN}

src_prepare() {
	epatch "${FILESDIR}"/${P}-gcc46.patch
	echo "# Configuration option for ${PN}" > ${PN}.conf
	if use tls; then
		echo "tls-certificate-file=/var/qmail/control/clientcert.pem" \
			>> ${PN}.conf
	fi
	echo "graylist-level=always-create-dir" >> ${PN}.conf
	echo "graylist-dir=/var/tmp/${PN}/graylist" >> ${PN}.conf
	echo "reject-empty-rdns" >> ${PN}.conf
	echo "reject-unresolvable-rdns" >> ${PN}.conf
	echo "dns-blacklist-entry=zen.spamhaus.org" >> ${PN}.conf
	echo "local-domains-file=/var/qmail/control/rcpthosts" >> ${PN}.conf
	sed -i \
		-e "/STRIP_CMD/d" \
		Makefile.in || die "sed on Makefile.in failed"
	eautoreconf
}

src_configure() {
	econf \
		$(use_enable tls) || die "econf failed"
	cd ../utils
	econf || die "econf failed in utils"
}

src_compile() {
	emake CFLAGS="${CFLAGS}" || die "emake failed"
	cd ../utils
	emake CFLAGS="${CFLAGS}" || die "emake in utils died"
}

src_install() {
	dobin ${PN} || die "Installing ${PN} binary failed"
	insinto /etc/${PN}
	doins ${PN}.conf || die "Installing ${PN} configuration file failed"
	dodir /var/tmp/${PN}/graylist
	fowners -R qmaild /var/tmp/${PN}/graylist
	cd ../utils
	dobin domain2path || die "Installing domain2path binary failed"
	cd ../documentation
	dodoc {Changelog,INSTALL,UPGRADING}.txt
	dohtml FAQ.html \
		README.html \
		README_ip_file_format.html \
		README_rdns_directory_format.html \
		README_rdns_file_format.html
}

pkg_postinst() {
	elog "In /var/qmail/control/conf-smtpd insert the line:"
	elog "QMAIL_SMTP_PRE=\"${QMAIL_SMTP_PRE} spamdyke -f /etc/${PN}/${PN}.conf\""
	elog "Run spamdyke with the '-h' flag to see the available options and"
	elog "update /etc/spamdyke/spamdyke.conf accordingly"
}