[gentoo-commits] gentoo-x86 commit in kde-base/korundum: korundum-4.7.3.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in kde-base/korundum: korundum-4.7.3.ebuild ChangeLog

[Alexey Shvetsov (alexxy)]

alexxy      11/11/02 20:48:03

  Modified:             ChangeLog
  Added:                korundum-4.7.3.ebuild
  Log:
  [kde-base] KDE SC 4.7.3
  
  (Portage version: 2.2.0_alpha72/cvs/Linux x86_64)

Revision  Changes    Path
1.92                 kde-base/korundum/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/korundum/ChangeLog?rev=1.92&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/korundum/ChangeLog?rev=1.92&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/korundum/ChangeLog?r1=1.91&r2=1.92

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/korundum/ChangeLog,v
retrieving revision 1.91
retrieving revision 1.92
diff -u -r1.91 -r1.92
--- ChangeLog	28 Oct 2011 19:03:23 -0000	1.91
+++ ChangeLog	2 Nov 2011 20:48:03 -0000	1.92
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/korundum
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/ChangeLog,v 1.91 2011/10/28 19:03:23 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/ChangeLog,v 1.92 2011/11/02 20:48:03 alexxy Exp $
+
+*korundum-4.7.3 (02 Nov 2011)
+
+  02 Nov 2011; Alexey Shvetsov <alexxy@gentoo.org> +korundum-4.7.3.ebuild:
+  Version bump KDE SC 4.7.3
 
   28 Oct 2011; Andreas K. Huettel <dilfridge@gentoo.org>
   -korundum-4.7.1.ebuild:



1.1                  kde-base/korundum/korundum-4.7.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/korundum/korundum-4.7.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/korundum/korundum-4.7.3.ebuild?rev=1.1&content-type=text/plain

Index: korundum-4.7.3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/korundum-4.7.3.ebuild,v 1.1 2011/11/02 20:48:03 alexxy Exp $

EAPI=4

OPENGL_REQUIRED="always"
KDE_SCM="git"

USE_RUBY="ruby18"
# No ruby19 for three reasons:
# 1) it does not build (yet) - will likely be solved soon
# 2) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
# 3) the ebuild can only be installed for one ruby variant, otherwise the compiled
#    files with identical path+name will overwrite each other - difficult :(

inherit kde4-base ruby-ng

DESCRIPTION="KDE Ruby bindings"
KEYWORDS="~amd64 ~x86"
IUSE="akonadi debug kate okular semantic-desktop"

DEPEND="
	$(add_kdebase_dep qtruby)
	$(add_kdebase_dep smokekde 'akonadi?,kate?,okular?,semantic-desktop=')
	$(add_kdebase_dep smokeqt)
"
RDEPEND="${DEPEND}
"

# Split from kdebindings-ruby in 4.7
add_blocker kdebindings-ruby

pkg_setup() {
	ruby-ng_pkg_setup
	kde4-base_pkg_setup
}

src_unpack() {
	local S="${WORKDIR}/${P}"
	kde4-base_src_unpack

	cd "${WORKDIR}"
	mkdir all
	mv ${P} all/ || die "Could not move sources"
}

all_ruby_prepare() {
	kde4-base_src_prepare
}

each_ruby_configure() {
	CMAKE_USE_DIR=${S}
	mycmakeargs=(
		-DRUBY_LIBRARY=$(ruby_get_libruby)
		-DRUBY_INCLUDE_PATH=$(ruby_get_hdrdir)
		-DRUBY_EXECUTABLE=${RUBY}
		$(cmake-utils_use_with akonadi)
		$(cmake-utils_use_with akonadi KdepimLibs)
		$(cmake-utils_use_disable kate)
		$(cmake-utils_use_with okular)
		$(cmake-utils_use_with semantic-desktop Nepomuk)
		$(cmake-utils_use_with semantic-desktop Soprano)
	)
	kde4-base_src_configure
}

each_ruby_compile() {
	CMAKE_USE_DIR=${S}
	kde4-base_src_compile
}

each_ruby_install() {
	CMAKE_USE_DIR=${S}
	kde4-base_src_install
}