[gentoo-commits] gentoo-x86 commit in dev-lang/spidermonkey: spidermonkey-1.8.2.15-r1.ebuild ChangeLog

["Ian Stakenvicius (axs)" <axs@gentoo.org>]

axs         11/12/29 17:49:12

  Modified:             ChangeLog
  Added:                spidermonkey-1.8.2.15-r1.ebuild
  Log:
  Added js shell to spidermonkey-1.8.2.15, as per user request in bug 377291
  
  (Portage version: 2.1.10.41/cvs/Linux i686)

Revision  Changes    Path
1.68                 dev-lang/spidermonkey/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/spidermonkey/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/spidermonkey/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/spidermonkey/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/spidermonkey/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	26 Nov 2011 04:49:25 -0000	1.67
+++ ChangeLog	29 Dec 2011 17:49:12 -0000	1.68
@@ -1,6 +1,12 @@
 # ChangeLog for dev-lang/spidermonkey
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/spidermonkey/ChangeLog,v 1.67 2011/11/26 04:49:25 dirtyepic Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/spidermonkey/ChangeLog,v 1.68 2011/12/29 17:49:12 axs Exp $
+
+*spidermonkey-1.8.2.15-r1 (29 Dec 2011)
+
+  29 Dec 2011; Ian Stakenvicius <axs@gentoo.org>
+  +spidermonkey-1.8.2.15-r1.ebuild:
+  Added js shell to spidermonkey-1.8.2.15, as per user request in bug 377291
 
   26 Nov 2011; Ryan Hill <dirtyepic@gentoo.org> spidermonkey-1.8.5-r1.ebuild:
   Fix typo (committed as obvious).



1.1                  dev-lang/spidermonkey/spidermonkey-1.8.2.15-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/spidermonkey/spidermonkey-1.8.2.15-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/spidermonkey/spidermonkey-1.8.2.15-r1.ebuild?rev=1.1&content-type=text/plain

Index: spidermonkey-1.8.2.15-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/spidermonkey/spidermonkey-1.8.2.15-r1.ebuild,v 1.1 2011/12/29 17:49:12 axs Exp $

EAPI="3"
inherit eutils toolchain-funcs multilib python

MY_PV="${PV}"
MY_PV="${MY_PV/1.8.2/3.6}"
DESCRIPTION="Stand-alone JavaScript C library"
HOMEPAGE="http://www.mozilla.org/js/spidermonkey/"
REL_URI="http://releases.mozilla.org/pub/mozilla.org/firefox/releases"
SRC_URI="${REL_URI}/${MY_PV}/source/firefox-${MY_PV}.source.tar.bz2"

LICENSE="NPL-1.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x64-macos ~x86-macos"
IUSE="threadsafe"

S="${WORKDIR}/mozilla-1.9.2"
BUILDDIR="${S}/js/src"

RDEPEND="threadsafe? ( >=dev-libs/nspr-4.8.6 )"

DEPEND="${RDEPEND}
	app-arch/zip
	=dev-lang/python-2*[threads]
	dev-util/pkgconfig"

pkg_setup(){
	python_set_active_version 2
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-1.9.2.13-as-needed.patch"

	epatch_user

	cd "${S}"
	if [[ ${CHOST} == *-freebsd* ]]; then
		# Don't try to be smart, this does not work in cross-compile anyway
		ln -s "${BUILDDIR}/config/Linux_All.mk" "${S}/config/$(uname -s)$(uname -r).mk"
	fi
}

src_configure() {
	cd ${BUILDDIR}

	local myconf

	if use threadsafe ; then
		myconf="${myconf} --with-system-nspr \
			--enable-threadsafe"
	fi
	# Disable no-print-directory
	MAKEOPTS=${MAKEOPTS/--no-print-directory/}

	CC="$(tc-getCC)" CXX="$(tc-getCXX)" LD="$(tc-getLD)" PYTHON="$(PYTHON)" econf \
		${myconf}
}

src_compile() {
	cd ${BUILDDIR}
	emake -j1 || die "emake failed";
}

src_install() {
	cd ${BUILDDIR}
	emake install DESTDIR="${D}" || die
	dobin shell/js ||die
	dodoc ../jsd/README
	dohtml README.html

	if [[ ${CHOST} == *-darwin* ]] ; then
		# fixup install_name
		install_name_tool -id "${EPREFIX}"/usr/$(get_libdir)/libmozjs.dylib \
			"${ED}"/usr/$(get_libdir)/libmozjs.dylib || die
	fi
}