* [gentoo-commits] gentoo-x86 commit in media-sound/rhythmbox: rhythmbox-2.95.ebuild ChangeLog rhythmbox-2.90.1_pre20111001.ebuild
@ 2012-01-16 3:47 Nirbheek Chauhan (nirbheek)
0 siblings, 0 replies; only message in thread
From: Nirbheek Chauhan (nirbheek) @ 2012-01-16 3:47 UTC (permalink / raw
To: gentoo-commits
nirbheek 12/01/16 03:47:24
Modified: ChangeLog
Added: rhythmbox-2.95.ebuild
Removed: rhythmbox-2.90.1_pre20111001.ebuild
Log:
Bump to 2.95 + patches, remove old, drop ~ppc64 due to unsatisfied deps
(Portage version: 2.2.0_alpha84/cvs/Linux x86_64)
Revision Changes Path
1.210 media-sound/rhythmbox/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/rhythmbox/ChangeLog?rev=1.210&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/rhythmbox/ChangeLog?rev=1.210&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/rhythmbox/ChangeLog?r1=1.209&r2=1.210
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/rhythmbox/ChangeLog,v
retrieving revision 1.209
retrieving revision 1.210
diff -u -r1.209 -r1.210
--- ChangeLog 5 Jan 2012 06:38:12 -0000 1.209
+++ ChangeLog 16 Jan 2012 03:47:24 -0000 1.210
@@ -1,6 +1,15 @@
# ChangeLog for media-sound/rhythmbox
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/rhythmbox/ChangeLog,v 1.209 2012/01/05 06:38:12 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/rhythmbox/ChangeLog,v 1.210 2012/01/16 03:47:24 nirbheek Exp $
+
+*rhythmbox-2.95 (16 Jan 2012)
+
+ 16 Jan 2012; Nirbheek Chauhan <nirbheek@gentoo.org>
+ +files/rhythmbox-2.95-fix-db-dbus-interface.patch,
+ +files/rhythmbox-2.95-port-im-status-plugin.patch,
+ +files/rhythmbox-2.95-port-rb-set-rating-py-example.patch,
+ +rhythmbox-2.95.ebuild, -rhythmbox-2.90.1_pre20111001.ebuild:
+ Bump to 2.95 + patches, remove old, drop ~ppc64 due to unsatisfied deps
05 Jan 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
rhythmbox-0.12.8-r1.ebuild, rhythmbox-0.13.3.ebuild,
1.1 media-sound/rhythmbox/rhythmbox-2.95.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/rhythmbox/rhythmbox-2.95.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/rhythmbox/rhythmbox-2.95.ebuild?rev=1.1&content-type=text/plain
Index: rhythmbox-2.95.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/rhythmbox/rhythmbox-2.95.ebuild,v 1.1 2012/01/16 03:47:24 nirbheek Exp $
EAPI="4"
GNOME2_LA_PUNT="yes"
PYTHON_DEPEND="python? 2:2.5"
PYTHON_USE_WITH="xml"
PYTHON_USE_WITH_OPT="python"
inherit eutils gnome2 python multilib virtualx
DESCRIPTION="Music management and playback software for GNOME"
HOMEPAGE="http://www.rhythmbox.org/"
LICENSE="GPL-2"
SLOT="0"
IUSE="cdr clutter daap dbus doc gnome-keyring html ipod +lastfm libnotify lirc
musicbrainz mtp nsplugin +python test +udev upnp webkit"
# vala
KEYWORDS="~amd64 ~x86"
REQUIRED_USE="
ipod? ( udev )
mtp? ( udev )
dbus? ( python )
gnome-keyring? ( python )
webkit? ( python )"
# FIXME: double check what to do with fm-radio plugin
# FIXME: Zeitgeist python plugin
# NOTE: gst-python is still needed because gstreamer introspection is incomplete
COMMON_DEPEND=">=dev-libs/glib-2.26.0:2
dev-libs/libxml2:2
>=x11-libs/gtk+-2.91.4:3[introspection]
>=x11-libs/gdk-pixbuf-2.18.0:2
>=dev-libs/gobject-introspection-0.10.0
>=dev-libs/libpeas-0.7.3[gtk,python?]
>=dev-libs/totem-pl-parser-2.32.1
>=net-libs/libsoup-2.26:2.4
>=net-libs/libsoup-gnome-2.26:2.4
>=media-libs/gst-plugins-base-0.10.32:0.10
>=media-libs/gstreamer-0.10.32:0.10[introspection]
>=sys-libs/tdb-1.2.6
clutter? (
>=media-libs/clutter-1.2:1.0
>=media-libs/clutter-gst-1.0:1.0
>=media-libs/clutter-gtk-1.0:1.0
>=x11-libs/mx-1.0.1:1.0 )
cdr? ( >=app-cdr/brasero-2.91.90 )
daap? (
>=net-libs/libdmapsharing-2.9.11:3.0
>=net-dns/avahi-0.6 )
gnome-keyring? ( >=gnome-base/gnome-keyring-0.4.9 )
html? ( >=net-libs/webkit-gtk-1.3.9:3 )
lastfm? ( dev-libs/json-glib )
libnotify? ( >=x11-libs/libnotify-0.7.0 )
lirc? ( app-misc/lirc )
musicbrainz? (
media-libs/musicbrainz:3
gnome-base/gconf:2 )
python? ( dev-python/pygobject:3 )
udev? (
ipod? ( >=media-libs/libgpod-0.7.92[udev] )
mtp? ( >=media-libs/libmtp-0.3 )
|| ( >=sys-fs/udev-171[gudev] >=sys-fs/udev-145[extras] ) )
"
RDEPEND="${COMMON_DEPEND}
>=media-plugins/gst-plugins-soup-0.10
>=media-plugins/gst-plugins-libmms-0.10
|| (
>=media-plugins/gst-plugins-cdparanoia-0.10
>=media-plugins/gst-plugins-cdio-0.10 )
>=media-plugins/gst-plugins-meta-0.10-r2:0.10
>=media-plugins/gst-plugins-taglib-0.10.6
upnp? (
>=media-libs/grilo-0.1.17
>=media-plugins/grilo-plugins-0.1.17[upnp] )
python? (
>=dev-python/gst-python-0.10.8
x11-libs/gdk-pixbuf:2[introspection]
x11-libs/gtk+:3[introspection]
x11-libs/pango[introspection]
dbus? ( sys-apps/dbus )
gnome-keyring? ( dev-python/gnome-keyring-python )
webkit? (
dev-python/mako
>=net-libs/webkit-gtk-1.3.9:3[introspection] ) )
"
# gtk-doc-am needed for eautoreconf
# dev-util/gtk-doc-am
DEPEND="${COMMON_DEPEND}
dev-util/pkgconfig
>=dev-util/intltool-0.35
app-text/scrollkeeper
>=app-text/gnome-doc-utils-0.9.1
doc? ( >=dev-util/gtk-doc-1.4 )
test? ( dev-libs/check )"
# vala? ( >=dev-lang/vala-0.9.4:0.12 )
DOCS="AUTHORS ChangeLog DOCUMENTERS INTERNALS \
MAINTAINERS MAINTAINERS.old NEWS README THANKS"
pkg_setup() {
if use python; then
python_set_active_version 2
python_pkg_setup
G2CONF="${G2CONF} PYTHON=$(PYTHON -2)"
fi
# --enable-vala just installs the sample vala plugin, and the configure
# checks are broken, so don't enable it
G2CONF="${G2CONF}
MOZILLA_PLUGINDIR=/usr/$(get_libdir)/nsbrowser/plugins
VALAC=$(type -P valac-0.14)
--enable-mmkeys
--disable-more-warnings
--disable-scrollkeeper
--disable-schemas-compile
--disable-static
--disable-vala
--without-hal
$(use_enable clutter visualizer)
$(use_enable daap)
$(use_enable lastfm)
$(use_enable libnotify)
$(use_enable lirc)
$(use_enable musicbrainz)
$(use_enable nsplugin browser-plugin)
$(use_enable python)
$(use_enable upnp grilo)
$(use_with cdr brasero)
$(use_with daap mdns avahi)
$(use_with gnome-keyring)
$(use_with html webkit)
$(use_with ipod)
$(use_with mtp)
$(use_with udev gudev)"
export GST_INSPECT=/bin/true
}
src_prepare() {
gnome2_src_prepare
# Not needed for next release
# https://bugzilla.gnome.org/show_bug.cgi?id=667980
epatch "${FILESDIR}/${P}-port-im-status-plugin.patch"
epatch "${FILESDIR}/${P}-port-rb-set-rating-py-example.patch"
epatch "${FILESDIR}/${P}-fix-db-dbus-interface.patch"
# Disable pyc compiling
echo > py-compile
}
src_test() {
unset SESSION_MANAGER
unset DBUS_SESSION_BUS_ADDRESS
Xemake check || die "test failed"
}
pkg_postinst() {
gnome2_pkg_postinst
if use python; then
python_need_rebuild
python_mod_optimize /usr/$(get_libdir)/rhythmbox/plugins
fi
ewarn
ewarn "If ${PN} doesn't play some music format, please check your"
ewarn "USE flags on media-plugins/gst-plugins-meta"
ewarn
}
pkg_postrm() {
gnome2_pkg_postrm
python_mod_cleanup /usr/$(get_libdir)/rhythmbox/plugins
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-01-16 3:47 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-01-16 3:47 [gentoo-commits] gentoo-x86 commit in media-sound/rhythmbox: rhythmbox-2.95.ebuild ChangeLog rhythmbox-2.90.1_pre20111001.ebuild Nirbheek Chauhan (nirbheek)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox