* [gentoo-commits] gentoo-x86 commit in sys-power/upower: ChangeLog upower-0.9.15.ebuild
@ 2011-12-05 17:14 Samuli Suominen (ssuominen)
0 siblings, 0 replies; only message in thread
From: Samuli Suominen (ssuominen) @ 2011-12-05 17:14 UTC (permalink / raw
To: gentoo-commits
ssuominen 11/12/05 17:14:48
Modified: ChangeLog
Added: upower-0.9.15.ebuild
Log:
Version bump.
(Portage version: 2.2.0_alpha79/cvs/Linux x86_64)
Revision Changes Path
1.67 sys-power/upower/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower/ChangeLog?rev=1.67&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower/ChangeLog?rev=1.67&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower/ChangeLog?r1=1.66&r2=1.67
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-power/upower/ChangeLog,v
retrieving revision 1.66
retrieving revision 1.67
diff -u -r1.66 -r1.67
--- ChangeLog 23 Oct 2011 15:13:15 -0000 1.66
+++ ChangeLog 5 Dec 2011 17:14:48 -0000 1.67
@@ -1,6 +1,11 @@
# ChangeLog for sys-power/upower
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/upower/ChangeLog,v 1.66 2011/10/23 15:13:15 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-power/upower/ChangeLog,v 1.67 2011/12/05 17:14:48 ssuominen Exp $
+
+*upower-0.9.15 (05 Dec 2011)
+
+ 05 Dec 2011; Samuli Suominen <ssuominen@gentoo.org> +upower-0.9.15.ebuild:
+ Version bump.
23 Oct 2011; Raúl Porcel <armin76@gentoo.org> upower-0.9.13-r1.ebuild:
alpha/ia64/sparc stable wrt #385233
1.1 sys-power/upower/upower-0.9.15.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower/upower-0.9.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower/upower-0.9.15.ebuild?rev=1.1&content-type=text/plain
Index: upower-0.9.15.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-power/upower/upower-0.9.15.ebuild,v 1.1 2011/12/05 17:14:48 ssuominen Exp $
EAPI=4
# PYTHON_DEPEND="test? 3"
# inherit python
DESCRIPTION="D-Bus abstraction for enumerating power devices and querying history and statistics"
HOMEPAGE="http://upower.freedesktop.org/"
SRC_URI="http://upower.freedesktop.org/releases/${P}.tar.xz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="debug doc +introspection ios kernel_FreeBSD kernel_linux" # test
COMMON_DEPEND=">=dev-libs/dbus-glib-0.90
>=dev-libs/glib-2.21.5:2
sys-apps/dbus
>=sys-auth/polkit-0.101-r1
introspection? ( dev-libs/gobject-introspection )
kernel_linux? (
|| ( >=sys-fs/udev-171-r1[gudev] <sys-fs/udev-171-r1[extras] )
virtual/libusb:1
ios? ( >=app-pda/libimobiledevice-0.9.7
>=app-pda/libplist-0.12 ) )"
RDEPEND="${COMMON_DEPEND}
kernel_linux? ( >=sys-power/pm-utils-1.4.1 )"
DEPEND="${COMMON_DEPEND}
dev-libs/libxslt
app-text/docbook-xsl-stylesheets
>=dev-util/intltool-0.40.0
dev-util/pkgconfig
doc? ( dev-util/gtk-doc
app-text/docbook-xml-dtd:4.1.2 )"
DOCS=( AUTHORS HACKING NEWS README )
src_prepare() {
sed -i -e '/DISABLE_DEPRECATED/d' configure || die
}
src_configure() {
local backend
if use kernel_linux; then
backend=linux
elif use kernel_FreeBSD; then
backend=freebsd
else
backend=dummy
fi
econf \
--localstatedir="${EPREFIX}"/var \
$(use_enable introspection) \
--disable-static \
$(use_enable debug verbose-mode) \
--enable-man-pages \
$(use_enable doc gtk-doc) \
--disable-tests \
--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html \
--with-backend=${backend} \
$(use_with ios idevice)
}
src_install() {
default
keepdir /var/lib/upower #383091
find "${ED}" -name '*.la' -exec rm -f {} +
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-12-05 17:15 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-12-05 17:14 [gentoo-commits] gentoo-x86 commit in sys-power/upower: ChangeLog upower-0.9.15.ebuild Samuli Suominen (ssuominen)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox