[gentoo-commits] gentoo-x86 commit in dev-lang/parrot: parrot-3.9.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-lang/parrot: parrot-3.9.0.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     11/10/22 18:34:28

  Modified:             ChangeLog
  Added:                parrot-3.9.0.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.0_alpha70/cvs/Linux x86_64)

Revision  Changes    Path
1.47                 dev-lang/parrot/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/parrot/ChangeLog?rev=1.47&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/parrot/ChangeLog?rev=1.47&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/parrot/ChangeLog?r1=1.46&r2=1.47

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/parrot/ChangeLog,v
retrieving revision 1.46
retrieving revision 1.47
diff -u -r1.46 -r1.47
--- ChangeLog	29 Aug 2011 17:32:25 -0000	1.46
+++ ChangeLog	22 Oct 2011 18:34:28 -0000	1.47
@@ -1,6 +1,11 @@
 # ChangeLog for dev-lang/parrot
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/parrot/ChangeLog,v 1.46 2011/08/29 17:32:25 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/parrot/ChangeLog,v 1.47 2011/10/22 18:34:28 patrick Exp $
+
+*parrot-3.9.0 (22 Oct 2011)
+
+  22 Oct 2011; Patrick Lauer <patrick@gentoo.org> +parrot-3.9.0.ebuild:
+  Bump
 
   29 Aug 2011; Fabian Groffen <grobian@gentoo.org> parrot-3.6.0.ebuild:
   Transfer Prefix keywords, fix building on Darwin by disabling checks for Fink



1.1                  dev-lang/parrot/parrot-3.9.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/parrot/parrot-3.9.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/parrot/parrot-3.9.0.ebuild?rev=1.1&content-type=text/plain

Index: parrot-3.9.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/parrot/parrot-3.9.0.ebuild,v 1.1 2011/10/22 18:34:28 patrick Exp $

EAPI=3

inherit eutils multilib

DESCRIPTION="Virtual machine designed to efficiently compile and execute bytecode for dynamic languages"
HOMEPAGE="http://www.parrot.org/"
#SRC_URI="ftp://ftp.parrot.org/pub/parrot/releases/supported/${PV}/${P}.tar.bz2"
SRC_URI="ftp://ftp.parrot.org/pub/parrot/releases/stable/${PV}/${P}.tar.bz2"

LICENSE="Artistic-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="opengl nls doc examples gdbm gmp ssl +unicode pcre"

RDEPEND="sys-libs/readline
	opengl? ( media-libs/freeglut )
	nls? ( sys-devel/gettext )
	unicode? ( >=dev-libs/icu-2.6 )
	gdbm? ( >=sys-libs/gdbm-1.8.3-r1 )
	gmp? ( >=dev-libs/gmp-4.1.4 )
	ssl? ( dev-libs/openssl )
	pcre? ( dev-libs/libpcre )"

DEPEND="dev-lang/perl[doc?]
	${RDEPEND}"

src_configure() {
	myconf="--disable-rpath"
	use unicode || myconf+=" --without-icu"
	use ssl     || myconf+=" --without-crypto"
	use gdbm    || myconf+=" --without-gdbm"
	use nls     || myconf+=" --without-gettext"
	use gmp     || myconf+=" --without-gmp"
	use opengl  || myconf+=" --without-opengl"
	use pcre    || myconf+=" --without-pcre"

	perl Configure.pl \
		--ccflags="${CFLAGS}" \
		--linkflags="${LDFLAGS}" \
		--prefix="${EPREFIX}"/usr \
		--libdir="${EPREFIX}"/usr/$(get_libdir) \
		--mandir="${EPREFIX}"/usr/share/man \
		--sysconfdir="${EPREFIX}"/etc \
		--sharedstatedir="${EPREFIX}"/var/lib/parrot \
		$myconf || die
}

src_compile() {
	export LD_LIBRARY_PATH=${LD_LIBRARY_PATH:+$LD_LIBRARY_PATH:}"${S}"/blib/lib
	# occasionally dies in parallel make
	emake -j1 || die
	if use doc ; then
		emake -j1 html || die
	fi
}

src_test() {
	emake -j1 test || die
}

src_install() {
	emake -j1 install-dev DESTDIR="${D}" DOC_DIR="${EPREFIX}/usr/share/doc/${PF}" || die
	dodoc CREDITS DONORS.pod PBC_COMPAT PLATFORMS RESPONSIBLE_PARTIES TODO || die
	if use examples; then
		insinto "/usr/share/doc/${PF}/examples"
		doins -r examples/* || die
	fi
	if use doc; then
		insinto "/usr/share/doc/${PF}/editor"
		doins -r editor || die
		cd docs/html
		dohtml -r developer.html DONORS.pod.html index.html ops.html parrotbug.html pdds.html \
			pmc.html tools.html docs src tools || die
	fi
}