[gentoo-commits] gentoo-x86 commit in app-misc/sphinx: sphinx-2.0.2_beta.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in app-misc/sphinx: sphinx-2.0.2_beta.ebuild ChangeLog

[Hans de Graaff (graaff)]

graaff      11/11/28 18:24:00

  Modified:             ChangeLog
  Added:                sphinx-2.0.2_beta.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.1.10.11/cvs/Linux x86_64)

Revision  Changes    Path
1.38                 app-misc/sphinx/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/sphinx/ChangeLog?rev=1.38&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/sphinx/ChangeLog?rev=1.38&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/sphinx/ChangeLog?r1=1.37&r2=1.38

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/sphinx/ChangeLog,v
retrieving revision 1.37
retrieving revision 1.38
diff -u -r1.37 -r1.38
--- ChangeLog	28 Sep 2011 10:40:10 -0000	1.37
+++ ChangeLog	28 Nov 2011 18:23:59 -0000	1.38
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/sphinx
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/sphinx/ChangeLog,v 1.37 2011/09/28 10:40:10 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/sphinx/ChangeLog,v 1.38 2011/11/28 18:23:59 graaff Exp $
+
+*sphinx-2.0.2_beta (28 Nov 2011)
+
+  28 Nov 2011; Hans de Graaff <graaff@gentoo.org> +sphinx-2.0.2_beta.ebuild:
+  Version bump.
 
   28 Sep 2011; Fabian Groffen <grobian@gentoo.org> sphinx-2.0.1_beta.ebuild,
   +files/sphinx-2.0.1_beta-solaris.patch:



1.1                  app-misc/sphinx/sphinx-2.0.2_beta.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/sphinx/sphinx-2.0.2_beta.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/sphinx/sphinx-2.0.2_beta.ebuild?rev=1.1&content-type=text/plain

Index: sphinx-2.0.2_beta.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/sphinx/sphinx-2.0.2_beta.ebuild,v 1.1 2011/11/28 18:23:59 graaff Exp $

EAPI=3
inherit eutils autotools

MY_P=${P/_/-}

# This has been added by Gentoo, to explicitly version libstemmer.
# It is the date that http://snowball.tartarus.org/dist/libstemmer_c.tgz was
# fetched.
STEMMER_PV="20091122"
DESCRIPTION="Full-text search engine with support for MySQL and PostgreSQL"
HOMEPAGE="http://www.sphinxsearch.com/"
SRC_URI="http://sphinxsearch.com/files/${MY_P}.tar.gz
	stemmer? ( mirror://gentoo/libstemmer_c-${STEMMER_PV}.tgz )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~ppc-macos ~x86-macos ~sparc-solaris ~sparc64-solaris"
IUSE="debug id64 mysql odbc postgres stemmer test"

RDEPEND="mysql? ( virtual/mysql )
	postgres? ( dev-db/postgresql-base )
	odbc? ( dev-db/unixODBC )
	virtual/libiconv"
DEPEND="${RDEPEND}
	test? ( dev-lang/php )"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${MY_P}.tar.gz
	if use stemmer; then
		cd "${S}"
		unpack libstemmer_c-${STEMMER_PV}.tgz
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.0.1_beta-darwin8.patch

	# drop nasty hardcoded search path breaking Prefix
	sed -i -e '/\/usr\/local\//d' configure.ac || die

	# Regenerate autoconf files in the api directory first to avoid
	# running elibtoolize twice, which results in a warning.
	pushd api/libsphinxclient || die
	eautoreconf
	popd || die

	eautoreconf
}

src_configure() {
	# fix libiconv detection
	use !elibc_glibc && export ac_cv_search_iconv=-liconv

	econf \
		--sysconfdir="${EPREFIX}/etc/${PN}" \
		$(use_enable id64) \
		$(use_with debug) \
		$(use_with mysql) \
		$(use_with odbc unixodbc) \
		$(use_with postgres pgsql) \
		$(use_with stemmer libstemmer)

	cd api/libsphinxclient || die
	econf STRIP=:
}

src_compile() {
	emake || die "emake failed"

	emake -j 1 -C api/libsphinxclient || die "emake libsphinxclient failed"
}

src_test() {
	elog "Tests require access to a live MySQL database and may require configuration."
	elog "You will find them in /usr/share/${PN}/test and they require dev-lang/php"
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"
	emake DESTDIR="${D}" -C api/libsphinxclient install || die "install libsphinxclient failed"

	dodoc doc/*

	dodir /var/lib/sphinx
	dodir /var/log/sphinx
	dodir /var/run/sphinx

	newinitd "${FILESDIR}"/searchd.rc searchd

	if use test; then
		insinto /usr/share/${PN}
		doins -r test || die "install of test files failed."
	fi
}