* [gentoo-commits] gentoo-x86 commit in games-strategy/freeciv: ChangeLog freeciv-2.3.1.ebuild freeciv-2.2.7.ebuild freeciv-2.2.5.ebuild
@ 2011-11-30 7:59 Michael Sterrett (mr_bones_)
0 siblings, 0 replies; only message in thread
From: Michael Sterrett (mr_bones_) @ 2011-11-30 7:59 UTC (permalink / raw
To: gentoo-commits
mr_bones_ 11/11/30 07:59:38
Modified: ChangeLog
Added: freeciv-2.3.1.ebuild
Removed: freeciv-2.2.7.ebuild freeciv-2.2.5.ebuild
Log:
version bump
(Portage version: 2.1.10.11/cvs/Linux i686)
Revision Changes Path
1.131 games-strategy/freeciv/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/freeciv/ChangeLog?rev=1.131&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/freeciv/ChangeLog?rev=1.131&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/freeciv/ChangeLog?r1=1.130&r2=1.131
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/freeciv/ChangeLog,v
retrieving revision 1.130
retrieving revision 1.131
diff -u -r1.130 -r1.131
--- ChangeLog 8 Oct 2011 16:32:57 -0000 1.130
+++ ChangeLog 30 Nov 2011 07:59:37 -0000 1.131
@@ -1,6 +1,14 @@
# ChangeLog for games-strategy/freeciv
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/freeciv/ChangeLog,v 1.130 2011/10/08 16:32:57 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/freeciv/ChangeLog,v 1.131 2011/11/30 07:59:37 mr_bones_ Exp $
+
+*freeciv-2.3.1 (30 Nov 2011)
+
+ 30 Nov 2011; Michael Sterrett <mr_bones_@gentoo.org> -freeciv-2.2.5.ebuild,
+ -files/freeciv-2.2.5-clean-man.patch, -freeciv-2.2.7.ebuild,
+ -files/freeciv-2.2.7-clean-man.patch, +freeciv-2.3.1.ebuild,
+ +files/freeciv-2.3.1-clean-man.patch:
+ version bump
08 Oct 2011; Pawel Hajdan jr <phajdan.jr@gentoo.org> freeciv-2.3.0.ebuild:
x86 stable wrt bug #385899
1.1 games-strategy/freeciv/freeciv-2.3.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/freeciv/freeciv-2.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/freeciv/freeciv-2.3.1.ebuild?rev=1.1&content-type=text/plain
Index: freeciv-2.3.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/freeciv/freeciv-2.3.1.ebuild,v 1.1 2011/11/30 07:59:37 mr_bones_ Exp $
EAPI=2
inherit eutils gnome2-utils games-ggz games
DESCRIPTION="multiplayer strategy game (Civilization Clone)"
HOMEPAGE="http://www.freeciv.org/"
SRC_URI="mirror://sourceforge/freeciv/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="auth dedicated ggz gtk ipv6 nls readline sdl +sound"
RDEPEND="readline? ( sys-libs/readline )
sys-libs/zlib
app-arch/bzip2
auth? ( virtual/mysql )
!dedicated? (
nls? ( virtual/libintl )
gtk? ( x11-libs/gtk+:2 )
sdl? (
media-libs/libsdl[video]
media-libs/sdl-image[png]
media-libs/freetype
)
!gtk? ( !sdl? ( x11-libs/gtk+:2 ) )
sound? (
media-libs/libsdl[audio]
media-libs/sdl-mixer
)
ggz? ( games-board/ggz-gtk-client )
media-libs/libpng
)"
DEPEND="${RDEPEND}
dev-util/pkgconfig
!dedicated? (
nls? ( sys-devel/gettext )
x11-proto/xextproto
)"
src_prepare() {
# install the .desktop in /usr/share/applications
# install the icons in /usr/share/pixmaps
sed -i \
-e 's:^.*\(desktopfiledir = \).*:\1/usr/share/applications:' \
-e 's:^\(icon[0-9]*dir = \)$(prefix)\(.*\):\1/usr\2:' \
-e 's:^\(icon[0-9]*dir = \)$(datadir)\(.*\):\1/usr/share\2:' \
client/Makefile.in \
server/Makefile.in \
modinst/Makefile.in \
data/Makefile.in \
data/icons/Makefile.in \
|| die "sed failed"
# remove civclient manpage if dedicated server
if use dedicated ; then
epatch "${FILESDIR}"/${P}-clean-man.patch
fi
}
src_configure() {
local myclient myopts
if use dedicated ; then
myclient="no"
else
use sdl && myclient="${myclient} sdl"
use gtk && myclient="${myclient} gtk"
[[ -z ${myclient} ]] && myclient="gtk" # default to gtk if none specified
myopts=$(use_with ggz ggz-client)
fi
egamesconf \
--disable-dependency-tracking \
--localedir=/usr/share/locale \
--with-ggzconfig=/usr/bin \
--enable-noregistry="${GGZ_MODDIR}" \
$(use_enable auth) \
$(use_enable ipv6) \
$(use_enable nls) \
$(use_with readline) \
$(use_enable sound sdl-mixer) \
${myopts} \
--enable-client="${myclient}"
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
if ! use dedicated ; then
# Create and install the html manual. It can't be done for dedicated
# servers, because the 'civmanual' tool is then not built. Also
# delete civmanual from the GAMES_BINDIR, because it's then useless.
# Note: to have it localized, it should be ran from _postinst, or
# something like that, but then it's a PITA to avoid orphan files...
./manual/freeciv-manual || die "freeciv-manual failed"
dohtml manual*.html || die "dohtml failed"
rm -f "${D}/${GAMES_BINDIR}"/civmanual
use sdl && make_desktop_entry freeciv-sdl "Freeciv (SDL)" freeciv-client
fi
dodoc ChangeLog NEWS doc/{BUGS,CodingStyle,HACKING,HOWTOPLAY,README*,TODO}
rm -rf "${D}$(games_get_libdir)"
prepgamesdirs
}
pkg_preinst() {
games_pkg_preinst
gnome2_icon_savelist
}
pkg_postinst() {
games_pkg_postinst
games-ggz_update_modules
gnome2_icon_cache_update
}
pkg_postrm() {
games-ggz_update_modules
gnome2_icon_cache_update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-11-30 7:59 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-11-30 7:59 [gentoo-commits] gentoo-x86 commit in games-strategy/freeciv: ChangeLog freeciv-2.3.1.ebuild freeciv-2.2.7.ebuild freeciv-2.2.5.ebuild Michael Sterrett (mr_bones_)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox