[gentoo-commits] gentoo-x86 commit in net-mail/notmuch: notmuch-0.10.2.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-mail/notmuch: notmuch-0.10.2.ebuild ChangeLog

[Amadeusz Zolnowski (aidecoe)]

aidecoe     11/12/11 20:51:27

  Modified:             ChangeLog
  Added:                notmuch-0.10.2.ebuild
  Log:
  net-mail/notmuch: Version bump to 0.10.2.
  
  (Portage version: 2.1.10.39/cvs/Linux x86_64)

Revision  Changes    Path
1.19                 net-mail/notmuch/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-mail/notmuch/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	2 Dec 2011 08:40:56 -0000	1.18
+++ ChangeLog	11 Dec 2011 20:51:27 -0000	1.19
@@ -1,6 +1,19 @@
 # ChangeLog for net-mail/notmuch
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-mail/notmuch/ChangeLog,v 1.18 2011/12/02 08:40:56 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-mail/notmuch/ChangeLog,v 1.19 2011/12/11 20:51:27 aidecoe Exp $
+
+*notmuch-0.10.2 (11 Dec 2011)
+
+  11 Dec 2011; Amadeusz Żołnowski <aidecoe@gentoo.org>
+  +files/0.10.2-fix-test-build.patch, +notmuch-0.10.2.ebuild:
+  Version bump.
+
+  NEWS
+  ~~~~
+  Fix crash in python bindings.
+
+  The python bindings did not call g_type_init, which caused crashes for some,
+  but not all users.
 
   02 Dec 2011; Amadeusz Żołnowski <aidecoe@gentoo.org>
   -files/0.10-fix-test-build.patch, -notmuch-0.10.ebuild:



1.1                  net-mail/notmuch/notmuch-0.10.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/notmuch-0.10.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/notmuch-0.10.2.ebuild?rev=1.1&content-type=text/plain

Index: notmuch-0.10.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-mail/notmuch/notmuch-0.10.2.ebuild,v 1.1 2011/12/11 20:51:26 aidecoe Exp $

EAPI=4

PYTHON_DEPEND="python? 2:2.6"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="2.[45] 3.*"
RUBY="/usr/bin/ruby18"
RDOC="/usr/bin/rdoc18"

inherit elisp-common distutils
inherit autotools-utils

DESCRIPTION="The mail indexer"
HOMEPAGE="http://notmuchmail.org/"
SRC_URI="${HOMEPAGE}/releases/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
REQUIRED_USE="test? ( crypt emacs )"
IUSE="bash-completion crypt debug doc emacs python ruby test vim zsh-completion"

CDEPEND="
	>=dev-libs/glib-2.14
	dev-libs/gmime:2.4
	dev-libs/xapian
	doc? ( python? ( dev-python/sphinx ) )
	sys-libs/talloc
	debug? ( dev-util/valgrind )
	emacs? ( >=virtual/emacs-23 )
	ruby? ( dev-lang/ruby:1.8 )
	x86? ( >=dev-libs/xapian-1.2.7-r2 )
	vim? ( || ( >=app-editors/vim-7.0 >=app-editors/gvim-7.0 ) )
	"
DEPEND="${CDEPEND}
	dev-util/pkgconfig
	test? ( app-misc/dtach sys-devel/gdb )
	"
RDEPEND="${CDEPEND}
	crypt? ( app-crypt/gnupg )
	zsh-completion? ( app-shells/zsh )
	"

PATCHES=( "${FILESDIR}/${PV}-fix-test-build.patch" )
DOCS=( AUTHORS NEWS README TODO )
SITEFILE="50${PN}-gentoo.el"

bindings() {
	if use $1; then
		pushd bindings/$1 || die
		shift
		$@
		popd || die
	fi
}

pkg_setup() {
	if use emacs; then
		elisp-need-emacs 23 || die "Emacs version too low"
	fi
	use python && python_pkg_setup
}

src_prepare() {
	autotools-utils_src_prepare
	bindings python distutils_src_prepare

	r_fix() {
		local pattern="\(find_library('notmuch', '[^']*', '\)\([^']*\)\(')\)"
		local replace="\1${WORKDIR}/${PF}_build/lib\3"

		sed -i "s|$pattern|$replace|" extconf.rb || die
	}
	bindings ruby r_fix
}

src_configure() {
	local myeconfargs=(
		--bashcompletiondir="${ROOT}/usr/share/bash-completion"
		--emacslispdir="${ROOT}/${SITELISP}/${PN}"
		--emacsetcdir="${ROOT}/${SITEETC}/${PN}"
		--zshcompletiondir="${ROOT}/usr/share/zsh/site-functions"
		$(use_with bash-completion)
		$(use_with emacs)
		$(use_with zsh-completion)
	)
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile
	bindings python distutils_src_compile

	r_make() {
		${RUBY} extconf.rb || die
		emake
	}
	bindings ruby r_make

	if use doc; then
		pydocs() {
			pushd docs || die
			emake html
			mv html ../python || die
			popd || die
		}

		rdocs() {
			${RDOC} --main 'Notmuch' --title 'Notmuch Ruby API' --op ruby *.c
		}

		LD_LIBRARY_PATH="${WORKDIR}/${PF}_build/lib" bindings python pydocs
		bindings ruby rdocs
	fi
}

src_install() {
	autotools-utils_src_install

	if use emacs; then
		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
	fi

	if use vim; then
		insinto /usr/share/vim/vimfiles
		doins -r vim/plugin vim/syntax
	fi

	DOCS="" bindings python distutils_src_install
	bindings ruby emake DESTDIR="'${D}'" install

	if use doc; then
		bindings python dohtml -r python
		bindings ruby dohtml -r ruby
	fi
}

pkg_postinst() {
	use emacs && elisp-site-regen
	use python && distutils_pkg_postinst

	if use python; then
		echo
		elog "Python API documentation is also available online at:"
		elog "  http://packages.python.org/notmuch/"
	fi
}

pkg_postrm() {
	use emacs && elisp-site-regen
	use python && distutils_pkg_postrm
}