[gentoo-commits] gentoo-x86 commit in dev-libs/seed: seed-3.2.0-r1.ebuild ChangeLog seed-3.2.0.ebuild

[gentoo-commits] gentoo-x86 commit in dev-libs/seed: seed-3.2.0-r1.ebuild ChangeLog seed-3.2.0.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    11/12/04 05:11:51

  Modified:             ChangeLog
  Added:                seed-3.2.0-r1.ebuild
  Removed:              seed-3.2.0.ebuild
  Log:
  Fix docs directory (bug #392445, thanks to Chris Mayo <aklhfex@gmail.com> for reporting).
  
  (Portage version: 2.2.0_alpha79/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  dev-libs/seed/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/seed/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/seed/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/seed/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/seed/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	24 Nov 2011 19:49:46 -0000	1.5
+++ ChangeLog	4 Dec 2011 05:11:51 -0000	1.6
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/seed
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/seed/ChangeLog,v 1.5 2011/11/24 19:49:46 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/seed/ChangeLog,v 1.6 2011/12/04 05:11:51 tetromino Exp $
+
+*seed-3.2.0-r1 (04 Dec 2011)
+
+  04 Dec 2011; Alexandre Rostovtsev <tetromino@gentoo.org> -seed-3.2.0.ebuild,
+  +seed-3.2.0-r1.ebuild:
+  Fix docs directory (bug #392445, thanks to Chris Mayo <aklhfex@gmail.com> for
+  reporting).
 
   24 Nov 2011; Alexandre Rostovtsev <tetromino@gentoo.org>
   -files/seed-2.31.5-cleanup-autotools.patch, -seed-3.0.0.ebuild:



1.1                  dev-libs/seed/seed-3.2.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/seed/seed-3.2.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/seed/seed-3.2.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: seed-3.2.0-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/seed/seed-3.2.0-r1.ebuild,v 1.1 2011/12/04 05:11:51 tetromino Exp $

EAPI="4"
WANT_AUTOMAKE="1.11"
GNOME2_LA_PUNT="yes"

inherit autotools eutils gnome2 virtualx

DESCRIPTION="Javascript bindings for Webkit-GTK and GNOME libraries"
HOMEPAGE="http://live.gnome.org/Seed"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc profile test"

RDEPEND="
	>=dev-libs/gobject-introspection-1

	dev-libs/glib:2
	virtual/libffi
	x11-libs/cairo
	x11-libs/gtk+:3[introspection]
	net-libs/webkit-gtk:3
	gnome-base/gnome-js-common
	dev-db/sqlite:3
	dev-libs/dbus-glib
	dev-libs/mpfr
	dev-libs/libxml2:2
	sys-apps/dbus
	sys-libs/readline"
DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.35
	doc? ( >=dev-util/gtk-doc-0.9 )
	profile? ( sys-devel/gcc )"

DOCS="AUTHORS ChangeLog NEWS README"

# Lots of tests fail: https://bugzilla.gnome.org/show_bug.cgi?id=660644
RESTRICT="test"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-static
		--with-webkit=3.0
		--enable-readline-module
		--enable-os-module
		--enable-ffi-module
		--enable-gtkbuilder-module
		--enable-cairo-module
		--enable-gettext-module
		--enable-dbus-module
		--enable-mpfr-module
		--enable-sqlite-module
		--enable-libxml-module
		--docdir=${EPREFIX}/usr/share/doc/${PF}/html"

	# configure behaves very strangely and enables profiling if we pass either
	# --disable-profile or --enable-profile
	if use profile; then
		G2CONF="${G2CONF}
			--enable-profile
			--enable-profile-modules"
		if ! use debug; then
			elog "USE=profile needs debug, auto-enabling..."
			G2CONF="${G2CONF} --enable-debug"
		fi
	fi

	if use profile && has ccache ${FEATURES}; then
		ewarn "USE=profile behaves very badly with ccache; it tries to create"
		ewarn "profiling data in CCACHE_DIR. Please disable one of them!"
	fi
}

src_prepare() {
	# Upstream patch to fix linking with libgio; will be in next release
	epatch "${FILESDIR}/${P}-gio-libs.patch"
	eautoreconf

	gnome2_src_prepare
}

src_test() {
	Xemake check
}

src_install() {
	gnome2_src_install
	# Don't install two copies of standard doc files
	rm "${ED}/usr/share/doc/${PF}/html/"{AUTHORS,ChangeLog,COPYING,INSTALL,README} || die
}