[gentoo-commits] gentoo-x86 commit in dev-util/cmt: ChangeLog cmt-1.23.ebuild cmt-1.20.20090520.ebuild

[gentoo-commits] gentoo-x86 commit in dev-util/cmt: ChangeLog cmt-1.23.ebuild cmt-1.20.20090520.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    11/12/29 09:04:19

  Modified:             ChangeLog
  Added:                cmt-1.23.ebuild
  Removed:              cmt-1.20.20090520.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.41/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 dev-util/cmt/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/cmt/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/cmt/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/cmt/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/cmt/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	23 Mar 2011 19:11:02 -0000	1.9
+++ ChangeLog	29 Dec 2011 09:04:19 -0000	1.10
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/cmt
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/cmt/ChangeLog,v 1.9 2011/03/23 19:11:02 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/cmt/ChangeLog,v 1.10 2011/12/29 09:04:19 bicatali Exp $
+
+*cmt-1.23 (29 Dec 2011)
+
+  29 Dec 2011; Sébastien Fabbro <bicatali@gentoo.org>
+  -cmt-1.20.20090520.ebuild, +cmt-1.23.ebuild:
+  Version bump
 
 *cmt-1.22 (23 Mar 2011)
 



1.1                  dev-util/cmt/cmt-1.23.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/cmt/cmt-1.23.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/cmt/cmt-1.23.ebuild?rev=1.1&content-type=text/plain

Index: cmt-1.23.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/cmt/cmt-1.23.ebuild,v 1.1 2011/12/29 09:04:19 bicatali Exp $

EAPI=4
inherit eutils elisp-common toolchain-funcs versionator

CPV=($(get_version_components ${PV}))
CMT_PV=v${CPV[0]}r${CPV[1]}

DESCRIPTION="Cross platform configuration management environment"
HOMEPAGE="http://www.cmtsite.org/"
SRC_URI="http://www.cmtsite.org/${CMT_PV}/CMT${CMT_PV}.tar.gz"

LICENSE="CeCILL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="emacs java doc"

DEPEND="emacs? ( virtual/emacs )"
RDEPEND="${DEPEND}
	java? ( virtual/jdk )"

S="${WORKDIR}/CMT/${CMT_PV}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.22-limits.patch
}

src_configure() {
	cd "${S}"/mgr
	./INSTALL
	source setup.sh
}

src_compile() {
	cd "${S}"/mgr
	emake -j1 \
		cpp="$(tc-getCXX)" \
		cppflags="${CXXFLAGS}" \
		cpplink="$(tc-getCXX) ${LDFLAGS}"

	sed -i -e "s:${WORKDIR}:${EPREFIX}/usr/$(get_libdir):g" setup.*sh || die
	cd "${S}"
	mv src/demo .
	rm -f ${CMTBIN}/*.o

	if use emacs; then
		elisp-compile doc/cmt-mode.el || die
	fi
}

src_install() {
	CMTDIR="${EPREFIX}"/usr/$(get_libdir)/CMT/${CMT_PV}
	dodir ${CMTDIR}
	cp -pPR mgr src ${CMTBIN} "${ED}"/${CMTDIR} || die
	dodir /usr/bin
	dosym ${CMTDIR}/${CMTBIN}/cmt.exe /usr/bin/cmt

	cat > 99cmt <<-EOF
		 CMTROOT="${CMTDIR}"
		 CMTBIN="$(uname)-$(uname -m | sed -e 's# ##g')"
		 CMTCONFIG="$(${CMTROOT}/mgr/cmt_system.sh)"
	EOF
	if use java; then
		cp -pPR java "${ED}"/${CMTDIR}
		echo "#!${EPREFIX}/bin/sh" > jcmt
		echo "java cmt_parser" >> jcmt
		exeinto /usr/bin
		doexe jcmt
		echo "CLASSPATH=\"${CMTDIR}/java/cmt.jar\"" >> 99cmt
	fi

	doenvd 99cmt
	dodoc ChangeLog doc/*.txt
	dohtml doc/{ChangeLog,ReleaseNotes}.html

	if use doc; then
		emake -C mgr gendoc
		insinto /usr/share/doc/${PF}
		doins -r doc/{CMTDoc,CMTFAQ}.{html,pdf} doc/Images
		doins -r demo
	fi

	if use emacs; then
		elisp-install ${PN} doc/cmt-mode.{el,elc} || die
		elisp-site-file-install "${FILESDIR}"/80cmt-mode-gentoo.el || die
	fi
}

pkg_postinst () {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}