[gentoo-commits] gentoo-x86 commit in x11-libs/libqxt: metadata.xml libqxt-0.6.1.ebuild ChangeLog libqxt-0.6.0-r2.ebuild

[gentoo-commits] gentoo-x86 commit in x11-libs/libqxt: metadata.xml libqxt-0.6.1.ebuild ChangeLog libqxt-0.6.0-r2.ebuild

[Davide Pesavento (pesa)]

pesa        11/11/12 16:22:31

  Modified:             metadata.xml ChangeLog
  Added:                libqxt-0.6.1.ebuild
  Removed:              libqxt-0.6.0-r2.ebuild
  Log:
  Version bump. Renamed 'crypt' useflag to 'ssl' and fixed description of 'web' useflag. Removed old.
  
  (Portage version: 2.2.0_alpha74/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  x11-libs/libqxt/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libqxt/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libqxt/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libqxt/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/libqxt/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	20 Aug 2010 09:26:59 -0000	1.3
+++ metadata.xml	12 Nov 2011 16:22:31 -0000	1.4
@@ -5,7 +5,7 @@
 <use>
 	<flag name="berkdb">Build the QxtBerkeley module</flag>
 	<flag name="sql">Build the QxtSql module</flag>
-	<flag name="web">Enable fast cgi bindings</flag>
+	<flag name="web">Build the QxtWeb module</flag>
 	<flag name="zeroconf">Build the QxtZeroconf module</flag>
 </use>
 </pkgmetadata>



1.18                 x11-libs/libqxt/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libqxt/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libqxt/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libqxt/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/libqxt/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	12 Nov 2011 00:09:01 -0000	1.17
+++ ChangeLog	12 Nov 2011 16:22:31 -0000	1.18
@@ -1,6 +1,13 @@
 # ChangeLog for x11-libs/libqxt
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libqxt/ChangeLog,v 1.17 2011/11/12 00:09:01 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libqxt/ChangeLog,v 1.18 2011/11/12 16:22:31 pesa Exp $
+
+*libqxt-0.6.1 (12 Nov 2011)
+
+  12 Nov 2011; Davide Pesavento <pesa@gentoo.org> +libqxt-0.6.1.ebuild,
+  -libqxt-0.6.0-r2.ebuild, metadata.xml:
+  Version bump. Renamed 'crypt' useflag to 'ssl' and fixed description of 'web'
+  useflag. Removed old.
 
   12 Nov 2011; Davide Pesavento <pesa@gentoo.org>
   -files/libqxt-0.5.0-gcc4.4.patch, -libqxt-0.2.5-r1.ebuild,



1.1                  x11-libs/libqxt/libqxt-0.6.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libqxt/libqxt-0.6.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libqxt/libqxt-0.6.1.ebuild?rev=1.1&content-type=text/plain

Index: libqxt-0.6.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/libqxt/libqxt-0.6.1.ebuild,v 1.1 2011/11/12 16:22:31 pesa Exp $

EAPI=4

inherit multilib qt4-r2

DESCRIPTION="The Qt eXTension library provides cross-platform utility classes for the Qt toolkit"
HOMEPAGE="http://libqxt.org/"
SRC_URI="http://dev.libqxt.org/libqxt/get/v${PV}.tar.bz2 -> ${P}.tar.bz2"

LICENSE="|| ( CPL-1.0 LGPL-2.1 )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="berkdb debug doc sql ssl web xscreensaver zeroconf"

COMMON_DEPEND="
	x11-libs/libXrandr
	x11-libs/qt-core:4
	x11-libs/qt-gui:4
	berkdb? ( >=sys-libs/db-4.6 )
	sql? ( x11-libs/qt-sql:4 )
	ssl? (
		>=dev-libs/openssl-0.9.8
		x11-libs/qt-core:4[ssl]
	)
	web? ( >=dev-libs/fcgi-2.4 )
	zeroconf? ( net-dns/avahi[mdnsresponder-compat] )
"
DEPEND="${COMMON_DEPEND}
	doc? ( x11-libs/qt-assistant:4 )
"
RDEPEND="${COMMON_DEPEND}
	xscreensaver? ( x11-libs/libXScrnSaver )
"

S="${WORKDIR}/${PN}-${PN}-v${PV}"

DOCS="AUTHORS CHANGES README"
PATCHES=(
	"${FILESDIR}/${PN}-use-system-qdoc3.patch"
)

src_prepare() {
	qt4-r2_src_prepare

	# remove insecure runpath
	sed -i -e '/-Wl,-rpath/d' src/qxtlibs.pri || die
}

src_configure() {
	# custom configure script
	local myconf="./configure
			-prefix '${EPREFIX}/usr'
			-libdir '${EPREFIX}/usr/$(get_libdir)'
			-docdir '${EPREFIX}/usr/share/doc/${PF}'
			-qmake-bin '${EPREFIX}/usr/bin/qmake'
			$(use debug && echo -debug || echo -release)
			$(use berkdb || echo -no-db -nomake berkeley)
			$(use doc || echo -nomake docs)
			$(use sql || echo -nomake sql)
			$(use ssl || echo -no-openssl)
			$(use web || echo -nomake web)
			$(use zeroconf || echo -no-zeroconf -nomake zeroconf)
			-verbose"
	echo ${myconf}
	eval ${myconf} || die "./configure failed"

	eqmake4 -recursive
}

src_compile() {
	qt4-r2_src_compile

	if use doc; then
		einfo "Building documentation"
		emake docs
	fi
}

pkg_postinst() {
	if use doc; then
		einfo
		einfo "In case you want to browse ${PN} documentation using"
		einfo "Qt Assistant, perform the following steps:"
		einfo "  1. Open the Assistant"
		einfo "  2. Edit -> Preferences -> Documentation -> Add"
		einfo "  3. Add this path: ${EPREFIX}/usr/share/doc/${PF}/qxt.qch"
		einfo
	fi
}