* [gentoo-commits] gentoo-x86 commit in app-admin/conky: conky-1.8.1-r6.ebuild ChangeLog conky-1.8.1-r5.ebuild
@ 2012-01-16 20:04 Daniel Pielmeier (billie)
0 siblings, 0 replies; only message in thread
From: Daniel Pielmeier (billie) @ 2012-01-16 20:04 UTC (permalink / raw
To: gentoo-commits
billie 12/01/16 20:04:45
Modified: ChangeLog
Added: conky-1.8.1-r6.ebuild
Removed: conky-1.8.1-r5.ebuild
Log:
Fix bug #398823. Thanks to nvinson for the report and patch.
(Portage version: 2.1.10.41/cvs/Linux i686)
Revision Changes Path
1.170 app-admin/conky/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/conky/ChangeLog?rev=1.170&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/conky/ChangeLog?rev=1.170&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/conky/ChangeLog?r1=1.169&r2=1.170
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/conky/ChangeLog,v
retrieving revision 1.169
retrieving revision 1.170
diff -u -r1.169 -r1.170
--- ChangeLog 16 Nov 2011 19:50:34 -0000 1.169
+++ ChangeLog 16 Jan 2012 20:04:45 -0000 1.170
@@ -1,6 +1,12 @@
# ChangeLog for app-admin/conky
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/conky/ChangeLog,v 1.169 2011/11/16 19:50:34 billie Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/conky/ChangeLog,v 1.170 2012/01/16 20:04:45 billie Exp $
+
+*conky-1.8.1-r6 (16 Jan 2012)
+
+ 16 Jan 2012; Daniel Pielmeier <billie@gentoo.org> -conky-1.8.1-r5.ebuild,
+ +conky-1.8.1-r6.ebuild, +files/conky-1.8.1-battery-time.patch:
+ Fix bug #398823. Thanks to nvinson for the report and patch.
*conky-1.8.1-r5 (16 Nov 2011)
1.1 app-admin/conky/conky-1.8.1-r6.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/conky/conky-1.8.1-r6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/conky/conky-1.8.1-r6.ebuild?rev=1.1&content-type=text/plain
Index: conky-1.8.1-r6.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/conky/conky-1.8.1-r6.ebuild,v 1.1 2012/01/16 20:04:45 billie Exp $
EAPI=2
inherit autotools eutils
DESCRIPTION="An advanced, highly configurable system monitor for X"
HOMEPAGE="http://conky.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
LICENSE="GPL-3 BSD LGPL-2.1 MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="apcupsd audacious curl debug eve hddtemp imlib iostats lua lua-cairo lua-imlib math moc mpd nano-syntax ncurses nvidia +portmon rss thinkpad truetype vim-syntax weather-metar weather-xoap wifi X xmms2"
DEPEND_COMMON="
X? (
imlib? ( media-libs/imlib2 )
lua-cairo? ( >=dev-lua/toluapp-1.0.93 x11-libs/cairo[X] )
lua-imlib? ( >=dev-lua/toluapp-1.0.93 media-libs/imlib2 )
nvidia? ( media-video/nvidia-settings )
truetype? ( x11-libs/libXft >=media-libs/freetype-2 )
x11-libs/libX11
x11-libs/libXdamage
x11-libs/libXext
audacious? ( >=media-sound/audacious-1.5 dev-libs/glib )
xmms2? ( media-sound/xmms2 )
)
curl? ( net-misc/curl )
eve? ( net-misc/curl dev-libs/libxml2 )
portmon? ( dev-libs/glib )
lua? ( >=dev-lang/lua-5.1 )
ncurses? ( sys-libs/ncurses )
rss? ( dev-libs/libxml2 net-misc/curl dev-libs/glib )
wifi? ( net-wireless/wireless-tools )
weather-metar? ( net-misc/curl )
weather-xoap? ( dev-libs/libxml2 net-misc/curl )
virtual/libiconv
"
RDEPEND="
${DEPEND_COMMON}
apcupsd? ( sys-power/apcupsd )
hddtemp? ( app-admin/hddtemp )
moc? ( media-sound/moc )
nano-syntax? ( app-editors/nano )
vim-syntax? ( || ( app-editors/vim app-editors/gvim ) )
"
DEPEND="
${DEPEND_COMMON}
dev-util/pkgconfig
"
src_prepare() {
epatch "${FILESDIR}/${P}-nvidia-x.patch" \
"${FILESDIR}/${P}-xmms2.patch" \
"${FILESDIR}/${P}-secunia-SA43225.patch" \
"${FILESDIR}/${P}-acpitemp.patch" \
"${FILESDIR}/${P}-curl-headers.patch" \
"${FILESDIR}/${P}-maxinterfaces.patch" \
"${FILESDIR}/${P}-utf8-scroll.patch" \
"${FILESDIR}/${P}-battery-time.patch"
eautoreconf
}
src_configure() {
local myconf
if use X; then
myconf="--enable-x11 --enable-double-buffer --enable-xdamage"
myconf="${myconf} --enable-argb --enable-own-window"
myconf="${myconf} $(use_enable imlib imlib2) $(use_enable lua-cairo)"
myconf="${myconf} $(use_enable lua-imlib lua-imlib2)"
myconf="${myconf} $(use_enable nvidia) $(use_enable truetype xft)"
myconf="${myconf} $(use_enable audacious) $(use_enable xmms2)"
else
myconf="--disable-x11 --disable-own-window --disable-argb"
myconf="${myconf} --disable-lua-cairo --disable-nvidia --disable-xft"
myconf="${myconf} --disable-audacious --disable-xmms2"
fi
econf \
${myconf} \
$(use_enable apcupsd) \
$(use_enable curl) \
$(use_enable debug) \
$(use_enable eve) \
$(use_enable hddtemp) \
$(use_enable iostats) \
$(use_enable lua) \
$(use_enable thinkpad ibm) \
$(use_enable math) \
$(use_enable moc) \
$(use_enable mpd) \
$(use_enable ncurses) \
$(use_enable portmon) \
$(use_enable rss) \
$(use_enable weather-metar) \
$(use_enable weather-xoap) \
$(use_enable wifi wlan)
}
src_install() {
emake DESTDIR="${D}" install || die
dodoc ChangeLog AUTHORS TODO || die
dohtml doc/docs.html doc/config_settings.html doc/variables.html || die
if use vim-syntax; then
insinto /usr/share/vim/vimfiles/ftdetect
doins "${S}"/extras/vim/ftdetect/conkyrc.vim || die
insinto /usr/share/vim/vimfiles/syntax
doins "${S}"/extras/vim/syntax/conkyrc.vim || die
fi
if use nano-syntax; then
insinto /usr/share/nano/
doins "${S}"/extras/nano/conky.nanorc || die
fi
}
pkg_postinst() {
elog "You can find a sample configuration file at ${ROOT%/}/etc/conky/conky.conf."
elog "To customize, copy it to ~/.conkyrc and edit it to your liking."
elog
elog "For more info on Conky's features please look at the Changelog in"
elog "${ROOT%/}/usr/share/doc/${PF}. There are also pretty html docs available"
elog "on Conky's site or in ${ROOT%/}/usr/share/doc/${PF}/html."
elog
elog "Also see http://www.gentoo.org/doc/en/conky-howto.xml"
elog
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-01-16 20:05 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-01-16 20:04 [gentoo-commits] gentoo-x86 commit in app-admin/conky: conky-1.8.1-r6.ebuild ChangeLog conky-1.8.1-r5.ebuild Daniel Pielmeier (billie)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox