[gentoo-commits] gentoo-x86 commit in net-misc/freerdp: freerdp-1.0_beta5.ebuild ChangeLog freerdp-1.0_beta2.ebuild freerdp-1.0_beta3.ebuild freerdp-1.0_beta1.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/freerdp: freerdp-1.0_beta5.ebuild ChangeLog freerdp-1.0_beta2.ebuild freerdp-1.0_beta3.ebuild freerdp-1.0_beta1.ebuild

[Mike Gilbert (floppym)]

floppym     12/01/07 20:45:32

  Modified:             ChangeLog
  Added:                freerdp-1.0_beta5.ebuild
  Removed:              freerdp-1.0_beta2.ebuild freerdp-1.0_beta3.ebuild
                        freerdp-1.0_beta1.ebuild
  Log:
  Version bump. Remove old betas.
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.20                 net-misc/freerdp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/freerdp/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/freerdp/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/freerdp/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/freerdp/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	24 Dec 2011 01:06:35 -0000	1.19
+++ ChangeLog	7 Jan 2012 20:45:32 -0000	1.20
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/freerdp
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/ChangeLog,v 1.19 2011/12/24 01:06:35 floppym Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/ChangeLog,v 1.20 2012/01/07 20:45:32 floppym Exp $
+
+*freerdp-1.0_beta5 (07 Jan 2012)
+
+  07 Jan 2012; Mike Gilbert <floppym@gentoo.org> +freerdp-1.0_beta5.ebuild,
+  -freerdp-1.0_beta1.ebuild, -freerdp-1.0_beta2.ebuild,
+  -freerdp-1.0_beta3.ebuild:
+  Version bump. Remove old betas.
 
 *freerdp-1.0_beta4 (24 Dec 2011)
 



1.1                  net-misc/freerdp/freerdp-1.0_beta5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/freerdp/freerdp-1.0_beta5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/freerdp/freerdp-1.0_beta5.ebuild?rev=1.1&content-type=text/plain

Index: freerdp-1.0_beta5.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/freerdp-1.0_beta5.ebuild,v 1.1 2012/01/07 20:45:32 floppym Exp $

EAPI="4"

inherit cmake-utils

DESCRIPTION="Client-side implementation of the Remote Desktop Protocol"
HOMEPAGE="http://www.freerdp.com/"
SRC_URI="https://github.com/downloads/FreeRDP/FreeRDP/FreeRDP-${PV/_/-}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa cups directfb doc ffmpeg pulseaudio smartcard sse2 test X xinerama xv"

FREERDP_DEBUG="transport chanman svc dvc kbd nla nego certificate license gdi
	rfx x11 rail xv scard orders redir"
IUSE+=" $(printf 'debug-%s ' ${FREERDP_DEBUG})"

RDEPEND="
	dev-libs/openssl
	sys-libs/zlib
	alsa? ( media-libs/alsa-lib )
	cups? ( net-print/cups )
	directfb? ( dev-libs/DirectFB )
	ffmpeg? ( virtual/ffmpeg )
	pulseaudio? ( media-sound/pulseaudio )
	smartcard? ( sys-apps/pcsc-lite )
	X? (
		x11-libs/libX11
		x11-libs/libXcursor
		x11-libs/libXext
		x11-libs/libxkbfile
		xinerama? ( x11-libs/libXinerama )
		xv? ( x11-libs/libXv )
	)
"
DEPEND="${RDEPEND}
	doc? (
		X? (
			app-text/docbook-xml-dtd:4.1.2
			app-text/xmlto
		)
	)
	test? ( dev-util/cunit )
"

DOCS=( README )

# Test suite segfaults
RESTRICT="test"

src_unpack() {
	unpack ${A}
	mv FreeRDP-* "${S}" || die
}

CMAKE_VERBOSE=1

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_with alsa ALSA)
		$(cmake-utils_use_with cups CUPS)
		$(cmake-utils_use_with doc MANPAGES)
		$(cmake-utils_use_with directfb DIRECTFB)
		$(cmake-utils_use_with ffmpeg FFMPEG)
		$(cmake-utils_use_with pulseaudio PULSEAUDIO)
		$(cmake-utils_use_with smartcard PCSC)
		$(cmake-utils_use_with sse2 SSE2)
		$(cmake-utils_use_with test CUNIT)
		$(cmake-utils_use_with X X11)
		$(cmake-utils_use_with X XCURSOR)
		$(cmake-utils_use_with X XEXT)
		$(cmake-utils_use_with X XKBFILE)
		$(cmake-utils_use_with xinerama XINERAMA)
		$(cmake-utils_use_with xv XV)
	)
	for i in ${FREERDP_DEBUG}; do
		mycmakeargs+=(
			$(cmake-utils_use_with debug-${i} DEBUG_$(LC_ALL=C echo ${i} | tr a-z A-Z))
		)
	done
	cmake-utils_src_configure
}