[gentoo-commits] gentoo-x86 commit in mail-client/sylpheed: ChangeLog sylpheed-3.1.2.ebuild

["Akinori Hattori (hattya)" <hattya@gentoo.org>]

hattya      11/11/03 07:40:36

  Modified:             ChangeLog
  Added:                sylpheed-3.1.2.ebuild
  Log:
  new upstream release. fixes bug #382229.
  
  (Portage version: 2.1.10.11/cvs/Linux i686)

Revision  Changes    Path
1.295                mail-client/sylpheed/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/sylpheed/ChangeLog?rev=1.295&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/sylpheed/ChangeLog?rev=1.295&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/sylpheed/ChangeLog?r1=1.294&r2=1.295

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/sylpheed/ChangeLog,v
retrieving revision 1.294
retrieving revision 1.295
diff -u -r1.294 -r1.295
--- ChangeLog	3 Nov 2011 07:07:23 -0000	1.294
+++ ChangeLog	3 Nov 2011 07:40:36 -0000	1.295
@@ -1,6 +1,11 @@
 # ChangeLog for mail-client/sylpheed
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/sylpheed/ChangeLog,v 1.294 2011/11/03 07:07:23 hattya Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/sylpheed/ChangeLog,v 1.295 2011/11/03 07:40:36 hattya Exp $
+
+*sylpheed-3.1.2 (03 Nov 2011)
+
+  03 Nov 2011; Akinori Hattori <hattya@gentoo.org> +sylpheed-3.1.2.ebuild:
+  new upstream release. fixes bug #382229.
 
   03 Nov 2011; Akinori Hattori <hattya@gentoo.org> sylpheed-3.1.1.ebuild:
   remove dev-libs/dbus-glib from (R)DEPEND.



1.1                  mail-client/sylpheed/sylpheed-3.1.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/sylpheed/sylpheed-3.1.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/sylpheed/sylpheed-3.1.2.ebuild?rev=1.1&content-type=text/plain

Index: sylpheed-3.1.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-client/sylpheed/sylpheed-3.1.2.ebuild,v 1.1 2011/11/03 07:40:36 hattya Exp $

EAPI="4"

inherit eutils

DESCRIPTION="A lightweight email client and newsreader"
HOMEPAGE="http://sylpheed.sraoss.jp/"
SRC_URI="http://sylpheed.sraoss.jp/${PN}/v${PV%.*}/${P}.tar.bz2"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="crypt ipv6 ldap nls oniguruma pda spell ssl xface"

CDEPEND="x11-libs/gtk+:2
	nls? ( sys-devel/gettext )
	crypt? ( app-crypt/gpgme )
	ldap? ( net-nds/openldap )
	oniguruma? ( dev-libs/oniguruma )
	pda? ( app-pda/jpilot )
	spell? ( app-text/gtkspell:2 )
	ssl? ( dev-libs/openssl )"
RDEPEND="${CDEPEND}
	app-misc/mime-types
	net-misc/curl"
DEPEND="${CDEPEND}
	dev-util/pkgconfig
	xface? ( media-libs/compface )"

src_configure() {
	local htmldir=/usr/share/doc/${PF}/html
	econf \
		$(use_enable crypt gpgme) \
		$(use_enable ipv6) \
		$(use_enable ldap) \
		$(use_enable oniguruma) \
		$(use_enable pda jpilot) \
		$(use_enable spell gtkspell) \
		$(use_enable ssl) \
		$(use_enable xface compface) \
		--with-manualdir=${htmldir}/manual \
		--with-faqdir=${htmldir}/faq \
		--disable-updatecheck
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc AUTHORS ChangeLog* NEWS* README* TODO*

	doicon *.png
	domenu *.desktop
}