[gentoo-commits] gentoo-x86 commit in x11-terms/mlterm: mlterm-3.0.7.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in x11-terms/mlterm: mlterm-3.0.7.ebuild ChangeLog

[Naohiro Aota (naota)]

naota       11/10/28 07:56:49

  Modified:             ChangeLog
  Added:                mlterm-3.0.7.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha67/cvs/Linux x86_64)

Revision  Changes    Path
1.80                 x11-terms/mlterm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/mlterm/ChangeLog?rev=1.80&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/mlterm/ChangeLog?rev=1.80&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/mlterm/ChangeLog?r1=1.79&r2=1.80

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-terms/mlterm/ChangeLog,v
retrieving revision 1.79
retrieving revision 1.80
diff -u -r1.79 -r1.80
--- ChangeLog	18 Aug 2011 02:19:26 -0000	1.79
+++ ChangeLog	28 Oct 2011 07:56:49 -0000	1.80
@@ -1,6 +1,12 @@
 # ChangeLog for x11-terms/mlterm
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/mlterm/ChangeLog,v 1.79 2011/08/18 02:19:26 naota Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/mlterm/ChangeLog,v 1.80 2011/10/28 07:56:49 naota Exp $
+
+*mlterm-3.0.7 (28 Oct 2011)
+
+  28 Oct 2011; Naohiro Aota <naota@gentoo.org> +mlterm-3.0.7.ebuild,
+  +files/mlterm-3.0.7-ldflags.patch, +files/mlterm-3.0.7-underlinking.patch:
+  Version bump.
 
 *mlterm-3.0.6 (18 Aug 2011)
 



1.1                  x11-terms/mlterm/mlterm-3.0.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/mlterm/mlterm-3.0.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/mlterm/mlterm-3.0.7.ebuild?rev=1.1&content-type=text/plain

Index: mlterm-3.0.7.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-terms/mlterm/mlterm-3.0.7.ebuild,v 1.1 2011/10/28 07:56:49 naota Exp $

EAPI="3"
inherit autotools eutils

IUSE="bidi debug gtk ibus libssh2 m17n-lib nls scim static-libs uim xft"

DESCRIPTION="A multi-lingual terminal emulator"
HOMEPAGE="http://mlterm.sourceforge.net/"
SRC_URI="mirror://sourceforge/mlterm/${P}.tar.gz"

SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
LICENSE="BSD"

RDEPEND="|| ( sys-libs/libutempter sys-apps/utempter )
	x11-libs/libX11
	x11-libs/libICE
	x11-libs/libSM
	gtk? ( x11-libs/gtk+:2 )
	xft? ( x11-libs/libXft )
	bidi? ( >=dev-libs/fribidi-0.10.4 )
	ibus? ( >=app-i18n/ibus-1.3 )
	libssh2? ( net-libs/libssh2 )
	nls? ( virtual/libintl )
	uim? ( >=app-i18n/uim-1.0 )
	scim? ( >=app-i18n/scim-1.4 )
	m17n-lib? ( >=dev-libs/m17n-lib-1.2.0 )"
#	vte? ( x11-libs/vte )
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-2.9.4-uim15-fix.patch \
		"${FILESDIR}"/${PN}-3.0.5-ibus.patch \
		"${FILESDIR}"/${PN}-3.0.7-ldflags.patch \
		"${FILESDIR}"/${PN}-3.0.7-underlinking.patch

	eautoconf
}

src_configure() {
	local myconf

	if use gtk ; then
		myconf="${myconf} --with-imagelib=gdk-pixbuf"
	else
		myconf="${myconf} --with-tools=mlclient,mlcc"
	fi

	if use xft ; then
		myconf="${myconf} --with-type-engines=xft"
	else
		myconf="${myconf} --with-type-engines=xcore"
	fi

	# iiimf isn't stable enough
	#myconf="${myconf} $(use_enable iiimf)"

	econf --enable-utmp \
		$(use_enable bidi fribidi) \
		$(use_enable debug) \
		$(use_enable ibus) \
		$(use_enable libssh2 ssh2) \
		$(use_enable nls) \
		$(use_enable uim) \
		$(use_enable scim) \
		$(use_enable m17n-lib m17nlib) \
		$(use_enable static-libs static) \
		${myconf} || die "econf failed"
}

src_install () {
	emake DESTDIR="${D}" install || die

	if ! use static-libs ; then
		find "${ED}" -name '*.la' -delete || die
	fi

	doicon contrib/icon/mlterm* || die
	make_desktop_entry mlterm mlterm mlterm-icon TerminalEmulator || die

	dodoc ChangeLog README || die

	docinto ja
	dodoc doc/ja/* || die
	docinto en
	dodoc doc/en/* || die
}