[gentoo-commits] gentoo-x86 commit in app-misc/recoll: recoll-1.16.1.ebuild ChangeLog recoll-1.16.0.ebuild

[gentoo-commits] gentoo-x86 commit in app-misc/recoll: recoll-1.16.1.ebuild ChangeLog recoll-1.16.0.ebuild

[Markos Chandras (hwoarang)]

hwoarang    11/12/10 10:21:51

  Modified:             ChangeLog
  Added:                recoll-1.16.1.ebuild
  Removed:              recoll-1.16.0.ebuild
  Log:
  Version bump. Raise libwpd dependency to slot 0.9 per bug #393249
  
  (Portage version: 2.2.0_alpha71/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  app-misc/recoll/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/recoll/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/recoll/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/recoll/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/recoll/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	14 Nov 2011 21:18:47 -0000	1.2
+++ ChangeLog	10 Dec 2011 10:21:51 -0000	1.3
@@ -1,6 +1,12 @@
 # ChangeLog for app-misc/recoll
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/recoll/ChangeLog,v 1.2 2011/11/14 21:18:47 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/recoll/ChangeLog,v 1.3 2011/12/10 10:21:51 hwoarang Exp $
+
+*recoll-1.16.1 (10 Dec 2011)
+
+  10 Dec 2011; Markos Chandras <hwoarang@gentoo.org> +recoll-1.16.1.ebuild,
+  -recoll-1.16.0.ebuild:
+  Version bump. Raise libwpd dependency to slot 0.9 per bug #393249
 
   14 Nov 2011; Markos Chandras <hwoarang@gentoo.org> metadata.xml,
   recoll-1.16.0.ebuild:



1.1                  app-misc/recoll/recoll-1.16.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/recoll/recoll-1.16.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/recoll/recoll-1.16.1.ebuild?rev=1.1&content-type=text/plain

Index: recoll-1.16.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/recoll/recoll-1.16.1.ebuild,v 1.1 2011/12/10 10:21:51 hwoarang Exp $

EAPI="4"

inherit toolchain-funcs qt4-r2 linux-info

DESCRIPTION="A personal full text search package"
HOMEPAGE="http://www.lesbonscomptes.com/recoll/"
SRC_URI="http://www.lesbonscomptes.com/recoll/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

INDEX_HELPERS="audio chm djvu dvi exif ps ics info lyx msdoc msppt msxls pdf rtf tex wordperfect xml"
IUSE="+spell +inotify +qt4 +session camelcase xattr fam ${INDEX_HELPERS}"

DEPEND="
	virtual/libiconv
	>=dev-libs/xapian-1.0.12
	sys-libs/zlib
	spell? ( app-text/aspell )
	!inotify? ( fam? ( virtual/fam ) )
	qt4? ( x11-libs/qt-core:4[qt3support] )
	session? (
		inotify? ( x11-libs/libX11 x11-libs/libSM x11-libs/libICE )
		!inotify? ( fam? ( x11-libs/libX11 x11-libs/libSM x11-libs/libICE ) )
	)
"

RDEPEND="
	${DEPEND}
	app-arch/unzip
	sys-apps/sed
	|| ( sys-apps/gawk sys-apps/mawk )
	pdf? ( app-text/poppler )
	ps? ( app-text/pstotext )
	msdoc? ( app-text/antiword )
	msxls? ( app-text/catdoc )
	msppt? ( app-text/catdoc )
	wordperfect? ( app-text/libwpd:0.9 )
	rtf? ( app-text/unrtf )
	tex? ( dev-tex/detex )
	dvi? ( virtual/tex-base )
	djvu? ( >=app-text/djvu-3.5.15 )
	exif? ( media-libs/exiftool )
	chm? ( dev-python/pychm )
	ics? ( dev-python/icalendar )
	lyx? ( app-office/lyx )
	audio? ( media-libs/mutagen )
	xml? ( dev-libs/libxslt )
	info? ( sys-apps/texinfo )
	"

REQUIRED_USE="^^ ( fam inotify ( !fam !inotify ) ) session? ( || ( fam inotify ) )"

pkg_pretend() {
	if use inotify; then
		CONFIG_CHECK="~INOTIFY_USER"
		check_extra_config
	fi
}

pkg_setup() {
	local i at_least_one_helper

	at_least_one_helper=0
	for i in $INDEX_HELPERS; do
		if use $i; then
			at_least_one_helper=1
			break
		fi
	done
	if [[ $at_least_one_helper -eq 0 ]]; then
		ewarn
		ewarn "You did not enable any of the optional file format flags."
		ewarn "Recoll can read some file formats natively, but many of them"
		ewarn "are optional since they require external helpers."
		ewarn
	fi
}

src_prepare() {
	# remember configure.ac is b0rked. Fix it before using eautoreconf in the
	# future
	# eautoreconf

	# do not strip binaries
	sed -i -e "/STRIP/d" "${S}"/${PN}install.in \
		|| die "Failed to fix the installation script"
}

src_configure() {
	local qtconf

	use qt4 && qtconf="QMAKEPATH=/usr/bin/qmake"

	econf \
		$(use_with spell aspell) \
		$(use_enable xattr) \
		$(use_with inotify) \
		$(use_enable qt4 qtgui) \
		$(use_enable camelcase) \
		$(use_with fam) \
		$(use_with inotify) \
		$(use_enable session x11mon) \
		${qtconf}
}

src_compile() {
	# Do not let upstream people decide on our behalf
	emake \
		CC=$(tc-getCC) \
		CXX=$(tc-getCXX) \
		CFLAGS="${CFLAGS} ${LDFLAGS}" \
		CXXFLAGS="${CXXFLAGS} ${LDFLAGS}"
}

src_install() {
	# You probably wonder why I did not fix recollinstall in src_prepare.
	# --prefix requires an absolute path but recollinstall requires prefix
	# to be actually 'usr' because double // makes portage sad. And no, I am not
	# gonna ask upstream to fix the build system
	sed -i -e "/PREFIX/s:/usr:usr:" "${S}"/${PN}install || die
	sed -i -e "/prefix/s:/usr:usr:" "${S}"/Makefile || die

	emake DESTDIR="${D%/}" install
	dodoc ChangeLog README
	mv "${D}/usr/share/${PN}/doc" "${D}/usr/share/doc/${PF}/html"
	dosym /usr/share/doc/${PF}/html /usr/share/${PN}/doc
}

pkg_postinst() {
	elog
	elog "Default configuration files located at"
	elog "/usr/share/${PN}/examples. Either edit these files to match"
	elog "your needs or copy them to ~/.recoll/ and edit these files"
	elog "instead."
	elog
	if use xattr; then
		elog "Use flag \"xattr\" enables support for fetching field values"
		elog "from extended file attributes. You will also need to set up a"
		elog "map from the attributes names to the Recoll field names"
		elog "(see comment at the end of the fields configuration file."
	fi
}