* [gentoo-commits] gentoo-x86 commit in net-analyzer/munin: munin-1.4.6-r4.ebuild ChangeLog munin-1.4.6-r3.ebuild
@ 2011-11-11 11:36 Diego Petteno (flameeyes)
0 siblings, 0 replies; only message in thread
From: Diego Petteno (flameeyes) @ 2011-11-11 11:36 UTC (permalink / raw
To: gentoo-commits
flameeyes 11/11/11 11:36:04
Modified: ChangeLog
Added: munin-1.4.6-r4.ebuild
Removed: munin-1.4.6-r3.ebuild
Log:
Complete the if_-hardened patch that was incomplete, and backport one more fix (for a bug introduced in said patch).
(Portage version: 2.2.0_alpha72/cvs/Linux x86_64)
Revision Changes Path
1.63 net-analyzer/munin/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/munin/ChangeLog?rev=1.63&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/munin/ChangeLog?rev=1.63&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/munin/ChangeLog?r1=1.62&r2=1.63
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/munin/ChangeLog,v
retrieving revision 1.62
retrieving revision 1.63
diff -u -r1.62 -r1.63
--- ChangeLog 3 Nov 2011 18:08:56 -0000 1.62
+++ ChangeLog 11 Nov 2011 11:36:04 -0000 1.63
@@ -1,6 +1,13 @@
# ChangeLog for net-analyzer/munin
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/munin/ChangeLog,v 1.62 2011/11/03 18:08:56 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/munin/ChangeLog,v 1.63 2011/11/11 11:36:04 flameeyes Exp $
+
+*munin-1.4.6-r4 (11 Nov 2011)
+
+ 11 Nov 2011; Diego E. Pettenò <flameeyes@gentoo.org> +munin-1.4.6-r4.ebuild,
+ -munin-1.4.6-r3.ebuild, files/munin-1.4.6-if_-hardened.patch:
+ Complete the if_-hardened patch that was incomplete, and backport one more fix
+ (for a bug introduced in said patch).
*munin-1.4.6-r3 (03 Nov 2011)
1.1 net-analyzer/munin/munin-1.4.6-r4.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/munin/munin-1.4.6-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/munin/munin-1.4.6-r4.ebuild?rev=1.1&content-type=text/plain
Index: munin-1.4.6-r4.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/munin/munin-1.4.6-r4.ebuild,v 1.1 2011/11/11 11:36:04 flameeyes Exp $
EAPI=2
inherit eutils
DESCRIPTION="Munin Server Monitoring Tool"
HOMEPAGE="http://munin.projects.linpro.no/"
SRC_URI="mirror://sourceforge/munin/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~mips ~ppc ~sparc ~x86"
IUSE="asterisk doc irc java memcached minimal mysql postgres ssl"
# Upstream's listing of required modules is NOT correct!
# Some of the postgres plugins use DBD::Pg, while others call psql directly.
# The mysql plugins use mysqladmin directly.
DEPEND_COM="dev-lang/perl
sys-process/procps
asterisk? ( dev-perl/Net-Telnet )
irc? ( dev-perl/Net-IRC )
java? ( >=virtual/jdk-1.5 )
mysql? ( virtual/mysql dev-perl/Cache-Cache )
ssl? ( dev-perl/Net-SSLeay )
postgres? ( dev-perl/DBD-Pg dev-db/postgresql-base )
memcached? ( dev-perl/Cache-Memcached )
dev-perl/DateManip
dev-perl/Net-CIDR
dev-perl/Net-Netmask
dev-perl/Net-SNMP
dev-perl/libwww-perl
dev-perl/net-server
dev-perl/DBI
virtual/perl-Digest-MD5
virtual/perl-Getopt-Long
virtual/perl-MIME-Base64
virtual/perl-Storable
virtual/perl-Text-Balanced
virtual/perl-Time-HiRes
!minimal? ( dev-perl/HTML-Template
net-analyzer/rrdtool[perl]
dev-perl/Log-Log4perl )"
# Sybase isn't supported in Gentoo
#munin-sybase? ( dev-perl/DBD-Sybase )
# Keep this seperate, as previous versions have had other deps here
DEPEND="${DEPEND_COM}
virtual/perl-Module-Build"
RDEPEND="${DEPEND_COM}
!minimal? ( virtual/cron )"
pkg_setup() {
enewgroup munin
enewuser munin 177 -1 /var/lib/munin munin
}
src_prepare() {
# upstream needs a lot of DESTDIR loving
# and Gentoo location support
epatch "${FILESDIR}"/${PN}-1.4.4-Makefile.patch
epatch "${FILESDIR}"/${PN}-1.4.6-apc-temp.patch
epatch "${FILESDIR}"/${PN}-1.4.6-munin-version-identifier.patch
epatch "${FILESDIR}"/${PN}-1.4.6-fix-asterisk-plugins.patch
epatch "${FILESDIR}"/${PN}-1.4.6-if_-hardened.patch
epatch "${FILESDIR}"/${PN}-1.4.6-apc-multi.patch
# Don't build java plugins if not requested via USE.
if ! use java; then
# sed is needed so the java plugins aren't automagically built.
sed -i -e 's: build-plugins-java : :' \
-e 's: install-plugins-java : :' Makefile || die
fi
# Bug 304447, fix for gentoo PS location
sed -i -e 's,/usr/bin/ps,/bin/ps,g' \
"${S}"/plugins/node.d/ifx_concurrent_sessions_.in || die
# bug 367785, cleanup make output by disabling HP-UX cruft
sed -i -e "/plugins\/\*\.adv/d" Makefile || die
}
src_compile() {
emake -j 1 build build-man || die "build/build-man failed"
if use doc; then
emake -j 1 build-doc || die "build-doc failed"
fi
#Ensure TLS is disabled if built without SSL
if ! use ssl; then
echo "tls disabled" >> ${S}/build/node/munin-node.conf \
|| die "Fixing munin-node.conf Failed!"
echo "tls disabled" >> ${S}/build/master/munin.conf \
|| die "Fixing munin.conf Failed!"
fi
}
src_install() {
local dirs
dirs="/var/log/munin/ /var/lib/munin/"
dirs="${dirs} /var/lib/munin/plugin-state/"
dirs="${dirs} /var/run/munin/plugin-state/"
dirs="${dirs} /var/run/munin/spool/"
dirs="${dirs} /etc/munin/plugin-conf.d/"
dirs="${dirs} /etc/munin/munin-conf.d/"
dirs="${dirs} /etc/munin/plugins/"
keepdir ${dirs}
if use minimal; then
emake -j 1 DESTDIR="${D}" install-common-prime install-node-prime \
install-plugins-prime || die "install failed"
else
emake -j 1 DESTDIR="${D}" install || die "install failed"
fi
fowners munin:munin ${dirs} || die
insinto /etc/munin/plugin-conf.d/
newins "${FILESDIR}"/${PN}-1.3.2-plugins.conf munin-node || die
# make sure we've got everything in the correct directory
insinto /var/lib/munin
newins "${FILESDIR}"/${PN}-1.3.3-crontab crontab || die
newinitd "${FILESDIR}"/munin-node_init.d_1.4.6-r2 munin-node || die
newconfd "${FILESDIR}"/munin-node_conf.d_1.4.6-r2 munin-node || die
dodoc README ChangeLog INSTALL logo.eps logo.svg build/resources/apache* \
|| die
# bug 254968
insinto /etc/logrotate.d/
newins "${FILESDIR}"/logrotate.d-munin munin || die
}
pkg_config() {
einfo "Press enter to install the default crontab for the munin master"
einfo "installation from /var/lib/munin/crontab"
einfo "If you have a large site, you may wish to customize it."
read
# dcron is very fussy about syntax
# the following is the only form that works in BOTH dcron and vixie-cron
crontab - -u munin </var/lib/munin/crontab
}
pkg_postinst() {
elog "Please follow the munin documentation to set up the plugins you"
elog "need, afterwards start munin-node via /etc/init.d/munin-node."
if ! use minimal; then
elog "To have munin's cronjob automatically configured for you if this is"
elog "your munin master installation, please:"
elog "emerge --config net-analyzer/munin"
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-11-11 11:36 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-11-11 11:36 [gentoo-commits] gentoo-x86 commit in net-analyzer/munin: munin-1.4.6-r4.ebuild ChangeLog munin-1.4.6-r3.ebuild Diego Petteno (flameeyes)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox