[gentoo-commits] gentoo-x86 commit in www-apps/viewvc: ChangeLog viewvc-1.1.12-r1.ebuild viewvc-1.1.12.ebuild

[gentoo-commits] gentoo-x86 commit in www-apps/viewvc: ChangeLog viewvc-1.1.12-r1.ebuild viewvc-1.1.12.ebuild

[Jeremy Olexa (darkside)]

darkside    11/11/29 13:18:09

  Modified:             ChangeLog
  Added:                viewvc-1.1.12-r1.ebuild
  Removed:              viewvc-1.1.12.ebuild
  Log:
  Fix pygments and mime-type issue, bug 382959 by Alon Bar-Lev
  
  (Portage version: 2.1.10.34/cvs/Linux x86_64)

Revision  Changes    Path
1.82                 www-apps/viewvc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/viewvc/ChangeLog?rev=1.82&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/viewvc/ChangeLog?rev=1.82&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/viewvc/ChangeLog?r1=1.81&r2=1.82

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/viewvc/ChangeLog,v
retrieving revision 1.81
retrieving revision 1.82
diff -u -r1.81 -r1.82
--- ChangeLog	28 Nov 2011 21:40:04 -0000	1.81
+++ ChangeLog	29 Nov 2011 13:18:09 -0000	1.82
@@ -1,6 +1,12 @@
 # ChangeLog for www-apps/viewvc
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/viewvc/ChangeLog,v 1.81 2011/11/28 21:40:04 darkside Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/viewvc/ChangeLog,v 1.82 2011/11/29 13:18:09 darkside Exp $
+
+*viewvc-1.1.12-r1 (29 Nov 2011)
+
+  29 Nov 2011; Jeremy Olexa <darkside@gentoo.org> -viewvc-1.1.12.ebuild,
+  +viewvc-1.1.12-r1.ebuild:
+  Fix pygments and mime-type issue, bug 382959 by Alon Bar-Lev
 
 *viewvc-1.1.12 (28 Nov 2011)
 



1.1                  www-apps/viewvc/viewvc-1.1.12-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/viewvc/viewvc-1.1.12-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/viewvc/viewvc-1.1.12-r1.ebuild?rev=1.1&content-type=text/plain

Index: viewvc-1.1.12-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/viewvc/viewvc-1.1.12-r1.ebuild,v 1.1 2011/11/29 13:18:09 darkside Exp $

EAPI="3"
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.* *-jython"

inherit confutils eutils python webapp

WEBAPP_MANUAL_SLOT="yes"

DESCRIPTION="ViewVC, a web interface to CVS and Subversion"
HOMEPAGE="http://viewvc.org/"
DOWNLOAD_NUMBER="49132"
SRC_URI="http://viewvc.tigris.org/files/documents/3330/${DOWNLOAD_NUMBER}/${P}.tar.gz"

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="cvs cvsgraph mod_python mod_wsgi mysql pygments +subversion"

DEPEND=""
RDEPEND="
	cvs? ( dev-vcs/rcs )
	subversion? ( >=dev-vcs/subversion-1.3.1[python] )

	mod_python? ( www-apache/mod_python )
	mod_wsgi? ( www-apache/mod_wsgi )
	!mod_python? ( !mod_wsgi? ( virtual/httpd-cgi ) )

	cvsgraph? ( >=dev-vcs/cvsgraph-1.5.0 )
	mysql? ( >=dev-python/mysql-python-0.9.0 )
	pygments? (
		dev-python/pygments
		app-misc/mime-types
	)
"

pkg_setup() {
	python_pkg_setup
	webapp_pkg_setup

	confutils_require_any cvs subversion
}

src_prepare() {
	find bin/ -type f -print0 | xargs -0 sed -i \
		-e "s|\(^LIBRARY_DIR\)\(.*\$\)|\1 = \"$(python_get_sitedir -f)/${PN}\"|g" \
		-e "s|\(^CONF_PATHNAME\)\(.*\$\)|\1 = \"../conf/viewvc.conf\"|g"

	sed -i -e "s|\(self\.options\.template_dir\)\(.*\$\)|\1 = \"${MY_APPDIR}/templates\"|" \
		lib/config.py

	sed -i -e "s|^template_dir.*|#&|" conf/viewvc.conf.dist
	sed -i -e "s|^#mime_types_files =.*|mime_types_files = /etc/mime.types|" conf/viewvc.conf.dist
	mv conf/viewvc.conf{.dist,}
	mv conf/cvsgraph.conf{.dist,}

	python_convert_shebangs -r 2 .
}

src_install() {
	webapp_src_preinst

	newbin bin/standalone.py viewvc-standalone-server || die "newbin failed"

	dodoc CHANGES COMMITTERS INSTALL README || die "dodoc failed"

	installation() {
		insinto $(python_get_sitedir)/${PN}
		doins -r lib/*
	}
	python_execute_function installation

	insinto "${MY_APPDIR}"
	doins -r templates/ || die "doins failed"
	doins -r templates-contrib/ || die "doins failed"

	if use mysql; then
		exeinto "${MY_HOSTROOTDIR}/bin"
		doexe bin/{*dbadmin,make-database,loginfo-handler} || die "doexe failed"
	fi

	insinto "${MY_HOSTROOTDIR}/conf"
	doins conf/{viewvc,cvsgraph}.conf

	if use mod_python; then
		insinto "${MY_HTDOCSDIR}"
		doins bin/mod_python/viewvc.py || die "doins failed"
		doins bin/mod_python/handler.py || die "doins failed"
		doins bin/mod_python/.htaccess || die "doins failed"
		if use mysql; then
			doins bin/mod_python/query.py || die "doins failed"
		fi
	else
		exeinto "${MY_CGIBINDIR}"
		doexe bin/cgi/viewvc.cgi || die "doexe failed"
		if use mysql; then
			doexe bin/cgi/query.cgi || die "doexe failed"
		fi
	fi

	webapp_configfile "${MY_HOSTROOTDIR}/conf/"{viewvc,cvsgraph}.conf

	webapp_src_install
}

pkg_postinst() {
	python_mod_optimize viewvc
	webapp_pkg_postinst
	elog "Now read INSTALL in /usr/share/doc/${PF} to configure ${PN}"
}

pkg_postrm() {
	python_mod_cleanup viewvc
}