* [gentoo-commits] gentoo-x86 commit in gnome-base/nautilus: metadata.xml ChangeLog nautilus-3.2.1.ebuild
@ 2011-11-02 16:51 Alexandre Rostovtsev (tetromino)
0 siblings, 0 replies; only message in thread
From: Alexandre Rostovtsev (tetromino) @ 2011-11-02 16:51 UTC (permalink / raw
To: gentoo-commits
tetromino 11/11/02 16:51:46
Modified: metadata.xml ChangeLog
Added: nautilus-3.2.1.ebuild
Log:
Add 3.2.1 from the gnome overlay. The internal media previewer is gone, gnome-extra/sushi is used for previewing instead. Has more-or-less working app-misc/tracker support.
(Portage version: 2.2.0_alpha72/cvs/Linux x86_64)
Revision Changes Path
1.8 gnome-base/nautilus/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/nautilus/metadata.xml?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/nautilus/metadata.xml?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/nautilus/metadata.xml?r1=1.7&r2=1.8
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/nautilus/metadata.xml,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- metadata.xml 15 Aug 2011 12:26:09 -0000 1.7
+++ metadata.xml 2 Nov 2011 16:51:46 -0000 1.8
@@ -5,7 +5,12 @@
<use>
<flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg> for
introspection</flag>
+ <flag name="packagekit">Use packagekit to search for programs to open
+ unknown file types</flag>
+ <flag name="previewer">Use <pkg>gnome-extra/sushi</pkg> to preview files
+ from the file mananger</flag>
<flag name="sendto">Enable the nautilus-sendto extension to send files to
various locations/devices</flag>
+ <flag name="tracker">Add support for <pkg>app-misc/tracker</pkg> search</flag>
</use>
</pkgmetadata>
1.385 gnome-base/nautilus/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/nautilus/ChangeLog?rev=1.385&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/nautilus/ChangeLog?rev=1.385&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/nautilus/ChangeLog?r1=1.384&r2=1.385
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/nautilus/ChangeLog,v
retrieving revision 1.384
retrieving revision 1.385
diff -u -r1.384 -r1.385
--- ChangeLog 5 Oct 2011 17:33:36 -0000 1.384
+++ ChangeLog 2 Nov 2011 16:51:46 -0000 1.385
@@ -1,6 +1,14 @@
# ChangeLog for gnome-base/nautilus
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/nautilus/ChangeLog,v 1.384 2011/10/05 17:33:36 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/nautilus/ChangeLog,v 1.385 2011/11/02 16:51:46 tetromino Exp $
+
+*nautilus-3.2.1 (02 Nov 2011)
+
+ 02 Nov 2011; Alexandre Rostovtsev <tetromino@gentoo.org>
+ +nautilus-3.2.1.ebuild, metadata.xml:
+ Add 3.2.1 from the gnome overlay. The internal media previewer is gone,
+ gnome-extra/sushi is used for previewing instead. Has more-or-less working
+ app-misc/tracker support.
05 Oct 2011; Kacper Kowalik <xarthisius@gentoo.org>
nautilus-2.32.2.1-r1.ebuild:
1.1 gnome-base/nautilus/nautilus-3.2.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/nautilus/nautilus-3.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/nautilus/nautilus-3.2.1.ebuild?rev=1.1&content-type=text/plain
Index: nautilus-3.2.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/nautilus/nautilus-3.2.1.ebuild,v 1.1 2011/11/02 16:51:46 tetromino Exp $
EAPI="4"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
inherit gnome2 virtualx
DESCRIPTION="A file manager for the GNOME desktop"
HOMEPAGE="http://live.gnome.org/Nautilus"
LICENSE="GPL-2 LGPL-2 FDL-1.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux"
IUSE="doc exif gnome +introspection packagekit +previewer sendto tracker xmp"
# Require {glib,gdbus-codegen}-2.30.0 due to GDBus API changes between 2.29.92
# and 2.30.0
COMMON_DEPEND=">=dev-libs/glib-2.30.0:2
>=x11-libs/pango-1.28.3
>=x11-libs/gtk+-3.1.6:3[introspection?]
>=dev-libs/libxml2-2.7.8:2
>=gnome-base/gnome-desktop-3.0.0:3
gnome-base/dconf
gnome-base/gsettings-desktop-schemas
>=x11-libs/libnotify-0.7
x11-libs/libX11
x11-libs/libXext
x11-libs/libXrender
exif? ( >=media-libs/libexif-0.6.20 )
introspection? ( >=dev-libs/gobject-introspection-0.6.4 )
tracker? ( >=app-misc/tracker-0.12 )
xmp? ( >=media-libs/exempi-2.1.0 )"
DEPEND="${COMMON_DEPEND}
>=dev-lang/perl-5
>=dev-util/gdbus-codegen-2.30.0
>=dev-util/pkgconfig-0.9
>=dev-util/intltool-0.40.1
sys-devel/gettext
x11-proto/xproto
doc? ( >=dev-util/gtk-doc-1.4 )"
RDEPEND="${COMMON_DEPEND}
packagekit? ( app-admin/packagekit-base )
sendto? ( !<gnome-extra/nautilus-sendto-3.0.1 )"
# For eautoreconf
# gnome-base/gnome-common
# dev-util/gtk-doc-am"
PDEPEND="gnome? (
>=x11-themes/gnome-icon-theme-1.1.91
x11-themes/gnome-icon-theme-symbolic )
tracker? ( >=gnome-extra/nautilus-tracker-tags-0.12 )
previewer? ( >=gnome-extra/sushi-0.1.9 )
sendto? ( >=gnome-extra/nautilus-sendto-3.0.1 )
>=gnome-base/gvfs-0.1.2"
pkg_setup() {
G2CONF="${G2CONF}
--disable-maintainer-mode
--disable-update-mimedb
$(use_enable exif libexif)
$(use_enable introspection)
$(use_enable packagekit)
$(use_enable sendto nst-extension)
$(use_enable tracker)
$(use_enable xmp)"
DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS README THANKS TODO"
}
src_prepare() {
gnome2_src_prepare
# Remove crazy CFLAGS
sed 's:-DG.*DISABLE_DEPRECATED::g' -i configure.in configure \
|| die "sed 1 failed"
}
src_test() {
addpredict "/root/.gnome2_private"
unset SESSION_MANAGER
unset ORBIT_SOCKETDIR
unset DBUS_SESSION_BUS_ADDRESS
Xemake check || die "Test phase failed"
}
pkg_postinst() {
gnome2_pkg_postinst
if use previewer; then
elog "nautilus uses gnome-extra/sushi to preview media files."
elog "To activate the previewer, select a file and press space; to"
elog "close the previewer, press space again."
else
elog "To preview media files, emerge nautilus with USE=previewer"
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-11-02 16:51 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-11-02 16:51 [gentoo-commits] gentoo-x86 commit in gnome-base/nautilus: metadata.xml ChangeLog nautilus-3.2.1.ebuild Alexandre Rostovtsev (tetromino)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox