[gentoo-commits] gentoo-x86 commit in x11-misc/lightdm: lightdm-1.1.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in x11-misc/lightdm: lightdm-1.1.0.ebuild ChangeLog

[Markos Chandras (hwoarang)]

hwoarang    11/10/23 16:50:42

  Modified:             ChangeLog
  Added:                lightdm-1.1.0.ebuild
  Log:
  Version bump. Bug #387197. Thanks to Roman Sergeev <sungeneral@gmail.com>
  
  (Portage version: 2.2.0_alpha70/cvs/Linux x86_64)

Revision  Changes    Path
1.13                 x11-misc/lightdm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/ChangeLog?r1=1.12&r2=1.13

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog	14 Oct 2011 16:52:05 -0000	1.12
+++ ChangeLog	23 Oct 2011 16:50:42 -0000	1.13
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/lightdm
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v 1.12 2011/10/14 16:52:05 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v 1.13 2011/10/23 16:50:42 hwoarang Exp $
+
+*lightdm-1.1.0 (23 Oct 2011)
+
+  23 Oct 2011; Markos Chandras <hwoarang@gentoo.org> +lightdm-1.1.0.ebuild:
+  Version bump. Bug #387197. Thanks to Roman Sergeev <sungeneral@gmail.com>
 
   14 Oct 2011; Markos Chandras <hwoarang@gentoo.org> -lightdm-0.9.8.ebuild:
   remove old



1.1                  x11-misc/lightdm/lightdm-1.1.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/lightdm-1.1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/lightdm-1.1.0.ebuild?rev=1.1&content-type=text/plain

Index: lightdm-1.1.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/lightdm-1.1.0.ebuild,v 1.1 2011/10/23 16:50:42 hwoarang Exp $

EAPI=4
inherit autotools eutils pam

DESCRIPTION="A lightweight display manager"
HOMEPAGE="http://www.freedesktop.org/wiki/Software/LightDM"
SRC_URI="http://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.gz
	gtk? ( http://dev.gentoo.org/~hwoarang/distfiles/${PN}-gentoo-patch.tar.gz )"

LICENSE="GPL-3 LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="branding +gtk +introspection qt4"

RDEPEND="dev-libs/glib:2
	virtual/pam
	x11-libs/libxklavier
	x11-libs/libX11
	dev-libs/libxml2
	gtk? ( x11-libs/gtk+:3
		x11-themes/gnome-themes-standard
		x11-themes/gnome-icon-theme )
	qt4? ( x11-libs/qt-core:4
		x11-libs/qt-dbus:4 )
	sys-apps/accountsservice"
DEPEND="${RDEPEND}
	dev-lang/vala:0.12
	dev-util/intltool
	dev-util/pkgconfig
	sys-devel/gettext
	introspection? ( dev-libs/gobject-introspection )"

REQUIRED_USE="branding? ( gtk ) || ( gtk qt4 )"
DOCS=( NEWS )

src_prepare() {
	sed -i -e "/minimum-uid/s:500:1000:" "${S}"/data/users.conf	|| die
	sed -i -e "s:gtk+-3.0:gtk+-2.0:" "${S}"/configure.ac || die
	# work around for broken compilation
	sed -i "s/lightdm-session//" "${S}"/tests/src/Makefile.am || die

	eautoreconf
}

src_configure() {
	# Maybe in the future, we can support some automatic session and user
	# recognition. Until then, use default values
	local default=gnome greeter= user=root

	# gtk has higher priority because Qt4 interface sucks :)
	use qt4 && greeter=lightdm-qt-greeter
	use gtk && greeter=lightdm-gtk-greeter

	# Let user know how lightdm is configured
	einfo "Gentoo configuration"
	einfo "Default greeter: ${greeter}"
	einfo "Default session: ${default}"
	einfo "Greeter user: ${user}"

	# do the actual configuration
	econf --localstatedir=/var \
		--disable-static \
		$(use_enable introspection) \
		$(use_enable qt4 liblightdm-qt) \
		$(use_enable qt4 qt-greeter) \
		$(use_enable gtk gtk-greeter) \
		--with-user-session=${default} \
		--with-greeter-session=${greeter} \
		--with-greeter-user=${user} \
		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
}

src_install() {
	default

	# Install missing files
	insinto /etc/${PN}/
	doins "${S}"/data/{users,keys}.conf
	# remove .la files
	find "${ED}" -name "*.la" -exec rm -rf {} +
	rm -Rf "${ED}"/etc/init || die

	if use gtk; then
		insinto /etc/${PN}/
		doins "${WORKDIR}"/${PN}-gtk-greeter.conf
		if use branding; then
			insinto /usr/share/${PN}/backgrounds/
			doins "${WORKDIR}"/gentoo1024x768.png
			sed -i -e "/background/s:=.*:=/usr/share/${PN}/backgrounds/gentoo1024x768.png:" \
				"${D}"/etc/${PN}/${PN}-gtk-greeter.conf || die
		fi
	fi
	pamd_mimic system-local-login lightdm auth account session
}

pkg_postinst() {
	elog
	elog "Even though the default /etc/${PN}/${PN}.conf will work for"
	elog "most users, make sure you configure it to suit your needs"
	elog "before using ${PN} for the first time."
	elog "You can test the configuration file using the following"
	elog "command: ${PN} --test-mode -c /etc/${PN}/${PN}.conf. This"
	elog "requires xorg-server to be built with the 'kdrive' useflag."
	elog
}