[gentoo-commits] gentoo-x86 commit in x11-misc/xlockmore: ChangeLog xlockmore-5.37.ebuild

["Tim Harder (radhermit)" <radhermit@gentoo.org>]

radhermit    11/12/23 02:42:09

  Modified:             ChangeLog
  Added:                xlockmore-5.37.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha81/cvs/Linux x86_64)

Revision  Changes    Path
1.97                 x11-misc/xlockmore/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xlockmore/ChangeLog?rev=1.97&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xlockmore/ChangeLog?rev=1.97&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xlockmore/ChangeLog?r1=1.96&r2=1.97

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/xlockmore/ChangeLog,v
retrieving revision 1.96
retrieving revision 1.97
diff -u -r1.96 -r1.97
--- ChangeLog	16 Dec 2011 05:22:09 -0000	1.96
+++ ChangeLog	23 Dec 2011 02:42:08 -0000	1.97
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/xlockmore
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/xlockmore/ChangeLog,v 1.96 2011/12/16 05:22:09 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xlockmore/ChangeLog,v 1.97 2011/12/23 02:42:08 radhermit Exp $
+
+*xlockmore-5.37 (23 Dec 2011)
+
+  23 Dec 2011; Tim Harder <radhermit@gentoo.org> +xlockmore-5.37.ebuild:
+  Version bump.
 
 *xlockmore-5.36 (16 Dec 2011)
 



1.1                  x11-misc/xlockmore/xlockmore-5.37.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xlockmore/xlockmore-5.37.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xlockmore/xlockmore-5.37.ebuild?rev=1.1&content-type=text/plain

Index: xlockmore-5.37.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/xlockmore/xlockmore-5.37.ebuild,v 1.1 2011/12/23 02:42:08 radhermit Exp $

EAPI=4
inherit autotools eutils flag-o-matic pam

DESCRIPTION="Just another screensaver application for X"
HOMEPAGE="http://www.tux.org/~bagleyd/xlockmore.html"
SRC_URI="http://ftp.tux.org/pub/tux/bagleyd/${PN}/${P}/${P}.tar.bz2"

LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
IUSE="crypt debug esd gtk imagemagick motif nas opengl pam truetype xinerama xlockrc"

RDEPEND="x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXmu
	x11-libs/libXpm
	x11-libs/libXt
	esd? ( media-sound/esound )
	gtk? ( x11-libs/gtk+:2 )
	imagemagick? ( media-gfx/imagemagick )
	motif? ( >=x11-libs/openmotif-2.3:0 )
	nas? ( media-libs/nas )
	opengl? (
		media-libs/mesa
		truetype? ( >=media-libs/ftgl-2.1.3_rc5 )
		)
	pam? ( virtual/pam )
	truetype? ( media-libs/freetype:2 )
	xinerama? ( x11-libs/libXinerama )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	x11-proto/xineramaproto"

MAKEOPTS="${MAKEOPTS} -j1"

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-5.31-configure.in.patch \
		"${FILESDIR}"/${PN}-5.31-ldflags.patch

	eautoreconf
}

src_configure() {
	local myconf=""

	if use opengl && use truetype; then
			myconf="${myconf} --with-ftgl"
			append-flags -DFTGL213
		else
			myconf="${myconf} --without-ftgl"
	fi

	econf \
		--enable-vtlock \
		--enable-syslog \
		$(use_enable xlockrc) \
		$(use_enable pam) \
		--disable-use-mb \
		--enable-appdefaultdir=/usr/share/X11/app-defaults \
		$(use_with motif) \
		$(use_with imagemagick magick) \
		$(use_with debug editres) \
		$(use_with truetype ttf) \
		$(use_with truetype freetype) \
		$(use_with opengl) \
		$(use_with opengl mesa) \
		$(use_with xinerama) \
		$(use_with esd esound) \
		$(use_with nas) \
		$(use_with crypt) \
		$(use_with gtk gtk2) \
		--without-gtk \
		${myconf}
}

src_install() {
	einstall xapploaddir="${D}/usr/share/X11/app-defaults" \
		mandir="${D}/usr/share/man/man1" INSTPGMFLAGS=""

	pamd_mimic_system xlock auth

	if use pam; then
		fperms 755 /usr/bin/xlock
	else
		fperms 4755 /usr/bin/xlock
	fi

	dohtml docs/xlock.html
	dodoc README docs/{3d.howto,cell_automata,HACKERS.GUIDE,Purify,Revisions,TODO}
}