* [gentoo-commits] gentoo-x86 commit in app-admin/rsyslog: rsyslog-5.8.6.ebuild ChangeLog
@ 2011-12-28 12:00 Alexys Jacob (ultrabug)
0 siblings, 0 replies; 3+ messages in thread
From: Alexys Jacob (ultrabug) @ 2011-12-28 12:00 UTC (permalink / raw
To: gentoo-commits
ultrabug 11/12/28 12:00:25
Modified: ChangeLog
Added: rsyslog-5.8.6.ebuild
Log:
version bump.
(Portage version: 2.1.10.43/cvs/Linux x86_64)
Revision Changes Path
1.61 app-admin/rsyslog/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/ChangeLog?rev=1.61&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/ChangeLog?rev=1.61&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/ChangeLog?r1=1.60&r2=1.61
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/rsyslog/ChangeLog,v
retrieving revision 1.60
retrieving revision 1.61
diff -u -r1.60 -r1.61
--- ChangeLog 13 Sep 2011 12:14:45 -0000 1.60
+++ ChangeLog 28 Dec 2011 12:00:25 -0000 1.61
@@ -1,6 +1,11 @@
# ChangeLog for app-admin/rsyslog
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/ChangeLog,v 1.60 2011/09/13 12:14:45 ultrabug Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/ChangeLog,v 1.61 2011/12/28 12:00:25 ultrabug Exp $
+
+*rsyslog-5.8.6 (28 Dec 2011)
+
+ 28 Dec 2011; Ultrabug <ultrabug@gentoo.org> +rsyslog-5.8.6.ebuild:
+ Version bump.
13 Sep 2011; Ultrabug <ultrabug@gentoo.org> -rsyslog-5.6.5.ebuild,
-rsyslog-5.8.3.ebuild:
1.1 app-admin/rsyslog/rsyslog-5.8.6.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.6.ebuild?rev=1.1&content-type=text/plain
Index: rsyslog-5.8.6.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.6.ebuild,v 1.1 2011/12/28 12:00:25 ultrabug Exp $
EAPI=4
inherit autotools-utils systemd
DESCRIPTION="An enhanced multi-threaded syslogd with database support and more."
HOMEPAGE="http://www.rsyslog.com/"
SRC_URI="http://www.rsyslog.com/files/download/${PN}/${P}.tar.gz
zeromq? ( https://github.com/aggregateknowledge/rsyslog-zeromq/tarball/44b551abc29dd5b541884bd51b45b413855a93d8 -> ${PN}-zeromq.tar.gz )"
LICENSE="GPL-3 LGPL-3"
KEYWORDS="~amd64 ~arm ~hppa ~sparc ~x86"
SLOT="0"
IUSE="dbi debug doc extras gnutls kerberos mysql oracle postgres relp snmp static-libs zeromq zlib"
RDEPEND="dbi? ( dev-db/libdbi )
extras? ( net-libs/libnet )
gnutls? ( net-libs/gnutls )
kerberos? ( virtual/krb5 )
mysql? ( virtual/mysql )
postgres? ( dev-db/postgresql-base )
oracle? ( dev-db/oracle-instantclient-basic )
relp? ( >=dev-libs/librelp-0.1.3 )
snmp? ( net-analyzer/net-snmp )
zeromq? ( net-libs/zeromq )
zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}
dev-util/pkgconfig"
BRANCH="5-stable"
# need access to certain device nodes
RESTRICT="test"
# Maitainer note : open a bug to upstream
# showing that building in a separate dir fails
AUTOTOOLS_IN_SOURCE_BUILD=1
DOCS=(AUTHORS ChangeLog doc/rsyslog-example.conf)
src_prepare() {
# Maintainer notes:
# ZeroMQ support, for now it is done by hand until upstream process bug.
# Bugzilla : http://bugzilla.adiscon.com/show_bug.cgi?id=277
if use zeromq; then
local ZEROPATH=${WORKDIR}/aggregateknowledge-rsyslog-zeromq-44b551a
epatch ${ZEROPATH}/rsyslog-zeromq.patch
cp -r ${ZEROPATH}/{i,o}mzeromq "${S}/plugins"
fi
# Don't force '-g' CFLAG
sed -i 's/CFLAGS="\(.*\) -g"/CFLAGS="\1"/g' configure.ac || die
eautoreconf
}
src_configure() {
# Maintainer notes:
# * rfc3195 needs a library and development of that library
# is suspended, so we disable it
# * About the java GUI:
# The maintainer says there is no real installation support
# for the java GUI, so we disable it for now.
local myeconfargs=(
--disable-gui
--disable-rfc3195
--enable-largefile
--enable-unlimited-select
--enable-imdiag
--enable-imfile
--enable-impstats
--enable-imtemplate
--enable-imptcp
--enable-mail
--enable-omprog
--enable-omstdout
--enable-omtemplate
--enable-omdbalerting
--enable-omuxsock
--enable-pmlastmsg
--enable-pmrfc3164sd
--enable-pmcisconames
--enable-pmaixforwardedfrom
--enable-pmsnare
$(use_enable extras omudpspoof)
$(use_enable zlib)
$(use_enable mysql)
$(use_enable dbi libdbi)
$(use_enable postgres pgsql)
$(use_enable oracle oracle)
$(use_enable gnutls)
$(use_enable kerberos gssapi-krb5)
$(use_enable relp)
$(use_enable snmp)
$(use_enable snmp mmsnmptrapd)
$(use_enable debug)
$(use_enable debug rtinst)
$(use_enable debug diagtools)
$(use_enable debug memcheck)
$(use_enable debug valgrind)
)
use zeromq && myeconfargs=(
${myeconfargs[@]-}
$(use_enable zeromq imzeromq)
$(use_enable zeromq omzeromq)
)
systemd_to_myeconfargs
autotools-utils_src_configure
}
src_install() {
use doc && HTML_DOCS=(doc/)
autotools-utils_src_install
insinto /etc
newins "${FILESDIR}/${BRANCH}/${PN}-gentoo.conf" ${PN}.conf
newconfd "${FILESDIR}/${BRANCH}/${PN}.confd" ${PN}
newinitd "${FILESDIR}/${BRANCH}/${PN}.initd" ${PN}
keepdir /var/spool/${PN}
keepdir /etc/ssl/${PN}
keepdir /etc/${PN}.d
use static-libs || find "${D}" -name '*.la' -delete || die
if use mysql; then
insinto /usr/share/doc/${PF}/scripts/mysql
doins plugins/ommysql/{createDB.sql,contrib/delete_mysql}
fi
if use postgres; then
insinto /usr/share/doc/${PF}/scripts/pgsql
doins plugins/ompgsql/createDB.sql
fi
insinto /etc/logrotate.d/
newins "${FILESDIR}/${BRANCH}/${PN}.logrotate" ${PN}
}
pkg_postinst() {
if use mysql || use postgres; then
echo
elog "Sample SQL scripts for MySQL & PostgreSQL have been installed to:"
elog " /usr/share/doc/${PF}/scripts"
fi
if use gnutls; then
echo
elog "To create a default CA and certificates for your server and clients, run:"
elog " emerge --config =${PF}"
elog "on your logging server. You can run it several times,"
elog "once for each logging client. The client certificates will be signed"
elog "using the CA certificate generated during the first run."
fi
}
pkg_config() {
if ! use gnutls ; then
einfo "There is nothing to configure for rsyslog unless you"
einfo "used USE=gnutls to build it."
return 0
fi
# Make sure the certificates directory exists
CERTDIR="${ROOT}/etc/ssl/${PN}"
if [ ! -d "${CERTDIR}" ]; then
mkdir "${CERTDIR}" || die
fi
einfo "Your certificates will be stored in ${CERTDIR}"
# Create a default CA if needed
if [ ! -f "${CERTDIR}/${PN}_ca.cert.pem" ]; then
einfo "No CA key and certificate found in ${CERTDIR}, creating them for you..."
certtool --generate-privkey \
--outfile "${CERTDIR}/${PN}_ca.privkey.pem" &>/dev/null
chmod 400 "${CERTDIR}/${PN}_ca.privkey.pem"
cat > "${T}/${PF}.$$" <<_EOF
cn = Portage automated CA
ca
cert_signing_key
expiration_days = 3650
_EOF
certtool --generate-self-signed \
--load-privkey "${CERTDIR}/${PN}_ca.privkey.pem" \
--outfile "${CERTDIR}/${PN}_ca.cert.pem" \
--template "${T}/${PF}.$$" &>/dev/null
chmod 400 "${CERTDIR}/${PN}_ca.privkey.pem"
# Create the server certificate
echo
einfon "Please type the Common Name of the SERVER you wish to create a certificate for: "
read -r CN
einfo "Creating private key and certificate for server ${CN}..."
certtool --generate-privkey \
--outfile "${CERTDIR}/${PN}_${CN}.key.pem" &>/dev/null
chmod 400 "${CERTDIR}/${PN}_${CN}.key.pem"
cat > "${T}/${PF}.$$" <<_EOF
cn = ${CN}
tls_www_server
dns_name = ${CN}
expiration_days = 3650
_EOF
certtool --generate-certificate \
--outfile "${CERTDIR}/${PN}_${CN}.cert.pem" \
--load-privkey "${CERTDIR}/${PN}_${CN}.key.pem" \
--load-ca-certificate "${CERTDIR}/${PN}_ca.cert.pem" \
--load-ca-privkey "${CERTDIR}/${PN}_ca.privkey.pem" \
--template "${T}/${PF}.$$" &>/dev/null
chmod 400 "${CERTDIR}/${PN}_${CN}.cert.pem"
else
einfo "Found existing ${CERTDIR}/${PN}_ca.cert.pem, skipping CA and SERVER creation."
fi
# Create a client certificate
echo
einfon "Please type the Common Name of the CLIENT you wish to create a certificate for: "
read -r CN
einfo "Creating private key and certificate for client ${CN}..."
certtool --generate-privkey \
--outfile "${CERTDIR}/${PN}_${CN}.key.pem" &>/dev/null
chmod 400 "${CERTDIR}/${PN}_${CN}.key.pem"
cat > "${T}/${PF}.$$" <<_EOF
cn = ${CN}
tls_www_client
dns_name = ${CN}
expiration_days = 3650
_EOF
certtool --generate-certificate \
--outfile "${CERTDIR}/${PN}_${CN}.cert.pem" \
--load-privkey "${CERTDIR}/${PN}_${CN}.key.pem" \
--load-ca-certificate "${CERTDIR}/${PN}_ca.cert.pem" \
--load-ca-privkey "${CERTDIR}/${PN}_ca.privkey.pem" \
--template "${T}/${PF}.$$" &>/dev/null
chmod 400 "${CERTDIR}/${PN}_${CN}.cert.pem"
rm -f "${T}/${PF}.$$"
echo
einfo "Here is the documentation on how to encrypt your log traffic:"
einfo " http://www.rsyslog.com/doc/rsyslog_tls.html"
}
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-admin/rsyslog: rsyslog-5.8.6.ebuild ChangeLog
@ 2012-01-16 7:57 Tomas Chvatal (scarabeus)
0 siblings, 0 replies; 3+ messages in thread
From: Tomas Chvatal (scarabeus) @ 2012-01-16 7:57 UTC (permalink / raw
To: gentoo-commits
scarabeus 12/01/16 07:57:47
Modified: rsyslog-5.8.6.ebuild ChangeLog
Log:
Fix initscript to not use deprecated opts. Use ssl useflag not gnutls for ssl support as ssl should enable the ssl support and gnutls/openssl respective features if multiple backends are available.
(Portage version: 2.2.0_alpha84/cvs/Linux x86_64)
Revision Changes Path
1.2 app-admin/rsyslog/rsyslog-5.8.6.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.6.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.6.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.6.ebuild?r1=1.1&r2=1.2
Index: rsyslog-5.8.6.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.6.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- rsyslog-5.8.6.ebuild 28 Dec 2011 12:00:25 -0000 1.1
+++ rsyslog-5.8.6.ebuild 16 Jan 2012 07:57:47 -0000 1.2
@@ -1,6 +1,6 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.6.ebuild,v 1.1 2011/12/28 12:00:25 ultrabug Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.6.ebuild,v 1.2 2012/01/16 07:57:47 scarabeus Exp $
EAPI=4
@@ -14,17 +14,17 @@
LICENSE="GPL-3 LGPL-3"
KEYWORDS="~amd64 ~arm ~hppa ~sparc ~x86"
SLOT="0"
-IUSE="dbi debug doc extras gnutls kerberos mysql oracle postgres relp snmp static-libs zeromq zlib"
+IUSE="dbi debug doc extras kerberos mysql oracle postgres relp snmp ssl static-libs zeromq zlib"
RDEPEND="dbi? ( dev-db/libdbi )
extras? ( net-libs/libnet )
- gnutls? ( net-libs/gnutls )
kerberos? ( virtual/krb5 )
mysql? ( virtual/mysql )
postgres? ( dev-db/postgresql-base )
oracle? ( dev-db/oracle-instantclient-basic )
relp? ( >=dev-libs/librelp-0.1.3 )
snmp? ( net-analyzer/net-snmp )
+ ssl? ( net-libs/gnutls )
zeromq? ( net-libs/zeromq )
zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}
@@ -90,7 +90,7 @@
$(use_enable dbi libdbi)
$(use_enable postgres pgsql)
$(use_enable oracle oracle)
- $(use_enable gnutls)
+ $(use_enable ssl gnutls)
$(use_enable kerberos gssapi-krb5)
$(use_enable relp)
$(use_enable snmp)
@@ -158,9 +158,9 @@
}
pkg_config() {
- if ! use gnutls ; then
+ if ! use ssl ; then
einfo "There is nothing to configure for rsyslog unless you"
- einfo "used USE=gnutls to build it."
+ einfo "used USE=ssl to build it."
return 0
fi
1.62 app-admin/rsyslog/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/ChangeLog?rev=1.62&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/ChangeLog?rev=1.62&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/ChangeLog?r1=1.61&r2=1.62
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/rsyslog/ChangeLog,v
retrieving revision 1.61
retrieving revision 1.62
diff -u -r1.61 -r1.62
--- ChangeLog 28 Dec 2011 12:00:25 -0000 1.61
+++ ChangeLog 16 Jan 2012 07:57:47 -0000 1.62
@@ -1,6 +1,12 @@
# ChangeLog for app-admin/rsyslog
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/ChangeLog,v 1.61 2011/12/28 12:00:25 ultrabug Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/ChangeLog,v 1.62 2012/01/16 07:57:47 scarabeus Exp $
+
+ 16 Jan 2012; Tomáš Chvátal <scarabeus@gentoo.org>
+ files/5-stable/rsyslog.initd, rsyslog-5.8.6.ebuild:
+ Fix initscript to not use deprecated opts. Use ssl useflag not gnutls for ssl
+ support as ssl should enable the ssl support and gnutls/openssl respective
+ features if multiple backends are available.
*rsyslog-5.8.6 (28 Dec 2011)
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-admin/rsyslog: rsyslog-5.8.6.ebuild ChangeLog
@ 2012-01-24 20:32 Justin Lecher (jlec)
0 siblings, 0 replies; 3+ messages in thread
From: Justin Lecher (jlec) @ 2012-01-24 20:32 UTC (permalink / raw
To: gentoo-commits
jlec 12/01/24 20:32:58
Modified: rsyslog-5.8.6.ebuild ChangeLog
Log:
exchange last gnutls to ssl
(Portage version: 2.2.0_alpha84/cvs/Linux x86_64)
Revision Changes Path
1.3 app-admin/rsyslog/rsyslog-5.8.6.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.6.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.6.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.6.ebuild?r1=1.2&r2=1.3
Index: rsyslog-5.8.6.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.6.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- rsyslog-5.8.6.ebuild 16 Jan 2012 07:57:47 -0000 1.2
+++ rsyslog-5.8.6.ebuild 24 Jan 2012 20:32:58 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.6.ebuild,v 1.2 2012/01/16 07:57:47 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.6.ebuild,v 1.3 2012/01/24 20:32:58 jlec Exp $
EAPI=4
@@ -147,7 +147,7 @@
elog " /usr/share/doc/${PF}/scripts"
fi
- if use gnutls; then
+ if use ssl; then
echo
elog "To create a default CA and certificates for your server and clients, run:"
elog " emerge --config =${PF}"
1.63 app-admin/rsyslog/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/ChangeLog?rev=1.63&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/ChangeLog?rev=1.63&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/rsyslog/ChangeLog?r1=1.62&r2=1.63
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/rsyslog/ChangeLog,v
retrieving revision 1.62
retrieving revision 1.63
diff -u -r1.62 -r1.63
--- ChangeLog 16 Jan 2012 07:57:47 -0000 1.62
+++ ChangeLog 24 Jan 2012 20:32:58 -0000 1.63
@@ -1,6 +1,9 @@
# ChangeLog for app-admin/rsyslog
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/ChangeLog,v 1.62 2012/01/16 07:57:47 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/ChangeLog,v 1.63 2012/01/24 20:32:58 jlec Exp $
+
+ 24 Jan 2012; Justin Lecher <jlec@gentoo.org> rsyslog-5.8.6.ebuild:
+ exchange last gnutls to ssl
16 Jan 2012; Tomáš Chvátal <scarabeus@gentoo.org>
files/5-stable/rsyslog.initd, rsyslog-5.8.6.ebuild:
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2012-01-24 20:33 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-01-16 7:57 [gentoo-commits] gentoo-x86 commit in app-admin/rsyslog: rsyslog-5.8.6.ebuild ChangeLog Tomas Chvatal (scarabeus)
-- strict thread matches above, loose matches on Subject: below --
2012-01-24 20:32 Justin Lecher (jlec)
2011-12-28 12:00 Alexys Jacob (ultrabug)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox