[gentoo-commits] gentoo-x86 commit in dev-ruby/test-unit: ChangeLog test-unit-2.4.3.ebuild

[gentoo-commits] gentoo-x86 commit in dev-ruby/test-unit: ChangeLog test-unit-2.4.3.ebuild

[Hans de Graaff (graaff)]

graaff      11/12/13 06:52:11

  Modified:             ChangeLog
  Added:                test-unit-2.4.3.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.1.10.11/cvs/Linux x86_64)

Revision  Changes    Path
1.48                 dev-ruby/test-unit/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/test-unit/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/test-unit/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/test-unit/ChangeLog?r1=1.47&r2=1.48

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ruby/test-unit/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -u -r1.47 -r1.48
--- ChangeLog	13 Dec 2011 06:41:39 -0000	1.47
+++ ChangeLog	13 Dec 2011 06:52:11 -0000	1.48
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/test-unit
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/test-unit/ChangeLog,v 1.47 2011/12/13 06:41:39 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/test-unit/ChangeLog,v 1.48 2011/12/13 06:52:11 graaff Exp $
+
+*test-unit-2.4.3 (13 Dec 2011)
+
+  13 Dec 2011; Hans de Graaff <graaff@gentoo.org> +test-unit-2.4.3.ebuild:
+  Version bump.
 
   13 Dec 2011; Hans de Graaff <graaff@gentoo.org> -test-unit-2.2.0.ebuild,
   -test-unit-2.3.0.ebuild:



1.1                  dev-ruby/test-unit/test-unit-2.4.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/test-unit/test-unit-2.4.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/test-unit/test-unit-2.4.3.ebuild?rev=1.1&content-type=text/plain

Index: test-unit-2.4.3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/test-unit/test-unit-2.4.3.ebuild,v 1.1 2011/12/13 06:52:11 graaff Exp $

EAPI=2
USE_RUBY="ruby18 ruby19 ree18 jruby"

RUBY_FAKEGEM_TASK_DOC=""
RUBY_FAKEGEM_DOCDIR="doc"
RUBY_FAKEGEM_EXTRADOC="TODO README.textile"

# Disable default binwraps
RUBY_FAKEGEM_BINWRAP=""

inherit ruby-fakegem

ruby_add_bdepend "doc? ( dev-ruby/yard )"
# redcloth is also needed to build documentation, but not available for
# jruby. Since we build documentation with the main ruby implementation
# only we skip the dependency for jruby in this roundabout way, assuming
# that jruby won't be the main ruby.
USE_RUBY=ruby18 ruby_add_bdepend "ruby_targets_ruby18 doc" "( dev-ruby/redcloth )"
USE_RUBY=ruby19 ruby_add_bdepend "ruby_targets_ruby19 doc" "( dev-ruby/redcloth )"
USE_RUBY=ree18 ruby_add_bdepend "ruby_targets_ree18 doc" "( dev-ruby/redcloth )"

DESCRIPTION="An improved version of the Test::Unit framework from Ruby 1.8"
HOMEPAGE="http://test-unit.rubyforge.org/"

LICENSE="Ruby"
SLOT="2"
KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
IUSE=""

all_ruby_compile() {
	all_fakegem_compile

	if use doc; then
		yard doc --title ${PN} || die
	fi
}

each_ruby_test() {
	# the rake audit using dev-ruby/zentest currently fails, and we
	# just need to call the testsuite directly.
	# rake audit || die "rake audit failed"
	local rubyflags

	[[ $(basename ${RUBY}) == jruby ]] && rubyflags="-X+O"

	${RUBY} ${rubyflags} test/run-test.rb || die "testsuite failed"
}

all_ruby_install() {
	all_fakegem_install

	# Create a testrb2 wrapper similarly to the rdoc2 wrapper for
	# rdoc-2* series.
	ruby_fakegem_binwrapper testrb /usr/bin/testrb-2
}