* [gentoo-commits] gentoo-x86 commit in sys-apps/file: ChangeLog file-5.10.ebuild
@ 2011-12-31 6:00 Mike Frysinger (vapier)
0 siblings, 0 replies; only message in thread
From: Mike Frysinger (vapier) @ 2011-12-31 6:00 UTC (permalink / raw
To: gentoo-commits
vapier 11/12/31 06:00:52
Modified: ChangeLog
Added: file-5.10.ebuild
Log:
Version bump.
(Portage version: 2.2.0_alpha81/cvs/Linux x86_64)
Revision Changes Path
1.214 sys-apps/file/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/ChangeLog?rev=1.214&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/ChangeLog?rev=1.214&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/ChangeLog?r1=1.213&r2=1.214
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/file/ChangeLog,v
retrieving revision 1.213
retrieving revision 1.214
diff -u -r1.213 -r1.214
--- ChangeLog 12 Dec 2011 22:41:16 -0000 1.213
+++ ChangeLog 31 Dec 2011 06:00:52 -0000 1.214
@@ -1,6 +1,11 @@
# ChangeLog for sys-apps/file
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/file/ChangeLog,v 1.213 2011/12/12 22:41:16 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/file/ChangeLog,v 1.214 2011/12/31 06:00:52 vapier Exp $
+
+*file-5.10 (31 Dec 2011)
+
+ 31 Dec 2011; Mike Frysinger <vapier@gentoo.org> +file-5.10.ebuild:
+ Version bump.
12 Dec 2011; Agostino Sarubbo <ago@gentoo.org> file-5.09.ebuild:
Stable for AMD64, wrt bug #393291
1.1 sys-apps/file/file-5.10.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/file-5.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/file-5.10.ebuild?rev=1.1&content-type=text/plain
Index: file-5.10.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/file/file-5.10.ebuild,v 1.1 2011/12/31 06:00:52 vapier Exp $
EAPI="2"
PYTHON_DEPEND="python? *"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="*-jython"
inherit eutils distutils libtool flag-o-matic
DESCRIPTION="identify a file's format by scanning binary data for patterns"
HOMEPAGE="ftp://ftp.astron.com/pub/file/"
SRC_URI="ftp://ftp.astron.com/pub/file/${P}.tar.gz
ftp://ftp.gw.com/mirrors/pub/unix/file/${P}.tar.gz"
LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="python static-libs zlib"
RDEPEND="zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}"
PYTHON_MODNAME="magic.py"
src_prepare() {
elibtoolize
# dont let python README kill main README #60043
mv python/README{,.python}
}
wd() { echo ${WORKDIR}/build-${CHOST}; }
do_configure() {
ECONF_SOURCE=${S}
mkdir "$(wd)"
pushd "$(wd)" >/dev/null
econf "$@"
popd >/dev/null
}
src_configure() {
# file uses things like strndup() and wcwidth()
append-flags -D_GNU_SOURCE
# when cross-compiling, we need to build up our own file
# because people often don't keep matching host/target
# file versions #362941
if tc-is-cross-compiler && ! ROOT=/ has_version ~${CATEGORY}/${P} ; then
ac_cv_header_zlib_h=no \
ac_cv_lib_z_gzopen=no \
CHOST=${CBUILD} \
CFLAGS=${BUILD_CFLAGS} \
CXXFLAGS=${BUILD_CXXFLAGS} \
CPPFLAGS=${BUILD_CPPFLAGS} \
LDFLAGS="${BUILD_LDFLAGS} -static" \
do_configure --disable-shared
fi
export ac_cv_header_zlib_h=$(usex zlib) ac_cv_lib_z_gzopen=$(usex zlib)
do_configure $(use_enable static-libs static)
}
do_make() {
emake -C "$(wd)" "$@" || die
}
src_compile() {
if tc-is-cross-compiler && ! ROOT=/ has_version ~${CATEGORY}/${P} ; then
CHOST=${CBUILD} do_make -C src file
PATH=$(CHOST=${CBUILD} wd)/src:${PATH}
fi
do_make
use python && cd python && distutils_src_compile
}
src_install() {
do_make DESTDIR="${D}" install || die
dodoc ChangeLog MAINT README
use python && cd python && distutils_src_install
use static-libs || rm -f "${D}"/usr/lib*/libmagic.la
}
pkg_postinst() {
use python && distutils_pkg_postinst
}
pkg_postrm() {
use python && distutils_pkg_postrm
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-12-31 6:01 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-12-31 6:00 [gentoo-commits] gentoo-x86 commit in sys-apps/file: ChangeLog file-5.10.ebuild Mike Frysinger (vapier)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox